src/backends/CMakeLists.txt

0001 function(add_backend name)
0002
0003     kcoreaddons_add_plugin("cantor_${name}"
0004         SOURCES ${ARGN}
0005         INSTALL_NAMESPACE "cantor/backends")
0006
0007     target_link_libraries("cantor_${name}"
0008         cantorlibs)
0009
0010 endfunction()
0011
0012 add_subdirectory(maxima)
0013 add_subdirectory(octave)
0014 add_subdirectory(scilab)
0015
0016 set(cantor_HELP
0017    qthelpconfig.cpp
0018 )
0019
0020 ki18n_wrap_ui(cantor_HELP qthelpconfig.ui)
0021 ki18n_wrap_ui(cantor_HELP qthelpconfigeditdialog.ui)
0022
0023 add_library(cantor_help STATIC ${cantor_HELP})
0024 target_link_libraries(cantor_help KF5::SyntaxHighlighting KF5::I18n KF5::IconThemes KF5::NewStuffWidgets KF5::KIOWidgets Qt5::Help)
0025
0026 if(NOT WIN32)
0027     add_subdirectory(sage)
0028 endif(NOT WIN32)
0029
0030 set_package_properties(Analitza5 PROPERTIES DESCRIPTION "A library provided by KAlgebra."
0031     URL "https://edu.kde.org/kalgebra/"
0032     TYPE OPTIONAL
0033     PURPOSE "Backend to use KAlgebra with Cantor.")
0034
0035 find_package(Analitza5)
0036 if(Analitza5_FOUND)
0037     add_subdirectory(kalgebra)
0038 endif(Analitza5_FOUND)
0039
0040 set_package_properties(R PROPERTIES DESCRIPTION "A free software environment for statistical computing and graphics."
0041   URL "https://www.r-project.org/"
0042   TYPE OPTIONAL
0043   PURPOSE "Backend to use R with Cantor.")
0044
0045 find_package(R)
0046 if(R_FOUND)
0047   add_subdirectory(R)
0048 endif(R_FOUND)
0049
0050 set_package_properties(Qalculate PROPERTIES DESCRIPTION "A multi-purpose desktop calculator with support for customizable functions, units and arbitrary precision."
0051     URL "https://qalculate.github.io/"
0052     TYPE OPTIONAL
0053     PURPOSE "Backend to use Qalculate with Cantor.")
0054
0055 # Due this bug (https://github.com/Qalculate/libqalculate/issues/171)
0056 set(QALCULATE_MIN_VERSION 3.8.0)
0057 find_package(Qalculate)
0058 if(QALCULATE_FOUND)
0059     add_subdirectory(qalculate)
0060 endif(QALCULATE_FOUND)
0061
0062 set_package_properties(Python3 PROPERTIES TYPE OPTIONAL
0063     PURPOSE "Backend to use Python with Cantor.")
0064
0065 find_package(Python3 COMPONENTS Development)
0066 if(Python3_FOUND)
0067     add_subdirectory(python)
0068 endif()
0069
0070 set_package_properties(LuaJIT PROPERTIES DESCRIPTION "A lightweight, extensible programming language (luajit implementation)."
0071     URL "https://www.lua.org/"
0072     TYPE OPTIONAL
0073     PURPOSE "Backend to use Lua (luajit2) with Cantor.")
0074
0075 find_package(LuaJIT)
0076 if(LUAJIT_FOUND)
0077     add_subdirectory(lua)
0078 endif(LUAJIT_FOUND)
0079
0080 set_package_properties(
0081     Julia
0082     PROPERTIES DESCRIPTION "A high-level, high-performance dynamic programming language for technical computing"
0083     URL "https://julialang.org/"
0084     TYPE OPTIONAL
0085     PURPOSE "Backend to use Julia with Cantor.")
0086
0087 find_package(Julia)
0088 if(Julia_FOUND)
0089     add_subdirectory(julia)
0090 endif()