frameworks/kdesu/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KDESu VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0012
0013 include(KDEInstallDirs)
0014 include(KDECMakeSettings)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016
0017 include(ECMGenerateExportHeader)
0018 include(ECMSetupVersion)
0019 include(ECMGenerateHeaders)
0020 include(ECMMarkNonGuiExecutable)
0021 include(ECMQtDeclareLoggingCategory)
0022 include(ECMAddQch)
0023 include(ECMDeprecationSettings)
0024
0025 set(REQUIRED_QT_VERSION 6.5.0)
0026 find_package(Qt6Core ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
0027
0028 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0029 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0030 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0031 find_package(KF6Pty ${KF_DEP_VERSION} REQUIRED)
0032
0033 #optional features
0034 find_package(X11)
0035 set(HAVE_X11 ${X11_FOUND})
0036
0037 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0038
0039 option(KDESU_USE_SUDO_DEFAULT "Set On to use sudo instead of su [default=Off]" Off)
0040 option(KDESU_USE_DOAS_DEFAULT "Set On to use doas instead of su and sudo [default=Off]" Off)
0041 if(KDESU_USE_SUDO_DEFAULT AND KDESU_USE_DOAS_DEFAULT)
0042    message(FATAL_ERROR "Choose between sudo(1) or doas(1)")
0043 elseif(KDESU_USE_SUDO_DEFAULT)
0044   message("Using sudo as default")
0045 elseif(KDESU_USE_DOAS_DEFAULT)
0046   message("Using doas as default")
0047 else()
0048   message("Using su as default (set KDESU_USE_SUDO_DEFAULT=On to use sudo)")
0049 endif()
0050
0051 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0052 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0053
0054 set(kdesu_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kdesu_version.h")
0055 ecm_setup_version(PROJECT VARIABLE_PREFIX KDESU
0056                         VERSION_HEADER "${kdesu_version_header}"
0057                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6SuConfigVersion.cmake"
0058                         SOVERSION 6)
0059 ecm_set_disabled_deprecation_versions(
0060     QT 6.5.0
0061     KF 5.240.0
0062 )
0063
0064 ki18n_install(po)
0065 add_subdirectory(src)
0066
0067 # create a Config.cmake and a ConfigVersion.cmake file and install them
0068 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Su")
0069
0070 if (BUILD_QCH)
0071     ecm_install_qch_export(
0072         TARGETS KF6Su_QCH
0073         FILE KF6SuQchTargets.cmake
0074         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0075         COMPONENT Devel
0076     )
0077     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6SuQchTargets.cmake\")")
0078 endif()
0079
0080 include(CMakePackageConfigHelpers)
0081
0082 configure_package_config_file(
0083   "${CMAKE_CURRENT_SOURCE_DIR}/KF6SuConfig.cmake.in"
0084   "${CMAKE_CURRENT_BINARY_DIR}/KF6SuConfig.cmake"
0085   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0086 )
0087
0088 install(FILES
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF6SuConfig.cmake"
0090   "${CMAKE_CURRENT_BINARY_DIR}/KF6SuConfigVersion.cmake"
0091   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0092   COMPONENT Devel
0093 )
0094
0095 install(EXPORT KF6SuTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6SuTargets.cmake NAMESPACE KF6:: )
0096
0097 install(FILES
0098    ${kdesu_version_header}
0099   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDESu COMPONENT Devel
0100 )
0101
0102 if(BUILD_TESTING)
0103   add_subdirectory(autotests)
0104 endif()
0105
0106 include(ECMFeatureSummary)
0107 ecm_feature_summary(WHAT ALL   FATAL_ON_MISSING_REQUIRED_PACKAGES)