kcompletion/src/CMakeLists.txt

0001 add_library(KF6Completion)
0002 add_library(KF6::Completion ALIAS KF6Completion)
0003
0004 set_target_properties(KF6Completion PROPERTIES
0005     VERSION     ${KCOMPLETION_VERSION}
0006     SOVERSION   ${KCOMPLETION_SOVERSION}
0007     EXPORT_NAME Completion
0008 )
0009
0010 ecm_create_qm_loader(KF6Completion kcompletion6_qt)
0011
0012 target_sources(KF6Completion PRIVATE
0013     kcombobox.cpp
0014     kcombobox.h
0015     kcombobox_p.h
0016     kcompletionbase.cpp
0017     kcompletionbase.h
0018     kcompletionbox.cpp
0019     kcompletionbox.h
0020     kcompletion.cpp
0021     kcompletion.h
0022     kcompletionmatches.cpp
0023     kcompletionmatches.h
0024     kcompletion_p.h
0025     kemailvalidator.cpp
0026     kemailvalidator.h
0027     khistorycombobox.cpp
0028     khistorycombobox.h
0029     klineedit.cpp
0030     klineedit.h
0031     klineedit_p.h
0032     ksortablelist.h
0033     kzoneallocator.cpp
0034     kzoneallocator_p.h
0035 )
0036
0037 ecm_qt_declare_logging_category(KF6Completion
0038     HEADER kcompletion_debug.h
0039     IDENTIFIER KCOMPLETION_LOG
0040     CATEGORY_NAME kf.completion
0041     DESCRIPTION "KCompletion"
0042     EXPORT KCOMPLETION
0043 )
0044
0045 ecm_generate_export_header(KF6Completion
0046     BASE_NAME KCompletion
0047     GROUP_BASE_NAME KF
0048     VERSION ${KF_VERSION}
0049     USE_VERSION_HEADER
0050     DEPRECATED_BASE_VERSION 0
0051     DEPRECATION_VERSIONS
0052     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0053 )
0054
0055 target_include_directories(KF6Completion INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KCompletion>")
0056
0057 target_link_libraries(KF6Completion PUBLIC Qt6::Widgets
0058                                     PRIVATE KF6::ConfigCore      # KConfigGroup, used in many places
0059                                             KF6::ConfigGui       # KStandardShortcut
0060                                             KF6::WidgetsAddons   # KCursor
0061                                             KF6::Codecs # KEmailAddress
0062 )
0063
0064 ecm_generate_headers(KCompletion_HEADERS
0065   HEADER_NAMES
0066   KComboBox
0067   KCompletion
0068   KCompletionBase
0069   KCompletionBox
0070   KEmailValidator
0071   KLineEdit
0072   KHistoryComboBox
0073   KSortableList
0074   KCompletionMatches
0075
0076   REQUIRED_HEADERS KCompletion_HEADERS
0077 )
0078
0079 install(TARGETS KF6Completion EXPORT KF6CompletionTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0080
0081 install(FILES
0082   ${CMAKE_CURRENT_BINARY_DIR}/kcompletion_export.h
0083   ${KCompletion_HEADERS}
0084   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KCompletion COMPONENT Devel
0085 )
0086
0087 if(BUILD_DESIGNERPLUGIN)
0088     add_subdirectory(designer)
0089 endif()
0090
0091 if(BUILD_QCH)
0092     ecm_add_qch(
0093         KF6Completion_QCH
0094         NAME KCompletion
0095         BASE_NAME KF6Completion
0096         VERSION ${KF_VERSION}
0097         ORG_DOMAIN org.kde
0098         SOURCES # using only public headers, to cover only public API
0099             ${KCompletion_HEADERS}
0100         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0101         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0102         LINK_QCHS
0103             Qt6Core_QCH
0104             Qt6Gui_QCH
0105             Qt6Widgets_QCH
0106         INCLUDE_DIRS
0107             ${CMAKE_CURRENT_BINARY_DIR}
0108         BLANK_MACROS
0109             KCOMPLETION_EXPORT
0110             KCOMPLETION_DEPRECATED
0111             "KCOMPLETION_DEPRECATED_VERSION(x, y, t)"
0112         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0113         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0114         COMPONENT Devel
0115     )
0116 endif()
0117
0118 ecm_qt_install_logging_categories(
0119     EXPORT KCOMPLETION
0120     FILE kcompletion.categories
0121     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0122 )