frameworks/kcrash/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KCrash VERSION ${KF_VERSION})
0006
0007 set(CMAKE_CXX_STANDARD 20)
0008 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0009
0010 include(FeatureSummary)
0011 find_package(ECM 5.249.0  NO_MODULE)
0012 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0013 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0014
0015 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0016
0017 include(KDEInstallDirs)
0018 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0019 include(KDECMakeSettings)
0020 include(KDEGitCommitHooks)
0021 include(ECMDeprecationSettings)
0022
0023 set(REQUIRED_QT_VERSION 6.5.0)
0024 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core Gui)
0025
0026 if (UNIX AND NOT APPLE AND NOT ANDROID)
0027     option(WITH_X11 "Build with X11 integration" ON)
0028 else()
0029     set(WITH_X11 OFF)
0030 endif()
0031
0032 if (WITH_X11)
0033     find_package(X11 REQUIRED)
0034     set(HAVE_X11 TRUE)
0035 endif()
0036 find_package(Qt6Test ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0037 include(ECMGenerateExportHeader)
0038 include(ECMSetupVersion)
0039 include(ECMGenerateHeaders)
0040 include(ECMAddQch)
0041 include(ECMQtDeclareLoggingCategory)
0042
0043 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0044 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0045
0046 set(kcrash_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kcrash_version.h")
0047 ecm_setup_version(PROJECT VARIABLE_PREFIX KCRASH
0048                         VERSION_HEADER "${kcrash_version_header}"
0049                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6CrashConfigVersion.cmake"
0050                         SOVERSION 6)
0051
0052 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0053
0054 set(KCRASH_CORE_PATTERN_RAISE_DEFAULT ON)
0055
0056 option(KCRASH_CORE_PATTERN_RAISE
0057     "Enables raising signals to kernel core patterns (iff the pattern is a process). You may wish to not install drkonqi if this can cause a UI conflict."
0058     ${KCRASH_CORE_PATTERN_RAISE_DEFAULT})
0059 add_feature_info("Core Pattern Raising"
0060     KCRASH_CORE_PATTERN_RAISE
0061     "Raising signals to kernel core patterns (iff the pattern is a process). You may wish to not install drkonqi if this can cause a UI conflict.")
0062
0063 ecm_set_disabled_deprecation_versions(
0064     QT 6.5
0065     KF 5.102.0
0066 )
0067
0068 add_subdirectory(src)
0069 if (BUILD_TESTING)
0070     add_subdirectory(autotests)
0071 endif()
0072
0073 # create a Config.cmake and a ConfigVersion.cmake file and install them
0074 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6Crash")
0075
0076 if (BUILD_QCH)
0077     ecm_install_qch_export(
0078         TARGETS KF6Crash_QCH
0079         FILE KF6CrashQchTargets.cmake
0080         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0081         COMPONENT Devel
0082     )
0083     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6CrashQchTargets.cmake\")")
0084 endif()
0085
0086 include(CMakePackageConfigHelpers)
0087
0088 configure_package_config_file(
0089   "${CMAKE_CURRENT_SOURCE_DIR}/KF6CrashConfig.cmake.in"
0090   "${CMAKE_CURRENT_BINARY_DIR}/KF6CrashConfig.cmake"
0091   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0092 )
0093
0094 install(FILES
0095   "${CMAKE_CURRENT_BINARY_DIR}/KF6CrashConfig.cmake"
0096   "${CMAKE_CURRENT_BINARY_DIR}/KF6CrashConfigVersion.cmake"
0097   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0098   COMPONENT Devel
0099 )
0100
0101 install(EXPORT KF6CrashTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6CrashTargets.cmake NAMESPACE KF6:: )
0102
0103 install(FILES
0104    ${kcrash_version_header}
0105   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCrash COMPONENT Devel
0106 )
0107
0108 include(ECMFeatureSummary)
0109 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0110
0111 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)