kdbusaddons/src/CMakeLists.txt

0001 add_subdirectory(tools/kquitapp)
0002
0003 add_library(KF6DBusAddons)
0004 add_library(KF6::DBusAddons ALIAS KF6DBusAddons)
0005
0006 set_target_properties(KF6DBusAddons PROPERTIES
0007     VERSION     ${KDBUSADDONS_VERSION}
0008     SOVERSION   ${KDBUSADDONS_SOVERSION}
0009     EXPORT_NAME DBusAddons
0010 )
0011
0012 ecm_create_qm_loader(KF6DBusAddons kdbusaddons6_qt)
0013
0014 target_sources(KF6DBusAddons PRIVATE
0015     kdbusservice.cpp
0016     kdbusservice.h
0017     kdedmodule.cpp
0018     kdedmodule.h
0019     kupdatelaunchenvironmentjob.cpp
0020     kupdatelaunchenvironmentjob.h
0021 )
0022
0023 ecm_qt_declare_logging_category(KF6DBusAddons
0024     HEADER kdbusaddons_debug.h
0025     IDENTIFIER KDBUSADDONS_LOG
0026     CATEGORY_NAME kf.dbusaddons
0027     OLD_CATEGORY_NAMES kf5.kdbusaddons
0028     DESCRIPTION "KDBusAddons"
0029     EXPORT KDBUSADDONS
0030 )
0031
0032 set(libkdbusaddons_dbus_SRCS)
0033 qt_add_dbus_interface(libkdbusaddons_dbus_SRCS org.freedesktop.Application.xml FreeDesktopApplpicationIface)
0034 qt_add_dbus_interface(libkdbusaddons_dbus_SRCS org.kde.KDBusService.xml KDBusServiceIface)
0035
0036 qt_add_dbus_adaptor(libkdbusaddons_dbus_SRCS
0037    org.freedesktop.Application.xml
0038    kdbusservice.h
0039    KDBusService
0040    kdbusservice_adaptor
0041    KDBusServiceAdaptor)
0042 qt_add_dbus_adaptor(libkdbusaddons_dbus_SRCS
0043    org.kde.KDBusService.xml
0044    kdbusservice.h
0045    KDBusService
0046    kdbusserviceextensions_adaptor
0047    KDBusServiceExtensionsAdaptor)
0048
0049 target_sources(KF6DBusAddons PRIVATE
0050     ${libkdbusaddons_dbus_SRCS}
0051 )
0052
0053 ecm_generate_export_header(KF6DBusAddons
0054     BASE_NAME KDBusAddons
0055     GROUP_BASE_NAME KF
0056     VERSION ${KF_VERSION}
0057     USE_VERSION_HEADER
0058     DEPRECATED_BASE_VERSION 0
0059     DEPRECATION_VERSIONS
0060     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0061 )
0062
0063 if(TARGET Qt6::Gui)
0064     set(_qt_x11_extras_libs Qt6::GuiPrivate) # qtx11extras_p.h
0065 endif()
0066
0067 target_link_libraries(KF6DBusAddons PUBLIC Qt6::DBus PRIVATE ${_qt_x11_extras_libs})
0068
0069 target_include_directories(KF6DBusAddons INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KDBusAddons>")
0070
0071 configure_file(config-kdbusaddons.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kdbusaddons.h )
0072
0073 ecm_generate_headers(KDBusAddons_HEADERS
0074   HEADER_NAMES
0075   KDBusService
0076   KDEDModule
0077   KUpdateLaunchEnvironmentJob
0078   REQUIRED_HEADERS KDBusAddons_HEADERS
0079 )
0080
0081 install(TARGETS KF6DBusAddons EXPORT KF6DBusAddonsTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0082
0083 install(FILES
0084     ${KDBusAddons_HEADERS}
0085     ${CMAKE_CURRENT_BINARY_DIR}/kdbusaddons_export.h
0086     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KDBusAddons COMPONENT Devel
0087 )
0088
0089 ecm_qt_install_logging_categories(
0090     EXPORT KDBUSADDONS
0091     FILE kdbusaddons.categories
0092     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0093 )
0094
0095 if(BUILD_QCH)
0096     ecm_add_qch(
0097         KF6DBusAddons_QCH
0098         NAME KDBusAddons
0099         BASE_NAME KF6DBusAddons
0100         VERSION ${KF_VERSION}
0101         ORG_DOMAIN org.kde
0102         SOURCES # using only public headers, to cover only public API
0103             ${KDBusAddons_HEADERS}
0104         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0105         LINK_QCHS
0106             Qt6DBus_QCH
0107             Qt6Core_QCH
0108         INCLUDE_DIRS
0109             ${CMAKE_CURRENT_BINARY_DIR}
0110         BLANK_MACROS
0111             KDBUSADDONS_EXPORT
0112             KDBUSADDONS_DEPRECATED
0113         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0114         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0115         COMPONENT Devel
0116     )
0117 endif()
0118