labplot/cmake/FindLIBCERF.cmake

0001 #=============================================================================
0002 # SPDX-FileCopyrightText: 2019 Harald Sitter <sitter@kde.org>
0003 #
0004 # SPDX-License-Identifier: BSD-3-Clause
0005 #=============================================================================
0006
0007 find_package(PkgConfig QUIET)
0008 pkg_check_modules(PC_LIBCERF libcerf QUIET)
0009
0010 find_library(LIBCERF_LIBRARIES
0011     NAMES cerf
0012     HINTS ${PC_LIBCERF_LIBRARY_DIRS}
0013 )
0014
0015 find_path(LIBCERF_INCLUDE_DIR
0016     NAMES cerf.h
0017     HINTS ${PC_LIBCERF_INCLUDE_DIRS}
0018 )
0019
0020 set(LIBCERF_VERSION ${PC_LIBCERF_VERSION})
0021
0022 include(FindPackageHandleStandardArgs)
0023 find_package_handle_standard_args(LIBCERF
0024     REQUIRED_VARS
0025         LIBCERF_LIBRARIES
0026         LIBCERF_INCLUDE_DIR
0027     VERSION_VAR
0028         LIBCERF_VERSION
0029 )
0030
0031 if(LIBCERF_FOUND AND NOT TARGET libcerf::libcerf)
0032     add_library(libcerf::libcerf UNKNOWN IMPORTED)
0033     set_target_properties(libcerf::libcerf PROPERTIES
0034          IMPORTED_LOCATION "${LIBCERF_LIBRARIES}"
0035          INTERFACE_COMPILE_OPTIONS "${PC_LIBCERF_CFLAGS}"
0036          INTERFACE_INCLUDE_DIRECTORIES "${LIBCERF_INCLUDE_DIR}"
0037     )
0038 else()
0039         set(LIBCERF_LIBRARIES "")
0040 endif()
0041
0042 mark_as_advanced(LIBCERF_LIBRARIES LIBCERF_INCLUDE_DIR LIBCERF_VERSION)
0043
0044 include(FeatureSummary)
0045 set_package_properties(LIBCERF PROPERTIES
0046     DESCRIPTION "Efficient and accurate implementation of complex error functions, along with Dawson, Faddeeva, and Voigt functions"
0047     URL "https://jugit.fz-juelich.de/mlz/libcerf"
0048 )