frameworks/kconfigwidgets/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(KF_VERSION "6.0.0") # handled by release scripts
0004 set(KF_DEP_VERSION "5.249.0") # handled by release scripts
0005 project(KConfigWidgets VERSION ${KF_VERSION})
0006
0007 include(FeatureSummary)
0008 find_package(ECM 5.249.0  NO_MODULE)
0009 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
0010 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
0011
0012 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0013
0014 include(KDEInstallDirs)
0015 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
0016 include(KDECMakeSettings)
0017 include(KDEGitCommitHooks)
0018
0019 include(ECMGenerateExportHeader)
0020 include(ECMSetupVersion)
0021 include(ECMGenerateHeaders)
0022 include(ECMAddQch)
0023 include(ECMQtDeclareLoggingCategory)
0024 include(ECMDeprecationSettings)
0025 include(CMakeDependentOption)
0026
0027 set(REQUIRED_QT_VERSION 6.5.0)
0028 find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
0029 set(HAVE_DBUS false)
0030 if (NOT ANDROID)
0031   find_package(Qt6 ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
0032   set(HAVE_DBUS true)
0033 endif()
0034
0035 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0036
0037 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0038 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0039
0040 cmake_dependent_option(BUILD_DESIGNERPLUGIN "Build plugin for Qt Designer" ON "NOT CMAKE_CROSSCOMPILING" OFF)
0041 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Build plugin for Qt Designer")
0042
0043 set(kconfigwidgets_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/kconfigwidgets_version.h")
0044 ecm_setup_version(PROJECT VARIABLE_PREFIX KCONFIGWIDGETS
0045                         VERSION_HEADER "${kconfigwidgets_version_header}"
0046                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF6ConfigWidgetsConfigVersion.cmake"
0047                         SOVERSION 6)
0048 find_package(KF6CoreAddons ${KF_DEP_VERSION} REQUIRED)
0049 find_package(KF6Codecs ${KF_DEP_VERSION} REQUIRED)
0050 find_package(KF6Config ${KF_DEP_VERSION} REQUIRED)
0051 find_package(KF6GuiAddons ${KF_DEP_VERSION} REQUIRED)
0052 find_package(KF6I18n ${KF_DEP_VERSION} REQUIRED)
0053 find_package(KF6WidgetsAddons ${KF_DEP_VERSION} REQUIRED)
0054 find_package(KF6ColorScheme ${KF_DEP_VERSION} REQUIRED)
0055
0056
0057 ecm_set_disabled_deprecation_versions(
0058     QT 6.5.0
0059     KF 5.102.0
0060 )
0061
0062 add_definitions(-DTRANSLATION_DOMAIN=\"kconfigwidgets6\")
0063 ki18n_install(po)
0064
0065 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0066     file(GLOB lang_dirs "po/*")
0067     foreach(lang_dir ${lang_dirs})
0068        get_filename_component(lang ${lang_dir} NAME)
0069        if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/po/${lang}/kf6_entry.desktop")
0070           install( FILES po/${lang}/kf6_entry.desktop DESTINATION ${KDE_INSTALL_LOCALEDIR}/${lang} )
0071        endif()
0072     endforeach()
0073 endif()
0074
0075 add_subdirectory(src)
0076 if (BUILD_TESTING)
0077     add_subdirectory(tests)
0078     add_subdirectory(autotests)
0079 endif()
0080
0081 # create a Config.cmake and a ConfigVersion.cmake file and install them
0082 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF6ConfigWidgets")
0083
0084 if (BUILD_QCH)
0085     ecm_install_qch_export(
0086         TARGETS KF6ConfigWidgets_QCH
0087         FILE KF6ConfigWidgetsQchTargets.cmake
0088         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0089         COMPONENT Devel
0090     )
0091     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF6ConfigWidgetsQchTargets.cmake\")")
0092 endif()
0093
0094 include(CMakePackageConfigHelpers)
0095
0096 configure_package_config_file(
0097   "${CMAKE_CURRENT_SOURCE_DIR}/KF6ConfigWidgetsConfig.cmake.in"
0098   "${CMAKE_CURRENT_BINARY_DIR}/KF6ConfigWidgetsConfig.cmake"
0099   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0100 )
0101
0102 install(FILES
0103   "${CMAKE_CURRENT_BINARY_DIR}/KF6ConfigWidgetsConfig.cmake"
0104   "${CMAKE_CURRENT_BINARY_DIR}/KF6ConfigWidgetsConfigVersion.cmake"
0105   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0106   COMPONENT Devel
0107 )
0108
0109 install(EXPORT KF6ConfigWidgetsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF6ConfigWidgetsTargets.cmake NAMESPACE KF6:: )
0110
0111 install(FILES
0112    ${kconfigwidgets_version_header}
0113   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigWidgets COMPONENT Devel
0114 )
0115
0116 include(ECMFeatureSummary)
0117 ecm_feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0118
0119 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)