kded/src/CMakeLists.txt

0001 add_executable(kded5)
0002
0003 target_sources(kded5 PRIVATE
0004     kded.cpp
0005     kdedadaptor.cpp
0006     ${CMAKE_CURRENT_BINARY_DIR}/org.kde.kded5.xml # just so that it gets generated
0007 )
0008
0009 ecm_qt_export_logging_category(
0010     IDENTIFIER KDED
0011     CATEGORY_NAME kf.kded
0012     OLD_CATEGORY_NAMES kf5.kded
0013     DEFAULT_SEVERITY Warning
0014     DESCRIPTION "KDED"
0015     EXPORT KDED
0016 )
0017
0018 ecm_mark_nongui_executable(kded5)
0019
0020 target_link_libraries(kded5
0021     Qt${QT_MAJOR_VERSION}::Widgets # QApplication
0022     KF5::Service # Needed for ksycoca.h
0023     KF5::CoreAddons # Needed for KDirWatch
0024     KF5::DBusAddons # Needed for kdedmodule.h
0025     KF5::Crash # Sets it as autostart
0026     KF5::ConfigCore
0027 )
0028 if(APPLE)
0029     target_link_libraries(kded5 "-framework CoreFoundation")
0030 endif()
0031 target_compile_definitions(kded5 PRIVATE
0032     KCONF_UPDATE_EXE="$<TARGET_FILE:KF5::kconf_update>"
0033 )
0034
0035 install(TARGETS kded5 ${KF_INSTALL_TARGETS_DEFAULT_ARGS} )
0036
0037 configure_file(plasma-kded.service.in
0038                ${CMAKE_CURRENT_BINARY_DIR}/plasma-kded.service @ONLY)
0039 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/plasma-kded.service
0040         DESTINATION ${KDE_INSTALL_SYSTEMDUSERUNITDIR})
0041
0042 qt_generate_dbus_interface( kdedadaptor.h org.kde.kded5.xml )
0043 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.kded5.xml DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR})
0044
0045 kdbusaddons_generate_dbus_service_file(kded5 org.kde.kded5 ${KDE_INSTALL_FULL_BINDIR})
0046
0047 if(QT_MAJOR_VERSION EQUAL "5")
0048     install( FILES kdedmodule.desktop DESTINATION  ${KDE_INSTALL_KSERVICETYPESDIR} )
0049 endif()
0050
0051 ecm_qt_install_logging_categories(
0052     EXPORT KDED
0053     FILE kded.categories
0054     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0055 )