kfilemetadata/src/CMakeLists.txt

0001 ecm_qt_declare_logging_category(debug_SRCS
0002     HEADER kfilemetadata_debug.h
0003     IDENTIFIER KFILEMETADATA_LOG
0004     CATEGORY_NAME kf.filemetadata
0005     OLD_CATEGORY_NAMES kf5.kfilemetadata
0006     DESCRIPTION "KFileMetaData"
0007     EXPORT KFILEMETADATA
0008 )
0009
0010 set(KF5FileMetaData_SRCS
0011     extractionresult.cpp
0012     simpleextractionresult.cpp
0013     embeddedimagedata.cpp
0014     extractor.cpp
0015     extractorplugin.cpp
0016     extractorcollection.cpp
0017     externalextractor.cpp
0018     propertyinfo.cpp
0019     typeinfo.cpp
0020     usermetadata.cpp
0021     writedata.cpp
0022     writer.cpp
0023     writerplugin.cpp
0024     writercollection.cpp
0025     externalwriter.cpp
0026     formatstrings.cpp
0027     mimeutils.cpp
0028     ${debug_SRCS}
0029     )
0030
0031 add_library(KF5FileMetaData
0032     ${KF5FileMetaData_SRCS}
0033 )
0034
0035 add_library(KF5::FileMetaData ALIAS KF5FileMetaData)
0036
0037 target_link_libraries(KF5FileMetaData
0038   PUBLIC
0039     Qt${QT_MAJOR_VERSION}::Core
0040   PRIVATE
0041     KF5::I18n
0042     KF5::CoreAddons
0043 )
0044
0045 ecm_generate_export_header(KF5FileMetaData
0046     EXPORT_FILE_NAME kfilemetadata_export.h
0047     BASE_NAME KFileMetaData
0048     GROUP_BASE_NAME KF
0049     VERSION ${KF_VERSION}
0050     DEPRECATED_BASE_VERSION 0
0051     DEPRECATION_VERSIONS 5.50 5.60 5.76 5.82 5.89 5.91
0052     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0053 )
0054
0055 set_target_properties(KF5FileMetaData PROPERTIES
0056     VERSION ${KFILEMETADATA_VERSION}
0057     SOVERSION ${KFILEMETADATA_SOVERSION}
0058     EXPORT_NAME FileMetaData
0059 )
0060
0061 target_include_directories(KF5FileMetaData INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData>")
0062
0063 ecm_generate_headers(KF5FileMetaData_CamelCase_HEADERS
0064     HEADER_NAMES
0065     ExtractionResult
0066     SimpleExtractionResult
0067     Extractor
0068     ExtractorPlugin
0069     ExtractorCollection
0070     Properties
0071     PropertyInfo
0072     Types
0073     TypeInfo
0074     UserMetaData
0075     WriteData
0076     Writer
0077     WriterPlugin
0078     WriterCollection
0079     EmbeddedImageData
0080     MimeUtils
0081
0082     PREFIX kfilemetadata
0083     REQUIRED_HEADERS KF5FileMetaData_HEADERS
0084 )
0085
0086 install(TARGETS KF5FileMetaData EXPORT KF5FileMetaDataTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0087
0088 install(EXPORT KF5FileMetaDataTargets
0089         NAMESPACE KF5::
0090         DESTINATION ${KDE_INSTALL_LIBDIR}/cmake/KF5FileMetaData
0091         FILE KF5FileMetaDataTargets.cmake)
0092
0093 install(FILES
0094     ${CMAKE_CURRENT_BINARY_DIR}/kfilemetadata_export.h
0095     ${KF5FileMetaData_HEADERS}
0096     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData/kfilemetadata COMPONENT Devel
0097 )
0098
0099 install(FILES
0100     ${KF5FileMetaData_CamelCase_HEADERS}
0101     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData/KFileMetaData COMPONENT Devel
0102 )
0103
0104 configure_file(config-kfilemetadata.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-kfilemetadata.h)
0105
0106 if(BUILD_QCH)
0107     ecm_add_qch(
0108         KF5FileMetaData_QCH
0109         NAME KFileMetaData
0110         BASE_NAME KF5FileMetaData
0111         VERSION ${KF_VERSION}
0112         ORG_DOMAIN org.kde
0113         SOURCES # using only public headers, to cover only public API
0114             ${KF5FileMetaData_HEADERS}
0115         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0116         LINK_QCHS
0117             Qt5Core_QCH
0118         INCLUDE_DIRS
0119             ${CMAKE_CURRENT_BINARY_DIR}
0120         BLANK_MACROS
0121             KFILEMETADATA_EXPORT
0122             KFILEMETADATA_DEPRECATED
0123             KFILEMETADATA_DEPRECATED_EXPORT
0124             "KFILEMETADATA_DEPRECATED_VERSION(x, y, t)"
0125             "KFILEMETADATA_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0126             "KFILEMETADATA_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0127             "KFILEMETADATA_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0128         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0129         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0130         COMPONENT Devel
0131     )
0132 endif()
0133
0134 include(ECMGeneratePriFile)
0135 ecm_generate_pri_file(
0136     BASE_NAME KFileMetaData
0137     LIB_NAME KF5FileMetaData
0138     DEPS "core"
0139     FILENAME_VAR PRI_FILENAME
0140     INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData
0141 )
0142 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0143
0144 add_subdirectory(extractors)
0145
0146 add_subdirectory(writers)
0147
0148 ecm_qt_install_logging_categories(
0149     EXPORT KFILEMETADATA
0150     FILE kfilemetadata.categories
0151     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0152 )