kdbusaddons/src/CMakeLists.txt

0001 add_subdirectory(tools/kquitapp)
0002
0003 add_library(KF5DBusAddons)
0004 add_library(KF5::DBusAddons ALIAS KF5DBusAddons)
0005
0006 ecm_create_qm_loader(KF5DBusAddons kdbusaddons5_qt)
0007
0008 target_sources(KF5DBusAddons PRIVATE
0009     kdbusinterprocesslock.cpp
0010     kdbusinterprocesslock.h
0011     kdbusservice.cpp
0012     kdbusservice.h
0013     kdedmodule.cpp
0014     kdedmodule.h
0015     kdeinitinterface.cpp
0016     kdeinitinterface.h
0017     updatelaunchenvironmentjob.cpp
0018     updatelaunchenvironmentjob.h
0019 )
0020 if (QT_MAJOR_VERSION EQUAL "5")
0021     target_sources(KF5DBusAddons PRIVATE
0022         kdbusconnectionpool.cpp
0023         kdbusconnectionpool.h
0024     )
0025 endif()
0026
0027 ecm_qt_declare_logging_category(KF5DBusAddons
0028     HEADER kdbusaddons_debug.h
0029     IDENTIFIER KDBUSADDONS_LOG
0030     CATEGORY_NAME kf.dbusaddons
0031     OLD_CATEGORY_NAMES kf5.kdbusaddons
0032     DESCRIPTION "KDBusAddons"
0033     EXPORT KDBUSADDONS
0034 )
0035
0036 set(libkdbusaddons_dbus_SRCS)
0037 qt_add_dbus_interface(libkdbusaddons_dbus_SRCS org.freedesktop.Application.xml FreeDesktopApplpicationIface)
0038 qt_add_dbus_interface(libkdbusaddons_dbus_SRCS org.kde.KDBusService.xml KDBusServiceIface)
0039
0040 qt_add_dbus_adaptor(libkdbusaddons_dbus_SRCS
0041    org.freedesktop.Application.xml
0042    kdbusservice.h
0043    KDBusService
0044    kdbusservice_adaptor
0045    KDBusServiceAdaptor)
0046 qt_add_dbus_adaptor(libkdbusaddons_dbus_SRCS
0047    org.kde.KDBusService.xml
0048    kdbusservice.h
0049    KDBusService
0050    kdbusserviceextensions_adaptor
0051    KDBusServiceExtensionsAdaptor)
0052
0053 target_sources(KF5DBusAddons PRIVATE
0054     ${libkdbusaddons_dbus_SRCS}
0055 )
0056
0057 ecm_generate_export_header(KF5DBusAddons
0058     BASE_NAME KDBusAddons
0059     GROUP_BASE_NAME KF
0060     VERSION ${KF_VERSION}
0061     DEPRECATED_BASE_VERSION 0
0062     DEPRECATION_VERSIONS 5.68
0063     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0064 )
0065
0066 if(TARGET Qt5::X11Extras)
0067     set(_qt_x11_extras_libs Qt5::X11Extras)
0068 elseif(TARGET Qt6::Gui)
0069     set(_qt_x11_extras_libs Qt6::GuiPrivate) # qtx11extras_p.h
0070 endif()
0071
0072 target_link_libraries(KF5DBusAddons PUBLIC Qt${QT_MAJOR_VERSION}::DBus PRIVATE ${_qt_x11_extras_libs})
0073
0074 target_include_directories(KF5DBusAddons INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KDBusAddons>")
0075
0076 set_target_properties(KF5DBusAddons PROPERTIES VERSION   ${KDBUSADDONS_VERSION}
0077                                                SOVERSION ${KDBUSADDONS_SOVERSION}
0078                                                EXPORT_NAME DBusAddons
0079 )
0080
0081 configure_file(config-kdbusaddons.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kdbusaddons.h )
0082
0083 ecm_generate_headers(KDBusAddons_HEADERS
0084   HEADER_NAMES
0085   KDBusInterProcessLock
0086   KDBusService
0087   KDEDModule
0088   KDEInitInterface
0089   UpdateLaunchEnvironmentJob
0090   REQUIRED_HEADERS KDBusAddons_HEADERS
0091 )
0092 if (QT_MAJOR_VERSION EQUAL "5")
0093     ecm_generate_headers(KDBusAddons_Legacy_HEADERS
0094         HEADER_NAMES
0095         KDBusConnectionPool
0096         REQUIRED_HEADERS KDBusAddons_Legacy_HEADERS
0097     )
0098 endif()
0099
0100 install(TARGETS KF5DBusAddons EXPORT KF5DBusAddonsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0101
0102 install(FILES
0103     ${KDBusAddons_HEADERS}
0104     ${KDBusAddons_Legacy_HEADERS}
0105     ${CMAKE_CURRENT_BINARY_DIR}/kdbusaddons_export.h
0106     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDBusAddons COMPONENT Devel
0107 )
0108
0109 ecm_qt_install_logging_categories(
0110     EXPORT KDBUSADDONS
0111     FILE kdbusaddons.categories
0112     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0113 )
0114
0115 if(BUILD_QCH)
0116     ecm_add_qch(
0117         KF5DBusAddons_QCH
0118         NAME KDBusAddons
0119         BASE_NAME KF5DBusAddons
0120         VERSION ${KF_VERSION}
0121         ORG_DOMAIN org.kde
0122         SOURCES # using only public headers, to cover only public API
0123             ${KDBusAddons_HEADERS}
0124         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0125         LINK_QCHS
0126             Qt5DBus_QCH
0127             Qt5Core_QCH
0128         INCLUDE_DIRS
0129             ${CMAKE_CURRENT_BINARY_DIR}
0130         BLANK_MACROS
0131             KDBUSADDONS_EXPORT
0132             KDBUSADDONS_DEPRECATED
0133         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0134         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0135         COMPONENT Devel
0136     )
0137 endif()
0138
0139 include(ECMGeneratePriFile)
0140 ecm_generate_pri_file(BASE_NAME KDBusAddons LIB_NAME KF5DBusAddons DEPS "dbus" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KDBusAddons)
0141 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})