src/lib/CMakeLists.txt

0001 set(BALOO_LIB_SRCS
0002     term.cpp
0003     query.cpp
0004     queryrunnable.cpp
0005     resultiterator.cpp
0006     advancedqueryparser.cpp
0007
0008     file.cpp
0009     filemonitor.cpp
0010     taglistjob.cpp
0011
0012     indexerconfig.cpp
0013     ../file/fileindexerconfig.cpp
0014     ../file/storagedevices.cpp
0015     ../file/regexpcache.cpp
0016     ../file/fileexcludefilters.cpp
0017     ../file/propertydata.cpp
0018
0019     searchstore.cpp
0020 )
0021 ecm_qt_declare_logging_category(BALOO_LIB_SRCS
0022     HEADER baloodebug.h
0023     IDENTIFIER BALOO
0024     CATEGORY_NAME kf.baloo
0025     OLD_CATEGORY_NAMES org.kde.baloo
0026     DESCRIPTION "Baloo File debug"
0027     EXPORT BALOO
0028 )
0029
0030 kconfig_add_kcfg_files(BALOO_LIB_SRCS baloosettings.kcfgc GENERATE_MOC)
0031 add_library(KF5Baloo ${BALOO_LIB_SRCS})
0032
0033 add_library(KF5::Baloo ALIAS KF5Baloo)
0034
0035 target_link_libraries(KF5Baloo
0036     PUBLIC
0037     Qt${QT_MAJOR_VERSION}::Core
0038     KF5::CoreAddons
0039     KF5::FileMetaData
0040
0041     PRIVATE
0042     KF5::ConfigCore
0043     Qt${QT_MAJOR_VERSION}::DBus
0044     KF5::Solid
0045     KF5::BalooEngine
0046     BalooDBusMainInterface
0047 )
0048
0049 set_target_properties(KF5Baloo PROPERTIES
0050     VERSION ${BALOO_VERSION}
0051     SOVERSION ${BALOO_SOVERSION}
0052     EXPORT_NAME Baloo
0053 )
0054 target_include_directories(KF5Baloo INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Baloo>")
0055
0056 ecm_generate_export_header(KF5Baloo
0057     EXPORT_FILE_NAME core_export.h
0058     BASE_NAME BALOO_CORE
0059     GROUP_BASE_NAME KF
0060     VERSION ${KF_VERSION}
0061     DEPRECATED_BASE_VERSION 0
0062     DEPRECATION_VERSIONS 5.55 5.69
0063     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0064 )
0065
0066 ecm_generate_headers(KF5Baloo_CamelCase_HEADERS
0067     HEADER_NAMES
0068     Query
0069     QueryRunnable
0070     ResultIterator
0071
0072     File
0073     FileMonitor
0074     TagListJob
0075     IndexerConfig
0076
0077     PREFIX baloo
0078     REQUIRED_HEADERS KF5Baloo_HEADERS
0079 )
0080
0081 install(TARGETS KF5Baloo EXPORT KF5BalooTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0082
0083 install(FILES
0084     ${CMAKE_CURRENT_BINARY_DIR}/core_export.h
0085     ${CMAKE_CURRENT_BINARY_DIR}/baloosettings.h
0086     ${KF5Baloo_HEADERS}
0087     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Baloo/baloo
0088     COMPONENT Devel
0089 )
0090
0091 install(FILES
0092     ${KF5Baloo_CamelCase_HEADERS}
0093     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Baloo/Baloo
0094     COMPONENT Devel
0095 )
0096
0097 if(BUILD_QCH)
0098     ecm_add_qch(
0099         KF5Baloo_QCH
0100         NAME Baloo
0101         BASE_NAME KF5Baloo
0102         VERSION ${KF_VERSION}
0103         ORG_DOMAIN org.kde
0104         SOURCES # using only public headers, to cover only public API
0105             ${KF5Baloo_HEADERS}
0106             "${CMAKE_SOURCE_DIR}/docs/distributing.md"
0107             "${CMAKE_SOURCE_DIR}/docs/development/build-instructions.md"
0108             "${CMAKE_SOURCE_DIR}/docs/user/searching.md"
0109         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0110         LINK_QCHS
0111             Qt5Core_QCH
0112             KF5CoreAddons_QCH
0113             KF5FileMetaData_QCH
0114         INCLUDE_DIRS
0115             ${CMAKE_CURRENT_BINARY_DIR}
0116         BLANK_MACROS
0117             BALOO_CORE_EXPORT
0118             BALOO_CORE_DEPRECATED
0119             BALOO_CORE_DEPRECATED_EXPORT
0120             "BALOO_DEPRECATED_VERSION(x, y, t)"
0121         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0122         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0123         COMPONENT Devel
0124     )
0125 endif()
0126
0127 if (NOT WIN32)
0128    configure_file (
0129       ${CMAKE_CURRENT_SOURCE_DIR}/Baloo.pc.cmake
0130       ${CMAKE_CURRENT_BINARY_DIR}/Baloo.pc
0131       )
0132    install (
0133       FILES ${CMAKE_CURRENT_BINARY_DIR}/Baloo.pc
0134       DESTINATION ${KDE_INSTALL_LIBDIR}/pkgconfig
0135       )
0136 endif ()
0137
0138 include(ECMGeneratePriFile)
0139 ecm_generate_pri_file(
0140     BASE_NAME Baloo
0141     LIB_NAME KF5Baloo
0142     DEPS "core KCoreAddons KFileMetaData"
0143     FILENAME_VAR PRI_FILENAME
0144     INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/Baloo
0145 )
0146 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})