utilities/okteta/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0)
0002
0003 project(Okteta VERSION 0.26.11)
0004
0005 set(REQUIRED_KF5_VERSION "5.48.0")
0006 find_package(ECM ${REQUIRED_KF5_VERSION} REQUIRED NO_MODULE)
0007
0008 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake ${ECM_MODULE_PATH})
0009
0010 # ECM KDE macros (include first, to have their policies and settings effect all other macros)
0011 include(KDEInstallDirs)
0012 include(KDECMakeSettings NO_POLICY_SCOPE)
0013 include(KDECompilerSettings NO_POLICY_SCOPE)
0014 # ECM macros
0015 include(ECMInstallIcons)
0016 include(ECMAddAppIcon)
0017 # CMake macros
0018 include(FeatureSummary)
0019 include(CMakeDependentOption)
0020 if(BUILD_TESTING)
0021   include(ECMAddTests)
0022 endif()
0023 # Okteta macros
0024 include(OktetaInternalMacros)
0025
0026 # control build scope, default to examples if BUILD_TESTING is ON
0027 if( NOT DEFINED OMIT_EXAMPLES AND NOT BUILD_TESTING )
0028     set( OMIT_EXAMPLES TRUE )
0029 endif()
0030 if( NOT DEFINED OMIT_INTERNAL_TEMPLATES AND NOT BUILD_TESTING )
0031     set( OMIT_INTERNAL_TEMPLATES TRUE )
0032 endif()
0033
0034 if( NOT OMIT_EXAMPLES )
0035     set( OKTETA_BUILD_EXAMPLES TRUE )
0036 endif()
0037 if( NOT OMIT_INTERNAL_TEMPLATES )
0038     set( KASTEN_BUILD_INTERNAL_TEMPLATES TRUE )
0039 endif()
0040
0041 option(BUILD_DESIGNERPLUGIN "Build the Designer plugin." ON)
0042 add_feature_info(DESIGNERPLUGIN ${BUILD_DESIGNERPLUGIN} "Qt Designer plugin")
0043 option(BUILD_OKTETAKASTENLIBS "Build the Okteta Kasten libraries." ON)
0044 add_feature_info(OKTETAKASTENLIBS ${BUILD_OKTETAKASTENLIBS} "Okteta Kasten libraries")
0045
0046 cmake_dependent_option(BUILD_KPARTSPLUGIN "Build the KParts plugin." ON "BUILD_OKTETAKASTENLIBS" OFF)
0047 add_feature_info(KPARTSPLUGIN ${BUILD_KPARTSPLUGIN} "KParts plugin")
0048 cmake_dependent_option(BUILD_DESKTOPPROGRAM "Build the program." ON "BUILD_OKTETAKASTENLIBS" OFF)
0049 add_feature_info(DESKTOPPROGRAM ${BUILD_DESKTOPPROGRAM} "Program")
0050
0051 set(REQUIRED_QT_VERSION "5.9.0")
0052 set(ADDITIONAL_REQUIRED_QT_COMPONENTS)
0053 if(BUILD_TESTING)
0054     list(APPEND ADDITIONAL_REQUIRED_QT_COMPONENTS Test)
0055 endif()
0056 if( BUILD_DESIGNERPLUGIN )
0057     list(APPEND ADDITIONAL_REQUIRED_QT_COMPONENTS UiPlugin)
0058 endif()
0059 if( BUILD_OKTETAKASTENLIBS )
0060     list(APPEND ADDITIONAL_REQUIRED_QT_COMPONENTS
0061         Network
0062         PrintSupport
0063         Qml
0064         Script
0065         ScriptTools
0066         Xml
0067     )
0068 endif()
0069 find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED
0070     COMPONENTS
0071     Core
0072     Widgets
0073     ${ADDITIONAL_REQUIRED_QT_COMPONENTS}
0074 )
0075
0076 set(ADDITIONAL_REQUIRED_KF_COMPONENTS)
0077 if( BUILD_OKTETAKASTENLIBS )
0078     list(APPEND ADDITIONAL_REQUIRED_KF_COMPONENTS
0079         Bookmarks
0080         Completion
0081         IconThemes
0082         KCMUtils
0083         KIO
0084         NewStuff
0085         Parts
0086         Service
0087         WidgetsAddons
0088         XmlGui
0089     )
0090 endif()
0091 if( BUILD_DESKTOPPROGRAM )
0092     list(APPEND ADDITIONAL_REQUIRED_KF_COMPONENTS
0093         Crash
0094         DBusAddons
0095         DocTools
0096     )
0097 endif()
0098 find_package(KF5 ${REQUIRED_KF5_VERSION} REQUIRED
0099     COMPONENTS
0100     Codecs
0101     ConfigWidgets
0102     I18n
0103     ${ADDITIONAL_REQUIRED_KF_COMPONENTS}
0104 )
0105
0106 find_package(Qca-qt5 2.1.0)
0107 set_package_properties(Qca-qt5 PROPERTIES
0108     DESCRIPTION "Qt Cryptographic Architecture"
0109     URL "https://commits.kde.org/qca"
0110     TYPE OPTIONAL
0111     PURPOSE "Needed for most of the algorithms of the checksum tool"
0112 )
0113
0114 add_definitions(
0115     -DQT_DEPRECATED_WARNINGS
0116     -DQT_DISABLE_DEPRECATED_BEFORE=0x050900
0117     -DQT_USE_QSTRINGBUILDER
0118     -DQT_NO_CAST_TO_ASCII
0119     -DQT_NO_CAST_FROM_ASCII
0120     -DQT_NO_CAST_FROM_BYTEARRAY
0121     -DQT_STRICT_ITERATORS
0122     -DQT_NO_URL_CAST_FROM_STRING
0123     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
0124     -DQT_NO_NARROWING_CONVERSIONS_IN_CONNECT
0125 )
0126
0127 # helper libs
0128 add_subdirectory( libs )
0129 if( BUILD_DESKTOPPROGRAM )
0130     add_subdirectory( doc )
0131 endif()
0132
0133 set( OKTETALIBS_MAJOR_VERSION 0 )
0134 set( OKTETALIBS_MINOR_VERSION 10 )
0135 set( OKTETALIBS_PATCHLEVEL_VERSION 0 )
0136 set( OKTETALIBS_VERSION "${OKTETALIBS_MAJOR_VERSION}.${OKTETALIBS_MINOR_VERSION}.${OKTETALIBS_PATCHLEVEL_VERSION}" )
0137 set( OKTETALIBS_ABI_VERSION 3 )
0138
0139 set( OKTETALIBS_LIB_SOVERSION 0 )
0140 set( OKTETALIBS_LIB_VERSION ${OKTETALIBS_VERSION} )
0141
0142 # Okteta libs
0143 add_subdirectory( core )
0144 add_subdirectory( gui )
0145
0146 if( BUILD_DESIGNERPLUGIN )
0147     add_subdirectory( designer )
0148 endif()
0149
0150 # Okteta Kasten components
0151 if( BUILD_OKTETAKASTENLIBS )
0152     add_subdirectory( kasten )
0153 endif()
0154 # special mimetypes
0155 if( BUILD_OKTETAKASTENLIBS )
0156     add_subdirectory( mimetypes )
0157 endif()
0158
0159 # programs and parts for desktop
0160 add_subdirectory( parts )
0161 if( BUILD_DESKTOPPROGRAM )
0162     add_subdirectory( program )
0163 endif()
0164
0165 ki18n_install(po)
0166
0167 if( BUILD_DESKTOPPROGRAM )
0168     kdoctools_install(po)
0169 endif()
0170
0171 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)