utilities/kongress/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2020 Dimitris Kardarakos <dimkard@posteo.net>
0002 #
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 cmake_minimum_required(VERSION 3.16)
0006
0007 # KDE Applications version, managed by release script.
0008 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0009 set(RELEASE_SERVICE_VERSION_MINOR "04")
0010 set(RELEASE_SERVICE_VERSION_MICRO "70")
0011 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0012
0013 project(kongress VERSION ${RELEASE_SERVICE_VERSION})
0014
0015 set(QT_MIN_VERSION "6.5.0")
0016 set(KF_MIN_VERSION "5.240.0")
0017 set (KDE_COMPILERSETTINGS_LEVEL "5.82.0")
0018
0019 set(CMAKE_CXX_STANDARD 20)
0020 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0021
0022 option(REMINDERS_ENABLED "Build with reminders support" ON)
0023
0024 include(CTest)
0025 include(FeatureSummary)
0026
0027 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0028
0029 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
0030 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0031 include(KDEInstallDirs)
0032 include(KDECMakeSettings)
0033 include(KDECompilerSettings NO_POLICY_SCOPE)
0034 include(ECMPoQmTools)
0035 include(ECMSetupVersion)
0036 include(ECMDeprecationSettings)
0037 include(ECMAddAndroidApk)
0038
0039
0040 ecm_setup_version(${PROJECT_VERSION}
0041     VARIABLE_PREFIX KONGRESS
0042     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/version.h
0043 )
0044
0045 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Core Quick Gui Svg Qml QuickControls2 Network)
0046
0047 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS Config Kirigami2 I18n CalendarCore CoreAddons)
0048
0049 if (ANDROID)
0050     find_package(OpenSSL REQUIRED)
0051 else()
0052     find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS Widgets)
0053 endif()
0054 if (BUILD_TESTING)
0055     find_package(Qt6 ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Test)
0056 endif()
0057 if(NOT ANDROID AND REMINDERS_ENABLED)
0058     find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS DBusAddons Notifications)
0059 endif()
0060
0061 add_subdirectory(src)
0062
0063 if(NOT ANDROID AND REMINDERS_ENABLED)
0064     add_subdirectory(kongressac)
0065 endif()
0066
0067 if (ANDROID)
0068     configure_file(${CMAKE_CURRENT_SOURCE_DIR}/android/version.gradle.in ${CMAKE_BINARY_DIR}/version.gradle)
0069 endif()
0070
0071 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0072     ki18n_install(po)
0073 endif()
0074
0075 if (NOT ANDROID)
0076     install(FILES org.kde.kongress.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0077     install(PROGRAMS org.kde.kongress.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0078     install(FILES org.kde.kongress.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps)
0079 else()
0080     install(FILES org.kde.kongress.svg DESTINATION ${KDE_INSTALL_QMLDIR}/org/kde/kirigami/breeze-internal/icons/)
0081 endif()
0082
0083 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)