telly-skout/src/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2022 Plata Hill <plata.hill@kdemail.net>
0002 # SPDX-License-Identifier: BSD-2-Clause
0003
0004 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-telly-skout.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-telly-skout.h)
0005
0006 ################# lib #################
0007 add_library(telly-skout STATIC
0008     channel.cpp
0009     channelfactory.cpp
0010     channelsmodel.cpp
0011     channelsproxymodel.cpp
0012     dataprovider.h
0013     database.cpp
0014     fetcher.cpp
0015     fetcherimpl.h
0016     group.cpp
0017     groupfactory.cpp
0018     groupsmodel.cpp
0019     localdataprovider.cpp
0020     networkdataprovider.cpp
0021     networkfetcher.cpp
0022     program.cpp
0023     programfactory.cpp
0024     programsmodel.cpp
0025     programsproxymodel.cpp
0026     tvspielfilmfetcher.cpp
0027     xmltvfetcher.cpp
0028 )
0029
0030 kconfig_add_kcfg_files(telly-skout TellySkoutSettings.kcfgc GENERATE_MOC)
0031
0032 target_include_directories(telly-skout PRIVATE ${CMAKE_BINARY_DIR})
0033 target_link_libraries(telly-skout PUBLIC Qt::Core Qt::Qml Qt::Quick Qt::QuickControls2 Qt::Sql Qt::Xml KF${QT_MAJOR_VERSION}::CoreAddons KF${QT_MAJOR_VERSION}::ConfigGui KF${QT_MAJOR_VERSION}::I18n)
0034
0035 if(ANDROID)
0036     target_link_libraries(telly-skout PUBLIC KF${QT_MAJOR_VERSION}::Kirigami2)
0037 else()
0038     target_link_libraries(telly-skout PUBLIC Qt::Widgets)
0039 endif()
0040
0041 ################# app #################
0042 add_executable(telly-skout-app
0043     main.cpp
0044     resources.qrc
0045 )
0046
0047 target_include_directories(telly-skout-app PRIVATE ${CMAKE_BINARY_DIR})
0048 target_link_libraries(telly-skout-app PRIVATE telly-skout)
0049
0050 set_target_properties(telly-skout-app PROPERTIES OUTPUT_NAME "telly-skout")
0051
0052 if(TARGET KF${QT_MAJOR_VERSION}::Crash)
0053     target_link_libraries(telly-skout-app PRIVATE KF${QT_MAJOR_VERSION}::Crash)
0054 endif()
0055
0056 install(TARGETS telly-skout-app ${KF${QT_MAJOR_VERSION}_INSTALL_TARGETS_DEFAULT_ARGS})
0057
0058 if(ANDROID)
0059     kirigami_package_breeze_icons(ICONS
0060         favorite
0061         help-about-symbolic
0062         list-add
0063         settings-configure
0064         tv
0065         view-calendar-day
0066         view-refresh
0067         view-sort
0068     )
0069 endif()