labplot/cmake/FindLIBCERF.cmake

0001 #=============================================================================
0002 # Copyright (c) 2019 Harald Sitter <sitter@kde.org>
0003 #
0004 # Redistribution and use in source and binary forms, with or without
0005 # modification, are permitted provided that the following conditions
0006 # are met:
0007 #
0008 # 1. Redistributions of source code must retain the copyright
0009 #    notice, this list of conditions and the following disclaimer.
0010 # 2. Redistributions in binary form must reproduce the copyright
0011 #    notice, this list of conditions and the following disclaimer in the
0012 #    documentation and/or other materials provided with the distribution.
0013 # 3. The name of the author may not be used to endorse or promote products
0014 #    derived from this software without specific prior written permission.
0015 #
0016 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
0017 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
0018 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
0019 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
0020 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
0021 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
0022 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
0023 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
0024 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
0025 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
0026 #=============================================================================
0027
0028 find_package(PkgConfig QUIET)
0029 pkg_check_modules(PC_LIBCERF libcerf QUIET)
0030
0031 find_library(LIBCERF_LIBRARY
0032     NAMES cerf
0033     HINTS ${PC_LIBCERF_LIBRARY_DIRS}
0034 )
0035
0036 find_path(LIBCERF_INCLUDE_DIR
0037     NAMES cerf.h
0038     HINTS ${PC_LIBCERF_INCLUDE_DIRS}
0039 )
0040
0041 set(LIBCERF_VERSION ${PC_LIBCERF_VERSION})
0042
0043 include(FindPackageHandleStandardArgs)
0044 find_package_handle_standard_args(LIBCERF
0045     REQUIRED_VARS
0046     LIBCERF_LIBRARY
0047         LIBCERF_INCLUDE_DIR
0048     VERSION_VAR
0049     LIBCERF_VERSION
0050 )
0051
0052 if(LIBCERF_FOUND AND NOT TARGET libcerf::libcerf)
0053     add_library(libcerf::libcerf UNKNOWN IMPORTED)
0054     set_target_properties(libcerf::libcerf PROPERTIES
0055         IMPORTED_LOCATION "${LIBCERF_LIBRARY}"
0056         INTERFACE_COMPILE_OPTIONS "${PC_LIBCERF_CFLAGS}"
0057         INTERFACE_INCLUDE_DIRECTORIES "${LIBCERF_INCLUDE_DIR}"
0058     )
0059 endif()
0060
0061 mark_as_advanced(LIBCERF_LIBRARIES LIBCERF_INCLUDE_DIR LIBCERF_VERSION)
0062
0063 include(FeatureSummary)
0064 set_package_properties(LIBCERF PROPERTIES
0065     DESCRIPTION "Efficient and accurate implementation of complex error functions, along with Dawson, Faddeeva, and Voigt functions"
0066     URL "https://jugit.fz-juelich.de/mlz/libcerf"
0067 )