src/gui/CMakeLists.txt

0001 add_library(KF5ConfigGui)
0002 add_library(KF5::ConfigGui ALIAS KF5ConfigGui)
0003
0004 ecm_create_qm_loader(KF5ConfigGui kconfig5_qt)
0005
0006 target_sources(KF5ConfigGui PRIVATE
0007     kconfiggui.cpp
0008     kconfiggroupgui.cpp
0009     kconfigloader.cpp
0010     kconfigskeleton.cpp
0011     kstandardshortcut.cpp
0012     kstandardshortcutwatcher.cpp
0013     kwindowconfig.cpp
0014     kwindowstatesaver.cpp
0015 )
0016
0017 ecm_qt_declare_logging_category(KF5ConfigGui
0018     HEADER kconfig_gui_log_settings.h
0019     IDENTIFIER KCONFIG_GUI_LOG
0020     CATEGORY_NAME kf.config.gui
0021     DESCRIPTION "KConfig Gui"
0022     EXPORT KCONFIG
0023 )
0024
0025 ecm_generate_export_header(KF5ConfigGui
0026     BASE_NAME KConfigGui
0027     GROUP_BASE_NAME KF
0028     VERSION ${KF_VERSION}
0029     DEPRECATED_BASE_VERSION 0
0030     DEPRECATION_VERSIONS 5.11 5.39 5.71 5.82
0031     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0032 )
0033
0034 target_include_directories(KF5ConfigGui
0035     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfig;${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui>")
0036
0037 target_link_libraries(KF5ConfigGui PUBLIC Qt${QT_MAJOR_VERSION}::Gui Qt${QT_MAJOR_VERSION}::Xml KF5::ConfigCore)
0038
0039 set_target_properties(KF5ConfigGui PROPERTIES VERSION   ${KCONFIG_VERSION}
0040                                               SOVERSION ${KCONFIG_SOVERSION}
0041                                               EXPORT_NAME ConfigGui
0042 )
0043
0044 ecm_generate_headers(KConfigGui_HEADERS
0045   HEADER_NAMES
0046   KConfigGui
0047   KConfigLoader
0048   KConfigSkeleton
0049   KStandardShortcut
0050   KStandardShortcutWatcher
0051   KWindowConfig
0052   KWindowStateSaver
0053
0054    REQUIRED_HEADERS KConfigGui_HEADERS
0055 )
0056
0057 if (NOT BUILD_SHARED_LIBS)
0058     target_sources(KF5ConfigGui PUBLIC
0059         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/kconfigguistaticinitializer.cpp>
0060         $<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui/kconfigguistaticinitializer.cpp>
0061     )
0062 endif()
0063
0064 install(TARGETS KF5ConfigGui EXPORT KF5ConfigTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0065
0066 install(FILES
0067   ${CMAKE_CURRENT_BINARY_DIR}/kconfiggui_export.h
0068   ${KConfigGui_HEADERS}
0069   kconfigguistaticinitializer.cpp
0070   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui COMPONENT Devel
0071 )
0072
0073 # make available to ecm_add_qch in parent folder
0074 set(KConfigGui_APIDOX_SRCS ${KConfigGui_HEADERS} PARENT_SCOPE)
0075 set(KConfigGui_APIDOX_INCLUDE_DIRS ${CMAKE_CURRENT_BINARY_DIR} PARENT_SCOPE)
0076
0077 include(ECMGeneratePriFile)
0078 ecm_generate_pri_file(BASE_NAME KConfigGui LIB_NAME KF5ConfigGui DEPS "gui xml KConfigCore" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui)
0079 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})