kcompletion/src/CMakeLists.txt

0001 add_library(KF5Completion)
0002 add_library(KF5::Completion ALIAS KF5Completion)
0003
0004 ecm_create_qm_loader(KF5Completion kcompletion5_qt)
0005
0006 target_sources(KF5Completion PRIVATE
0007     kcombobox.cpp
0008     kcombobox.h
0009     kcombobox_p.h
0010     kcompletionbase.cpp
0011     kcompletionbase.h
0012     kcompletionbox.cpp
0013     kcompletionbox.h
0014     kcompletion.cpp
0015     kcompletion.h
0016     kcompletionmatches.cpp
0017     kcompletionmatches.h
0018     kcompletion_p.h
0019     khistorycombobox.cpp
0020     khistorycombobox.h
0021     klineedit.cpp
0022     klineedit.h
0023     klineedit_p.h
0024     kpixmapprovider.cpp
0025     kpixmapprovider.h
0026     ksortablelist.h
0027     kzoneallocator.cpp
0028     kzoneallocator_p.h
0029 )
0030
0031 ecm_qt_declare_logging_category(KF5Completion
0032     HEADER kcompletion_debug.h
0033     IDENTIFIER KCOMPLETION_LOG
0034     CATEGORY_NAME kf.completion
0035     DESCRIPTION "KCompletion"
0036     EXPORT KCOMPLETION
0037 )
0038
0039 ecm_generate_export_header(KF5Completion
0040     BASE_NAME KCompletion
0041     GROUP_BASE_NAME KF
0042     VERSION ${KF_VERSION}
0043     DEPRECATED_BASE_VERSION 0
0044     DEPRECATION_VERSIONS 4.0 4.5 5.0 5.46 5.66 5.81 5.83
0045     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0046 )
0047
0048 target_include_directories(KF5Completion INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KCompletion>")
0049
0050 target_link_libraries(KF5Completion PUBLIC Qt${QT_MAJOR_VERSION}::Widgets
0051                                     PRIVATE KF5::ConfigCore      # KConfigGroup, used in many places
0052                                             KF5::ConfigGui       # KStandardShortcut
0053                                             KF5::WidgetsAddons   # KCursor
0054 )
0055
0056 set_target_properties(KF5Completion PROPERTIES VERSION   ${KCOMPLETION_VERSION}
0057                                                SOVERSION ${KCOMPLETION_SOVERSION}
0058                                                EXPORT_NAME Completion
0059 )
0060
0061 ecm_generate_headers(KCompletion_HEADERS
0062   HEADER_NAMES
0063   KComboBox
0064   KCompletion
0065   KCompletionBase
0066   KCompletionBox
0067   KLineEdit
0068   KHistoryComboBox
0069   KPixmapProvider
0070   KSortableList
0071   KCompletionMatches
0072
0073   REQUIRED_HEADERS KCompletion_HEADERS
0074 )
0075
0076 install(TARGETS KF5Completion EXPORT KF5CompletionTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0077
0078 install(FILES
0079   ${CMAKE_CURRENT_BINARY_DIR}/kcompletion_export.h
0080   ${KCompletion_HEADERS}
0081   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCompletion COMPONENT Devel
0082 )
0083
0084 if(BUILD_DESIGNERPLUGIN)
0085     add_subdirectory(designer)
0086 endif()
0087
0088 if(BUILD_QCH)
0089     ecm_add_qch(
0090         KF5Completion_QCH
0091         NAME KCompletion
0092         BASE_NAME KF5Completion
0093         VERSION ${KF_VERSION}
0094         ORG_DOMAIN org.kde
0095         SOURCES # using only public headers, to cover only public API
0096             ${KCompletion_HEADERS}
0097         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0098         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0099         LINK_QCHS
0100             Qt5Core_QCH
0101             Qt5Gui_QCH
0102             Qt5Widgets_QCH
0103         INCLUDE_DIRS
0104             ${CMAKE_CURRENT_BINARY_DIR}
0105         BLANK_MACROS
0106             KCOMPLETION_EXPORT
0107             KCOMPLETION_DEPRECATED
0108             "KCOMPLETION_DEPRECATED_VERSION(x, y, t)"
0109         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0110         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0111         COMPONENT Devel
0112     )
0113 endif()
0114
0115 include(ECMGeneratePriFile)
0116 ecm_generate_pri_file(BASE_NAME KCompletion LIB_NAME KF5Completion DEPS "widgets" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KCompletion)
0117 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0118
0119 ecm_qt_install_logging_categories(
0120     EXPORT KCOMPLETION
0121     FILE kcompletion.categories
0122     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0123 )