utilities/skanpage/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2015 by Kåre Särs <kare.sars@iki .fi>
0002 # SPDX-FileCopyrightText: 2020 Alexander Stippich <a.stippich@gmx.net>
0003 #
0004 # SPDX-License-Identifier: BSD-2-Clause
0005
0006 cmake_minimum_required(VERSION 3.16)
0007
0008 # KDE Gear version, managed by release script
0009 set (RELEASE_SERVICE_VERSION_MAJOR "24")
0010 set (RELEASE_SERVICE_VERSION_MINOR "04")
0011 set (RELEASE_SERVICE_VERSION_MICRO "70")
0012
0013 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0014
0015 project(skanpage
0016         VERSION ${RELEASE_SERVICE_VERSION}
0017         LANGUAGES CXX)
0018
0019 set(QT_REQUIRED_VERSION "6.5.0")
0020 set(KF_MIN_VERSION "5.240.0")
0021
0022 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0023 set(CMAKE_CXX_STANDARD 17)
0024
0025 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0026 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake" ${ECM_MODULE_PATH})
0027 include(FeatureSummary)
0028 include(ECMSetupVersion)
0029 include(ECMGenerateHeaders)
0030 include(ECMQtDeclareLoggingCategory)
0031 include(KDEInstallDirs)
0032 include(KDECompilerSettings)
0033 include(KDEClangFormat)
0034 include(KDECMakeSettings)
0035 include(ECMAddAppIcon)
0036 include(ECMInstallIcons)
0037 include(ECMDeprecationSettings)
0038
0039
0040 find_package(Qt6 ${QT_REQUIRED_VERSION} CONFIG REQUIRED Core Qml QuickControls2 Concurrent Widgets Quick PrintSupport)
0041
0042 find_package(KF6 ${KF_MIN_VERSION} REQUIRED
0043     COMPONENTS
0044         CoreAddons
0045         I18n
0046         Kirigami2
0047         Crash
0048         Config
0049         Purpose
0050         XmlGui
0051 )
0052
0053 find_package(KSaneCore6 "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}" REQUIRED)
0054
0055 find_package(KQuickImageEditor REQUIRED)
0056
0057 find_package(Tesseract 4)
0058 find_package(Leptonica)
0059
0060 if (LEPTONICA_FOUND AND TESSERACT_FOUND)
0061    set(OCR_AVAILABLE 1)
0062    set(CMAKE_CXX_FLAGS "-fopenmp")
0063 else()
0064    message(STATUS "Skanpage will be built without OCR as libraries are missing.")
0065 endif()
0066
0067 ecm_set_disabled_deprecation_versions(QT 6.4
0068     KF 5.101
0069 )
0070
0071 ecm_setup_version(${PROJECT_VERSION}
0072     VARIABLE_PREFIX SKANPAGE
0073     VERSION_HEADER skanpage_version.h)
0074
0075 install(PROGRAMS org.kde.skanpage.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0076 install(FILES org.kde.skanpage.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
0077
0078 include_directories(${CMAKE_CURRENT_BINARY_DIR})
0079
0080 configure_file(config-skanpage.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-skanpage.h)
0081
0082 add_subdirectory(src)
0083 add_subdirectory(icons)
0084 #add_subdirectory(autotests)
0085
0086 ki18n_install(po)
0087
0088 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)