Warning, /frameworks/kbookmarks/src/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 add_subdirectory(widgets)
0002 
0003 add_library(KF6Bookmarks)
0004 add_library(KF6::Bookmarks ALIAS KF6Bookmarks)
0005 
0006 set_target_properties(KF6Bookmarks PROPERTIES
0007     VERSION     ${KBOOKMARKS_VERSION}
0008     SOVERSION   ${KBOOKMARKS_SOVERSION}
0009     EXPORT_NAME Bookmarks
0010 )
0011 
0012 ecm_create_qm_loader(KF6Bookmarks kbookmarks6_qt)
0013 
0014 target_sources(KF6Bookmarks PRIVATE
0015     kbookmarkaction.cpp
0016     kbookmarkaction.h
0017     kbookmarkactioninterface.cpp
0018     kbookmarkactioninterface.h
0019     kbookmark.cpp
0020     kbookmark.h
0021     kbookmarkmanager.cpp
0022     kbookmarkmanager.h
0023     kbookmarkowner.cpp
0024     kbookmarkowner.h
0025     keditbookmarks_p.h
0026     keditbookmarks.cpp
0027     kbookmarksettings.cpp
0028 )
0029 
0030 ecm_qt_declare_logging_category(KF6Bookmarks
0031     HEADER kbookmarks_debug.h
0032     IDENTIFIER KBOOKMARKS_LOG
0033     CATEGORY_NAME kf.bookmarks
0034     OLD_CATEGORY_NAMES kf5.kbookmarks
0035     DESCRIPTION "KBookmarks"
0036     EXPORT KBOOKMARKS
0037 )
0038 
0039 ecm_generate_export_header(KF6Bookmarks
0040     BASE_NAME KBookmarks
0041     GROUP_BASE_NAME KF
0042     VERSION ${KF_VERSION}
0043     USE_VERSION_HEADER
0044     DEPRECATED_BASE_VERSION 0
0045     DEPRECATION_VERSIONS
0046     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0047 )
0048 
0049 target_include_directories(KF6Bookmarks INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarks>")
0050 
0051 target_link_libraries(KF6Bookmarks PUBLIC Qt6::Gui Qt6::Xml)
0052 target_link_libraries(KF6Bookmarks PRIVATE
0053     KF6::CoreAddons # for KStringHandler
0054     KF6::ConfigCore # for KConfigGroup
0055 )
0056 
0057 ecm_generate_headers(KBookmarks_HEADERS
0058   HEADER_NAMES
0059   KBookmark
0060   KBookmarkAction
0061   KBookmarkActionInterface
0062   KBookmarkManager
0063   KBookmarkOwner
0064 
0065   REQUIRED_HEADERS KBookmarks_HEADERS
0066 )
0067 
0068 install(TARGETS KF6Bookmarks EXPORT KF6BookmarksTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0069 
0070 install(FILES
0071   ${CMAKE_CURRENT_BINARY_DIR}/kbookmarks_export.h
0072   ${KBookmarks_HEADERS}
0073   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KBookmarks COMPONENT Devel
0074 )
0075 
0076 ecm_qt_install_logging_categories(
0077     EXPORT KBOOKMARKS
0078     FILE kbookmarks.categories
0079     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0080 )
0081 
0082 if(BUILD_QCH)
0083     ecm_add_qch(
0084         KF6Bookmarks_QCH
0085         NAME KBookmarks
0086         BASE_NAME KF6Bookmarks
0087         VERSION ${KF_VERSION}
0088         ORG_DOMAIN org.kde
0089         SOURCES # using only public headers, to cover only public API
0090             ${KBookmarks_HEADERS}
0091         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0092         LINK_QCHS
0093             Qt6Widgets_QCH
0094             Qt6Xml_QCH
0095             KF6WidgetsAddons_QCH
0096         INCLUDE_DIRS
0097             ${CMAKE_CURRENT_BINARY_DIR}
0098         BLANK_MACROS
0099             KBOOKMARKS_EXPORT
0100             KBOOKMARKS_DEPRECATED
0101             KBOOKMARKS_DEPRECATED_EXPORT
0102             "KBOOKMARKS_DEPRECATED_VERSION(x, y, t)"
0103         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0104         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0105         COMPONENT Devel
0106     )
0107 endif()