kbookmarks/src/CMakeLists.txt

0001 ecm_create_qm_loader(kbookmarks_QM_LOADER kbookmarks5_qt)
0002
0003 set(kbookmarks_SRCS
0004     kbookmarkaction.cpp
0005     kbookmarkaction.h
0006     kbookmarkactioninterface.cpp
0007     kbookmarkactioninterface.h
0008     kbookmarkactionmenu.cpp
0009     kbookmarkactionmenu.h
0010     kbookmarkcontextmenu.cpp
0011     kbookmarkcontextmenu.h
0012     kbookmark.cpp
0013     kbookmarkdialog.cpp
0014     kbookmarkdialog.h
0015     kbookmarkdialog_p.h
0016     kbookmarkexporter.h
0017     kbookmark.h
0018     kbookmarkimporter.cpp
0019     kbookmarkimporter.h
0020     kbookmarkimporter_ie.cpp
0021     kbookmarkimporter_ie.h
0022     kbookmarkimporter_ns.cpp
0023     kbookmarkimporter_ns.h
0024     kbookmarkimporter_opera.cpp
0025     kbookmarkimporter_opera.h
0026     kbookmarkimporter_opera_p.h
0027     kbookmarkmanager.cpp
0028     kbookmarkmanager.h
0029     kbookmarkmenu.cpp
0030     kbookmarkmenu.h
0031     kbookmarkmenu_p.h
0032     kbookmarkowner.cpp
0033     kbookmarkowner.h
0034     konqbookmarkmenu.cpp
0035     konqbookmarkmenu.h
0036     konqbookmarkmenu_p.h
0037     kbookmarkdombuilder.cpp
0038     kbookmarkdombuilder.h
0039   ${kbookmarks_QM_LOADER}
0040 )
0041 if (TARGET Qt${QT_MAJOR_VERSION}::DBus)
0042   list(APPEND kbookmarks_SRCS kbookmarkmanageradaptor.cpp kbookmarkmanageradaptor_p.h)
0043 endif()
0044
0045 ecm_qt_declare_logging_category(kbookmarks_SRCS
0046     HEADER kbookmarks_debug.h
0047     IDENTIFIER KBOOKMARKS_LOG
0048     CATEGORY_NAME kf.bookmarks
0049     OLD_CATEGORY_NAMES kf5.kbookmarks
0050     DESCRIPTION "KBookmarks"
0051     EXPORT KBOOKMARKS
0052 )
0053
0054 add_library(KF5Bookmarks ${kbookmarks_SRCS})
0055 add_library(KF5::Bookmarks ALIAS KF5Bookmarks)
0056 ecm_generate_export_header(KF5Bookmarks
0057     BASE_NAME KBookmarks
0058     GROUP_BASE_NAME KF
0059     VERSION ${KF_VERSION}
0060     DEPRECATED_BASE_VERSION 0
0061     DEPRECATION_VERSIONS 5.0 5.65 5.69
0062     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0063 )
0064
0065 target_include_directories(KF5Bookmarks INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarks>")
0066
0067 target_link_libraries(KF5Bookmarks PUBLIC Qt${QT_MAJOR_VERSION}::Widgets Qt${QT_MAJOR_VERSION}::Xml KF5::WidgetsAddons)
0068 target_link_libraries(KF5Bookmarks PRIVATE
0069     KF5::CoreAddons # for KStringHandler
0070     KF5::Codecs # for KCharsets
0071     KF5::ConfigCore # for KConfigGroup
0072     KF5::ConfigWidgets # for KStandardAction
0073 )
0074
0075 if(NOT EXCLUDE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT" AND EXCLUDE_DEPRECATED_BEFORE_AND_AT VERSION_LESS 5.69.0)
0076   target_link_libraries(KF5Bookmarks PRIVATE
0077     KF5::XmlGui # for KActionCollection
0078   )
0079 endif()
0080
0081 if (TARGET Qt${QT_MAJOR_VERSION}::DBus)
0082   target_link_libraries(KF5Bookmarks PRIVATE Qt${QT_MAJOR_VERSION}::DBus) # dbus usage in kbookmarkmanager.cpp
0083 else()
0084   target_compile_definitions(KF5Bookmarks PUBLIC -DKBOOKMARKS_NO_DBUS)
0085 endif()
0086
0087 set_target_properties(KF5Bookmarks PROPERTIES VERSION   ${KBOOKMARKS_VERSION}
0088                                               SOVERSION ${KBOOKMARKS_SOVERSION}
0089                                               EXPORT_NAME Bookmarks
0090 )
0091
0092 ecm_generate_headers(KBookmarks_HEADERS
0093   HEADER_NAMES
0094   KBookmark
0095   KBookmarkAction
0096   KBookmarkActionInterface
0097   KBookmarkActionMenu
0098   KBookmarkContextMenu
0099   KBookmarkManager
0100   KBookmarkMenu
0101   KBookmarkOwner
0102   KBookmarkDomBuilder
0103   KBookmarkDialog
0104   KonqBookmarkMenu
0105
0106   REQUIRED_HEADERS KBookmarks_HEADERS
0107 )
0108
0109 # These classes have weirdly named classes, no forwarding headers.
0110 set(KBookmarks_HEADERS
0111   ${KBookmarks_HEADERS}
0112   kbookmarkexporter.h
0113   kbookmarkimporter.h
0114   kbookmarkimporter_opera.h
0115   kbookmarkimporter_ie.h
0116   kbookmarkimporter_ns.h
0117 )
0118 install(TARGETS KF5Bookmarks EXPORT KF5BookmarksTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0119
0120 install(FILES
0121   ${CMAKE_CURRENT_BINARY_DIR}/kbookmarks_export.h
0122   ${KBookmarks_HEADERS}
0123   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarks COMPONENT Devel
0124 )
0125
0126 ecm_qt_install_logging_categories(
0127     EXPORT KBOOKMARKS
0128     FILE kbookmarks.categories
0129     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0130 )
0131
0132 if(BUILD_QCH)
0133     ecm_add_qch(
0134         KF5Bookmarks_QCH
0135         NAME KBookmarks
0136         BASE_NAME KF5Bookmarks
0137         VERSION ${KF_VERSION}
0138         ORG_DOMAIN org.kde
0139         SOURCES # using only public headers, to cover only public API
0140             ${KBookmarks_HEADERS}
0141         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0142         LINK_QCHS
0143             Qt5Widgets_QCH
0144             Qt5Xml_QCH
0145             KF5WidgetsAddons_QCH
0146         INCLUDE_DIRS
0147             ${CMAKE_CURRENT_BINARY_DIR}
0148         BLANK_MACROS
0149             KBOOKMARKS_EXPORT
0150             KBOOKMARKS_DEPRECATED
0151             KBOOKMARKS_DEPRECATED_EXPORT
0152             "KBOOKMARKS_DEPRECATED_VERSION(x, y, t)"
0153         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0154         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0155         COMPONENT Devel
0156     )
0157 endif()
0158
0159 include(ECMGeneratePriFile)
0160 ecm_generate_pri_file(BASE_NAME KBookmarks LIB_NAME KF5Bookmarks DEPS "widgets xml" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarks)
0161 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})