frameworks/kdesu/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KDESu VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.115.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016
0017 include(ECMGenerateExportHeader)
0018 include(ECMSetupVersion)
0019 include(ECMGenerateHeaders)
0020 include(ECMMarkNonGuiExecutable)
0021 include(ECMQtDeclareLoggingCategory)
0022 include(ECMAddQch)
0023 include(ECMDeprecationSettings)
0024
0025 set(REQUIRED_QT_VERSION 5.15.2)
0026 find_package(Qt${QT_MAJOR_VERSION}Core ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0027
0028 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0029 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0030 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0031 find_package(KF5Pty ${KF_DEP_VERSION} REQUIRED)
0032
0033 #optional features
0034 find_package(X11)
0035 set(HAVE_X11 ${X11_FOUND})
0036
0037 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0038
0039 option(KDESU_USE_SUDO_DEFAULT "Set On to use sudo instead of su [default=Off]" Off)
0040 option(KDESU_USE_DOAS_DEFAULT "Set On to use doas instead of su and sudo [default=Off]" Off)
0041 if(KDESU_USE_SUDO_DEFAULT AND KDESU_USE_DOAS_DEFAULT)
0042    message(FATAL_ERROR "Choose between sudo(1) or doas(1)")
0043 elseif(KDESU_USE_SUDO_DEFAULT)
0044   message("Using sudo as default")
0045 elseif(KDESU_USE_DOAS_DEFAULT)
0046   message("Using doas as default")
0047 else()
0048   message("Using su as default (set KDESU_USE_SUDO_DEFAULT=On to use sudo)")
0049 endif()
0050
0051 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0052 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0053
0054 ecm_setup_version(PROJECT VARIABLE_PREFIX KDESU
0055                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kdesu_version.h"
0056                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5SuConfigVersion.cmake"
0057                         SOVERSION 5)
0058 ecm_set_disabled_deprecation_versions(
0059     QT 5.15.2
0060     KF 5.95
0061 )
0062
0063 ki18n_install(po)
0064 add_subdirectory(src)
0065
0066 # create a Config.cmake and a ConfigVersion.cmake file and install them
0067 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Su")
0068
0069 if (BUILD_QCH)
0070     ecm_install_qch_export(
0071         TARGETS KF5Su_QCH
0072         FILE KF5SuQchTargets.cmake
0073         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0074         COMPONENT Devel
0075     )
0076     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5SuQchTargets.cmake\")")
0077 endif()
0078
0079 include(CMakePackageConfigHelpers)
0080
0081 configure_package_config_file(
0082   "${CMAKE_CURRENT_SOURCE_DIR}/KF5SuConfig.cmake.in"
0083   "${CMAKE_CURRENT_BINARY_DIR}/KF5SuConfig.cmake"
0084   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0085 )
0086
0087 install(FILES
0088   "${CMAKE_CURRENT_BINARY_DIR}/KF5SuConfig.cmake"
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF5SuConfigVersion.cmake"
0090   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0091   COMPONENT Devel
0092 )
0093
0094 install(EXPORT KF5SuTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5SuTargets.cmake NAMESPACE KF5:: )
0095
0096 install(FILES
0097    ${CMAKE_CURRENT_BINARY_DIR}/kdesu_version.h
0098   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDESu COMPONENT Devel
0099 )
0100
0101 if(BUILD_TESTING)
0102   add_subdirectory(autotests)
0103 endif()
0104
0105 feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)