kfilemetadata/src/CMakeLists.txt

0001 ecm_qt_declare_logging_category(debug_SRCS
0002     HEADER kfilemetadata_debug.h
0003     IDENTIFIER KFILEMETADATA_LOG
0004     CATEGORY_NAME kf.filemetadata
0005     OLD_CATEGORY_NAMES kf5.kfilemetadata
0006     DESCRIPTION "KFileMetaData"
0007     EXPORT KFILEMETADATA
0008 )
0009
0010 add_library(KF6FileMetaData)
0011 add_library(KF6::FileMetaData ALIAS KF6FileMetaData)
0012
0013 set_target_properties(KF6FileMetaData PROPERTIES
0014     VERSION     ${KFILEMETADATA_VERSION}
0015     SOVERSION   ${KFILEMETADATA_SOVERSION}
0016     EXPORT_NAME FileMetaData
0017 )
0018
0019 target_sources(KF6FileMetaData PRIVATE
0020     extractionresult.cpp
0021     simpleextractionresult.cpp
0022     embeddedimagedata.cpp
0023     extractor.cpp
0024     extractorplugin.cpp
0025     extractorcollection.cpp
0026     externalextractor.cpp
0027     propertyinfo.cpp
0028     typeinfo.cpp
0029     usermetadata.cpp
0030     writedata.cpp
0031     writer.cpp
0032     writerplugin.cpp
0033     writercollection.cpp
0034     externalwriter.cpp
0035     formatstrings.cpp
0036     mimeutils.cpp
0037     ${debug_SRCS}
0038     )
0039
0040 target_link_libraries(KF6FileMetaData
0041   PUBLIC
0042     Qt6::Core
0043   PRIVATE
0044     KF6::I18n
0045     KF6::CoreAddons
0046 )
0047
0048 ecm_generate_export_header(KF6FileMetaData
0049     EXPORT_FILE_NAME kfilemetadata_export.h
0050     BASE_NAME KFileMetaData
0051     GROUP_BASE_NAME KF
0052     VERSION ${KF_VERSION}
0053     USE_VERSION_HEADER
0054     DEPRECATED_BASE_VERSION 0
0055     DEPRECATION_VERSIONS
0056     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0057 )
0058
0059 target_include_directories(KF6FileMetaData INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData>")
0060
0061 ecm_generate_headers(KF6FileMetaData_CamelCase_HEADERS
0062     HEADER_NAMES
0063     ExtractionResult
0064     SimpleExtractionResult
0065     Extractor
0066     ExtractorPlugin
0067     ExtractorCollection
0068     Properties
0069     PropertyInfo
0070     Types
0071     TypeInfo
0072     UserMetaData
0073     WriteData
0074     Writer
0075     WriterPlugin
0076     WriterCollection
0077     EmbeddedImageData
0078     MimeUtils
0079
0080     PREFIX kfilemetadata
0081     REQUIRED_HEADERS KF6FileMetaData_HEADERS
0082 )
0083
0084 install(TARGETS KF6FileMetaData EXPORT KF6FileMetaDataTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0085
0086 install(EXPORT KF6FileMetaDataTargets
0087         NAMESPACE KF6::
0088         DESTINATION ${KDE_INSTALL_LIBDIR}/cmake/KF6FileMetaData
0089         FILE KF6FileMetaDataTargets.cmake)
0090
0091 install(FILES
0092     ${CMAKE_CURRENT_BINARY_DIR}/kfilemetadata_export.h
0093     ${KF6FileMetaData_HEADERS}
0094     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData/kfilemetadata COMPONENT Devel
0095 )
0096
0097 install(FILES
0098     ${KF6FileMetaData_CamelCase_HEADERS}
0099     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KFileMetaData/KFileMetaData COMPONENT Devel
0100 )
0101
0102 configure_file(config-kfilemetadata.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-kfilemetadata.h)
0103
0104 if(BUILD_QCH)
0105     ecm_add_qch(
0106         KF6FileMetaData_QCH
0107         NAME KFileMetaData
0108         BASE_NAME KF6FileMetaData
0109         VERSION ${KF_VERSION}
0110         ORG_DOMAIN org.kde
0111         SOURCES # using only public headers, to cover only public API
0112             ${KF6FileMetaData_HEADERS}
0113         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0114         LINK_QCHS
0115             Qt6Core_QCH
0116         INCLUDE_DIRS
0117             ${CMAKE_CURRENT_BINARY_DIR}
0118         BLANK_MACROS
0119             KFILEMETADATA_EXPORT
0120             KFILEMETADATA_DEPRECATED
0121             KFILEMETADATA_DEPRECATED_EXPORT
0122             "KFILEMETADATA_DEPRECATED_VERSION(x, y, t)"
0123             "KFILEMETADATA_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0124             "KFILEMETADATA_ENUMERATOR_DEPRECATED_VERSION(x, y, t)"
0125             "KFILEMETADATA_ENUMERATOR_DEPRECATED_VERSION_BELATED(x, y, xt, yt, t)"
0126         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0127         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0128         COMPONENT Devel
0129     )
0130 endif()
0131
0132 add_subdirectory(extractors)
0133
0134 add_subdirectory(writers)
0135
0136 ecm_qt_install_logging_categories(
0137     EXPORT KFILEMETADATA
0138     FILE kfilemetadata.categories
0139     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0140 )