src/gui/CMakeLists.txt

0001 add_library(KF6ConfigGui)
0002 add_library(KF6::ConfigGui ALIAS KF6ConfigGui)
0003
0004 set_target_properties(KF6ConfigGui PROPERTIES
0005     VERSION     ${KCONFIG_VERSION}
0006     SOVERSION   ${KCONFIG_SOVERSION}
0007     EXPORT_NAME ConfigGui
0008 )
0009
0010 ecm_create_qm_loader(KF6ConfigGui kconfig6_qt)
0011
0012 target_sources(KF6ConfigGui PRIVATE
0013     kconfiggui.cpp
0014     kconfiggroupgui.cpp
0015     kconfigloader.cpp
0016     kconfigskeleton.cpp
0017     kstandardshortcut.cpp
0018     kstandardshortcutwatcher.cpp
0019     kwindowconfig.cpp
0020     kwindowstatesaver.cpp
0021 )
0022
0023 ecm_qt_declare_logging_category(KF6ConfigGui
0024     HEADER kconfig_gui_log_settings.h
0025     IDENTIFIER KCONFIG_GUI_LOG
0026     CATEGORY_NAME kf.config.gui
0027     DESCRIPTION "KConfig Gui"
0028     EXPORT KCONFIG
0029 )
0030
0031 ecm_generate_export_header(KF6ConfigGui
0032     BASE_NAME KConfigGui
0033     GROUP_BASE_NAME KF
0034     VERSION ${KF_VERSION}
0035     USE_VERSION_HEADER
0036     VERSION_BASE_NAME KConfig
0037     DEPRECATED_BASE_VERSION 0
0038     DEPRECATION_VERSIONS
0039     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0040 )
0041
0042 target_include_directories(KF6ConfigGui
0043     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfig;${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui>")
0044
0045 target_link_libraries(KF6ConfigGui PUBLIC Qt6::Gui KF6::ConfigCore)
0046
0047 ecm_generate_headers(KConfigGui_HEADERS
0048   HEADER_NAMES
0049   KConfigGui
0050   KConfigLoader
0051   KConfigSkeleton
0052   KStandardShortcut
0053   KStandardShortcutWatcher
0054   KWindowConfig
0055   KWindowStateSaver
0056
0057    REQUIRED_HEADERS KConfigGui_HEADERS
0058 )
0059
0060 if (NOT BUILD_SHARED_LIBS)
0061     target_sources(KF6ConfigGui PUBLIC
0062         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/kconfigguistaticinitializer.cpp>
0063         $<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui/kconfigguistaticinitializer.cpp>
0064     )
0065 endif()
0066
0067 install(TARGETS KF6ConfigGui EXPORT KF6ConfigTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0068
0069 install(FILES
0070   ${CMAKE_CURRENT_BINARY_DIR}/kconfiggui_export.h
0071   ${KConfigGui_HEADERS}
0072   kconfigguistaticinitializer.cpp
0073   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KConfigGui COMPONENT Devel
0074 )
0075
0076 # make available to ecm_add_qch in parent folder
0077 set(KConfigGui_APIDOX_SRCS ${KConfigGui_HEADERS} PARENT_SCOPE)
0078 set(KConfigGui_APIDOX_INCLUDE_DIRS ${CMAKE_CURRENT_BINARY_DIR} PARENT_SCOPE)
0079