kded/src/CMakeLists.txt

0001 add_executable(kded6)
0002
0003 target_sources(kded6 PRIVATE
0004     kded.cpp
0005     kdedadaptor.cpp
0006     ${CMAKE_CURRENT_BINARY_DIR}/org.kde.kded6.xml # just so that it gets generated
0007 )
0008
0009 ecm_qt_declare_logging_category(
0010     kded6
0011     HEADER kded_debug.h
0012     IDENTIFIER KDED
0013     CATEGORY_NAME kf.kded
0014     OLD_CATEGORY_NAMES kf5.kded
0015     DEFAULT_SEVERITY Warning
0016     DESCRIPTION "KDED"
0017     EXPORT KDED
0018 )
0019
0020 ecm_mark_nongui_executable(kded6)
0021
0022 target_link_libraries(kded6
0023     Qt6::Widgets # QApplication
0024     KF6::Service # Needed for ksycoca.h
0025     KF6::CoreAddons # Needed for KDirWatch
0026     KF6::DBusAddons # Needed for kdedmodule.h
0027     KF6::Crash # Sets it as autostart
0028     KF6::ConfigCore
0029 )
0030
0031 target_compile_definitions(kded6 PRIVATE
0032     KCONF_UPDATE_EXE="$<TARGET_FILE:KF6::kconf_update>"
0033 )
0034
0035 install(TARGETS kded6 ${KF_INSTALL_TARGETS_DEFAULT_ARGS} )
0036
0037 configure_file(plasma-kded6.service.in
0038                ${CMAKE_CURRENT_BINARY_DIR}/plasma-kded6.service @ONLY)
0039 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/plasma-kded6.service
0040         DESTINATION ${KDE_INSTALL_SYSTEMDUSERUNITDIR})
0041
0042 qt_generate_dbus_interface( kdedadaptor.h org.kde.kded6.xml )
0043 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.kded6.xml DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR})
0044
0045 kdbusaddons_generate_dbus_service_file(kded6 org.kde.kded6 ${KDE_INSTALL_FULL_BINDIR})
0046
0047 ecm_qt_install_logging_categories(
0048     EXPORT KDED
0049     FILE kded.categories
0050     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0051 )