utilities/krename/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.7)
0002
0003 project(krename VERSION "5.0.60")
0004
0005 set(QT5_MIN_VERSION "5.12.0")
0006 set(KF5_MIN_VERSION "5.85.0")
0007 set(KDE_COMPILERSETTINGS_LEVEL "5.82.0")
0008
0009 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0010 set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/modules" ${ECM_MODULE_PATH})
0011
0012 include(KDEInstallDirs)
0013 include(ECMInstallIcons)
0014 include(KDECMakeSettings)
0015 include(KDECompilerSettings NO_POLICY_SCOPE)
0016 include(FeatureSummary)
0017
0018 find_package(Qt5 ${QT5_MIN_VERSION} REQUIRED COMPONENTS
0019     Core
0020     Widgets
0021     Qml
0022 )
0023 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0024     Completion
0025     Config
0026     CoreAddons
0027     Crash
0028     I18n
0029     IconThemes
0030     ItemViews
0031     JobWidgets
0032     KIO
0033     Service
0034     WidgetsAddons
0035     XmlGui
0036 )
0037
0038 add_definitions(
0039     -DQT_DEPRECATED_WARNINGS
0040     -DQT_DISABLE_DEPRECATED_BEFORE=0x050d00
0041     -DQT_NO_SIGNALS_SLOTS_KEYWORDS
0042     -DQT_NO_URL_CAST_FROM_STRING
0043     -DQT_STRICT_ITERATORS
0044 )
0045
0046 # Find KArchive
0047 find_package(KF5Archive)
0048 set_package_properties(KF5Archive PROPERTIES
0049     PURPOSE "Needed for ODF plugin"
0050     TYPE OPTIONAL)
0051
0052 # Find taglib
0053 set(TAGLIB_MIN_VERSION "1.5")
0054 find_package(Taglib ${TAGLIB_MIN_VERSION})
0055 set_package_properties(Taglib PROPERTIES
0056     TYPE OPTIONAL)
0057
0058 # Find exiv2
0059 find_package(LibExiv2 0.27) # EXIV2_TEST_VERSION was added in 0.27
0060 set_package_properties(LibExiv2 PROPERTIES TYPE OPTIONAL)
0061
0062 # Find podofo
0063 find_package(PoDoFo)
0064 set_package_properties(PoDoFo PROPERTIES TYPE OPTIONAL)
0065
0066 # Find freetype
0067 find_package(Freetype)
0068 set_package_properties(Freetype PROPERTIES
0069     DESCRIPTION "A library to access font metadata"
0070     URL "https://www.freetype.org"
0071     TYPE OPTIONAL)
0072
0073 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0074
0075 set(HAVE_TAGLIB ${TAGLIB_FOUND})
0076 set(HAVE_EXIV2 ${LibExiv2_FOUND})
0077 set(HAVE_PODOFO ${PoDoFo_FOUND})
0078 set(HAVE_KARCHIVE ${KF5Archive_FOUND})
0079 set(HAVE_FREETYPE ${FREETYPE_FOUND})
0080 configure_file(config-krename.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-krename.h)
0081
0082 # Directories
0083
0084 add_subdirectory(src)
0085 add_subdirectory(autotests)
0086
0087 ki18n_install(po)