frameworks/kcrash/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.116.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.115.0") # handled by release scripts
0005 project(KCrash VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.115.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018 include(ECMDeprecationSettings)
0019
0020 set(REQUIRED_QT_VERSION 5.15.2)
0021 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core Gui)
0022
0023 if (UNIX AND NOT APPLE AND NOT ANDROID)
0024     option(WITH_X11 "Build with X11 integration" ON)
0025 else()
0026     set(WITH_X11 OFF)
0027 endif()
0028
0029 if (WITH_X11)
0030     find_package(X11 REQUIRED)
0031     if (QT_MAJOR_VERSION STREQUAL "5")
0032         find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED X11Extras)
0033     endif()
0034     set(HAVE_X11 TRUE)
0035 endif()
0036 find_package(Qt${QT_MAJOR_VERSION}Test ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0037 include(GenerateExportHeader)
0038 include(ECMSetupVersion)
0039 include(ECMGenerateHeaders)
0040 include(ECMAddQch)
0041 include(ECMQtDeclareLoggingCategory)
0042
0043 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0044 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0045
0046 ecm_setup_version(PROJECT VARIABLE_PREFIX KCrash
0047                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/kcrash_version.h"
0048                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5CrashConfigVersion.cmake"
0049                         SOVERSION 5)
0050
0051 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0052
0053 set(KCRASH_CORE_PATTERN_RAISE_DEFAULT ON)
0054
0055 option(KCRASH_CORE_PATTERN_RAISE
0056     "Enables raising signals to kernel core patterns (iff the pattern is a process). You may wish to not install drkonqi if this can cause a UI conflict."
0057     ${KCRASH_CORE_PATTERN_RAISE_DEFAULT})
0058 add_feature_info("Core Pattern Raising"
0059     KCRASH_CORE_PATTERN_RAISE
0060     "Raising signals to kernel core patterns (iff the pattern is a process). You may wish to not install drkonqi if this can cause a UI conflict.")
0061
0062 ecm_set_disabled_deprecation_versions(
0063     QT 5.15.2
0064     KF 5.95.0
0065 )
0066
0067 add_subdirectory(src)
0068 if (BUILD_TESTING)
0069     add_subdirectory(autotests)
0070 endif()
0071
0072 # create a Config.cmake and a ConfigVersion.cmake file and install them
0073 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Crash")
0074
0075 if (BUILD_QCH)
0076     ecm_install_qch_export(
0077         TARGETS KF5Crash_QCH
0078         FILE KF5CrashQchTargets.cmake
0079         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0080         COMPONENT Devel
0081     )
0082     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5CrashQchTargets.cmake\")")
0083 endif()
0084
0085 include(CMakePackageConfigHelpers)
0086
0087 configure_package_config_file(
0088   "${CMAKE_CURRENT_SOURCE_DIR}/KF5CrashConfig.cmake.in"
0089   "${CMAKE_CURRENT_BINARY_DIR}/KF5CrashConfig.cmake"
0090   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0091 )
0092
0093 install(FILES
0094   "${CMAKE_CURRENT_BINARY_DIR}/KF5CrashConfig.cmake"
0095   "${CMAKE_CURRENT_BINARY_DIR}/KF5CrashConfigVersion.cmake"
0096   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0097   COMPONENT Devel
0098 )
0099
0100 install(EXPORT KF5CrashTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5CrashTargets.cmake NAMESPACE KF5:: )
0101
0102 install(FILES
0103    ${CMAKE_CURRENT_BINARY_DIR}/src/kcrash_version.h
0104   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCrash COMPONENT Devel
0105 )
0106
0107 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0108
0109 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)