Warning, /frameworks/baloo/src/lib/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 set(BALOO_LIB_SRCS
0002     term.cpp
0003     query.cpp
0004     queryrunnable.cpp
0005     resultiterator.cpp
0006     advancedqueryparser.cpp
0007 
0008     file.cpp
0009     filemonitor.cpp
0010     taglistjob.cpp
0011 
0012     indexerconfig.cpp
0013     ../file/fileindexerconfig.cpp
0014     ../file/storagedevices.cpp
0015     ../file/regexpcache.cpp
0016     ../file/fileexcludefilters.cpp
0017     ../file/propertydata.cpp
0018 
0019     searchstore.cpp
0020 )
0021 ecm_qt_declare_logging_category(BALOO_LIB_SRCS
0022     HEADER baloodebug.h
0023     IDENTIFIER BALOO
0024     CATEGORY_NAME kf.baloo
0025     OLD_CATEGORY_NAMES org.kde.baloo
0026     DESCRIPTION "Baloo File debug"
0027     EXPORT BALOO
0028 )
0029 
0030 kconfig_add_kcfg_files(BALOO_LIB_SRCS baloosettings.kcfgc GENERATE_MOC)
0031 add_library(KF6Baloo ${BALOO_LIB_SRCS})
0032 
0033 add_library(KF6::Baloo ALIAS KF6Baloo)
0034 
0035 target_link_libraries(KF6Baloo
0036     PUBLIC
0037     Qt6::Core
0038     KF6::CoreAddons
0039     KF6::FileMetaData
0040 
0041     PRIVATE
0042     KF6::ConfigCore
0043     Qt6::DBus
0044     KF6::Solid
0045     KF6::BalooEngine
0046     BalooDBusMainInterface
0047 )
0048 
0049 set_target_properties(KF6Baloo PROPERTIES
0050     VERSION ${BALOO_VERSION}
0051     SOVERSION ${BALOO_SOVERSION}
0052     EXPORT_NAME Baloo
0053 )
0054 target_include_directories(KF6Baloo INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/Baloo>")
0055 
0056 ecm_generate_export_header(KF6Baloo
0057     EXPORT_FILE_NAME core_export.h
0058     BASE_NAME BALOO_CORE
0059     GROUP_BASE_NAME KF
0060     VERSION ${KF_VERSION}
0061     USE_VERSION_HEADER
0062     VERSION_BASE_NAME Baloo
0063     DEPRECATED_BASE_VERSION 0
0064     DEPRECATION_VERSIONS
0065     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0066 )
0067 
0068 ecm_generate_headers(KF6Baloo_CamelCase_HEADERS
0069     HEADER_NAMES
0070     Query
0071     QueryRunnable
0072     ResultIterator
0073 
0074     File
0075     FileMonitor
0076     TagListJob
0077     IndexerConfig
0078 
0079     PREFIX baloo
0080     REQUIRED_HEADERS KF6Baloo_HEADERS
0081 )
0082 
0083 install(TARGETS KF6Baloo EXPORT KF6BalooTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS})
0084 
0085 install(FILES
0086     ${CMAKE_CURRENT_BINARY_DIR}/core_export.h
0087     ${CMAKE_CURRENT_BINARY_DIR}/baloosettings.h
0088     ${KF6Baloo_HEADERS}
0089     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Baloo/baloo
0090     COMPONENT Devel
0091 )
0092 
0093 install(FILES
0094     ${KF6Baloo_CamelCase_HEADERS}
0095     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/Baloo/Baloo
0096     COMPONENT Devel
0097 )
0098 
0099 if(BUILD_QCH)
0100     ecm_add_qch(
0101         KF6Baloo_QCH
0102         NAME Baloo
0103         BASE_NAME KF6Baloo
0104         VERSION ${KF_VERSION}
0105         ORG_DOMAIN org.kde
0106         SOURCES # using only public headers, to cover only public API
0107             ${KF6Baloo_HEADERS}
0108             "${CMAKE_SOURCE_DIR}/docs/distributing.md"
0109             "${CMAKE_SOURCE_DIR}/docs/development/build-instructions.md"
0110             "${CMAKE_SOURCE_DIR}/docs/user/searching.md"
0111         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0112         LINK_QCHS
0113             Qt6Core_QCH
0114             KF6CoreAddons_QCH
0115             KF6FileMetaData_QCH
0116         INCLUDE_DIRS
0117             ${CMAKE_CURRENT_BINARY_DIR}
0118         BLANK_MACROS
0119             BALOO_CORE_EXPORT
0120             BALOO_CORE_DEPRECATED
0121             BALOO_CORE_DEPRECATED_EXPORT
0122             "BALOO_DEPRECATED_VERSION(x, y, t)"
0123         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0124         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0125         COMPONENT Devel
0126     )
0127 endif()
0128 
0129 if (NOT WIN32)
0130     ecm_generate_pkgconfig_file(BASE_NAME KF6Baloo
0131         LIB_NAME KF6Baloo
0132         INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/Baloo
0133         DEPS Qt6Core
0134         DESCRIPTION "Baloo is a file indexing and searching framework for Linux"
0135         INSTALL
0136     )
0137 endif ()
0138