src/backends/CMakeLists.txt

0001 function(add_backend name)
0002
0003     kcoreaddons_add_plugin("cantor_${name}"
0004         SOURCES ${ARGN}
0005         INSTALL_NAMESPACE "cantor/backends")
0006
0007     target_link_libraries("cantor_${name}"
0008         cantorlibs)
0009
0010 endfunction()
0011
0012 add_subdirectory(maxima)
0013 add_subdirectory(octave)
0014 add_subdirectory(scilab)
0015
0016 set(cantor_HELP
0017    qthelpconfig.cpp
0018 )
0019
0020 ki18n_wrap_ui(cantor_HELP qthelpconfig.ui)
0021 ki18n_wrap_ui(cantor_HELP qthelpconfigeditdialog.ui)
0022
0023 add_library(cantor_help STATIC ${cantor_HELP})
0024 target_link_libraries(cantor_help KF5::SyntaxHighlighting KF5::I18n KF5::IconThemes KF5::NewStuffWidgets KF5::KIOWidgets Qt5::Help)
0025
0026 if(NOT WIN32)
0027     add_subdirectory(sage)
0028 endif(NOT WIN32)
0029
0030 set_package_properties(Analitza5 PROPERTIES DESCRIPTION "A library provided by KAlgebra."
0031     URL "https://edu.kde.org/kalgebra/"
0032     TYPE OPTIONAL
0033     PURPOSE "Backend to use KAlgebra with Cantor.")
0034
0035 find_package(Analitza5)
0036 if(Analitza5_FOUND)
0037     add_subdirectory(kalgebra)
0038 endif(Analitza5_FOUND)
0039
0040 set_package_properties(R PROPERTIES DESCRIPTION "A free software environment for statistical computing and graphics."
0041   URL "https://www.r-project.org/"
0042   TYPE OPTIONAL
0043   PURPOSE "Backend to use R with Cantor.")
0044
0045 find_package(R)
0046 if(R_FOUND)
0047   add_subdirectory(R)
0048 endif(R_FOUND)
0049
0050 set_package_properties(Qalculate PROPERTIES DESCRIPTION "A multi-purpose desktop calculator with support for customizable functions, units and arbitrary precision."
0051     URL "https://qalculate.github.io/"
0052     TYPE OPTIONAL
0053     PURPOSE "Backend to use Qalculate with Cantor.")
0054
0055 # set the minimal version to 3.11 (release date 22.06.2020) since this is the version where the colored output
0056 # was introduced and we don't want to deal with two different formattings and switch off the color completely
0057 # when starting qcalc
0058 set(QALCULATE_MIN_VERSION 3.11.0)
0059 find_package(Qalculate)
0060 if(QALCULATE_FOUND)
0061     add_subdirectory(qalculate)
0062 endif(QALCULATE_FOUND)
0063
0064 set_package_properties(Python3 PROPERTIES TYPE OPTIONAL
0065     PURPOSE "Backend to use Python with Cantor.")
0066
0067 find_package(Python3 COMPONENTS Development)
0068 if(Python3_FOUND)
0069     add_subdirectory(python)
0070 endif()
0071
0072 set_package_properties(LuaJIT PROPERTIES DESCRIPTION "A lightweight, extensible programming language (luajit implementation)."
0073     URL "https://www.lua.org/"
0074     TYPE OPTIONAL
0075     PURPOSE "Backend to use Lua (luajit2) with Cantor.")
0076
0077 find_package(LuaJIT)
0078 if(LUAJIT_FOUND)
0079     add_subdirectory(lua)
0080 endif(LUAJIT_FOUND)
0081
0082 set_package_properties(
0083     Julia
0084     PROPERTIES DESCRIPTION "A high-level, high-performance dynamic programming language for technical computing"
0085     URL "https://julialang.org/"
0086     TYPE OPTIONAL
0087     PURPOSE "Backend to use Julia with Cantor.")
0088
0089 find_package(Julia)
0090 if(Julia_FOUND)
0091     add_subdirectory(julia)
0092 endif()