frameworks/kconfigwidgets/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "5.107.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.106.0") # handled by release scripts
0005 project(KConfigWidgets VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.106.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMSetupVersion)
0021 include(ECMGenerateHeaders)
0022 include(ECMAddQch)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMDeprecationSettings)
0025 include(CMakeDependentOption)
0026
0027 set(REQUIRED_QT_VERSION 5.15.2)
0028 find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0029 if (NOT ANDROID)
0030   find_package(Qt${QT_MAJOR_VERSION} ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0031 endif()
0032
0033 set(_qt6_core5_compat FALSE)
0034 if (QT_MAJOR_VERSION STREQUAL "6")
0035     find_package(Qt6Core5Compat CONFIG REQUIRED) # QTextCodec
0036     set(_qt6_core5_compat ${Qt6Core5Compat_FOUND})
0037 endif()
0038
0039 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0040
0041 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0042 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0043
0044 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0045 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0046
0047 ecm_setup_version(PROJECT VARIABLE_PREFIX KCONFIGWIDGETS
0048                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kconfigwidgets_version.h"
0049                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigWidgetsConfigVersion.cmake"
0050                         SOVERSION 5)
0051 find_package(KF5CoreAddons ${KF_DEP_VERSION} REQUIRED)
0052 find_package(KF5Codecs ${KF_DEP_VERSION} REQUIRED)
0053 find_package(KF5Config ${KF_DEP_VERSION} REQUIRED)
0054 find_package(KF5DocTools ${KF_DEP_VERSION})
0055 find_package(KF5GuiAddons ${KF_DEP_VERSION} REQUIRED)
0056 find_package(KF5I18n ${KF_DEP_VERSION} REQUIRED)
0057 find_package(KF5WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0058
0059 if (NOT ANDROID AND NOT WIN32)
0060     option(WITH_KAUTH "Build with KAuth support" ON)
0061 else()
0062     set(WITH_KAUTH OFF)
0063 endif()
0064
0065 set(HAVE_KAUTH FALSE)
0066 if (WITH_KAUTH)
0067   find_package(KF5Auth ${KF_DEP_VERSION} REQUIRED)
0068   set(HAVE_KAUTH TRUE)
0069 endif()
0070
0071 ecm_set_disabled_deprecation_versions(
0072     QT 5.15.2
0073     KF 5.97.0
0074     KWIDGETSADDONS 5.77.0  # We need KSelectAction::triggered(QString)
0075 )
0076
0077 add_definitions(-DTRANSLATION_DOMAIN=\"kconfigwidgets5\")
0078 ki18n_install(po)
0079 if (KF5DocTools_FOUND)
0080     kdoctools_install(po)
0081 endif()
0082
0083 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0084     file(GLOB lang_dirs "po/*")
0085     foreach(lang_dir ${lang_dirs})
0086        get_filename_component(lang ${lang_dir} NAME)
0087        if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/po/${lang}/kf5_entry.desktop")
0088           install( FILES po/${lang}/kf5_entry.desktop DESTINATION ${KDE_INSTALL_LOCALEDIR}/${lang} )
0089        endif()
0090     endforeach()
0091 endif()
0092
0093 if (KF5DocTools_FOUND)
0094     add_subdirectory(docs)
0095 endif()
0096
0097 add_subdirectory(src)
0098 if (BUILD_TESTING)
0099     add_subdirectory(tests)
0100     add_subdirectory(autotests)
0101 endif()
0102
0103 # create a Config.cmake and a ConfigVersion.cmake file and install them
0104 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5ConfigWidgets")
0105
0106 if (BUILD_QCH)
0107     ecm_install_qch_export(
0108         TARGETS KF5ConfigWidgets_QCH
0109         FILE KF5ConfigWidgetsQchTargets.cmake
0110         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0111         COMPONENT Devel
0112     )
0113     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5ConfigWidgetsQchTargets.cmake\")")
0114 endif()
0115
0116 include(CMakePackageConfigHelpers)
0117
0118 configure_package_config_file(
0119   "${CMAKE_CURRENT_SOURCE_DIR}/KF5ConfigWidgetsConfig.cmake.in"
0120   "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigWidgetsConfig.cmake"
0121   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0122 )
0123
0124 install(FILES
0125   "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigWidgetsConfig.cmake"
0126   "${CMAKE_CURRENT_BINARY_DIR}/KF5ConfigWidgetsConfigVersion.cmake"
0127   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0128   COMPONENT Devel
0129 )
0130
0131 install(EXPORT KF5ConfigWidgetsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5ConfigWidgetsTargets.cmake NAMESPACE KF5:: )
0132
0133 install(FILES
0134    ${CMAKE_CURRENT_BINARY_DIR}/kconfigwidgets_version.h
0135   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigWidgets COMPONENT Devel
0136 )
0137
0138 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0139
0140 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)