utilities/kdebugsettings/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2015-2022 Laurent Montel <montel@kde.org>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003 # KDE Application Version, managed by release script
0004 set (RELEASE_SERVICE_VERSION_MAJOR "22")
0005 set (RELEASE_SERVICE_VERSION_MINOR "12")
0006 set (RELEASE_SERVICE_VERSION_MICRO "1")
0007 set (RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0008 cmake_minimum_required (VERSION 3.16.0 FATAL_ERROR)
0009 project(kdebugsettings VERSION ${RELEASE_SERVICE_VERSION})
0010
0011 set(QT_MIN_VERSION "5.15.2")
0012 set(KF5_MIN_VERSION "5.99.0")
0013
0014 set(ECM_VERSION ${KF5_MIN_VERSION})
0015 find_package(ECM ${ECM_VERSION} REQUIRED NO_MODULE)
0016 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0017 include(FeatureSummary)
0018 include(KDEGitCommitHooks)
0019 include(KDEClangFormat)
0020 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0021 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0022 include(ECMAddAppIcon)
0023 include(ECMInstallIcons)
0024 include(KDEInstallDirs)
0025 include(KDECompilerSettings NO_POLICY_SCOPE)
0026 include(KDECMakeSettings)
0027 include(ECMAddTests)
0028 include(ECMQtDeclareLoggingCategory)
0029 include(GenerateExportHeader)
0030 include(ECMDeprecationSettings)
0031
0032 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Widgets)
0033 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0034     CoreAddons
0035     Config
0036     DBusAddons
0037     I18n
0038     WidgetsAddons
0039     ItemViews
0040     Completion)
0041
0042 add_definitions(-DTRANSLATION_DOMAIN="kdebugsettings")
0043 ecm_set_disabled_deprecation_versions(QT 5.15.2
0044     KF 5.99
0045 )
0046
0047 configure_file(config-kdebugsettings.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kdebugsettings.h)
0048
0049 set(KDEBUGSETTINGS_LIB_VERSION "${RELEASE_SERVICE_VERSION}")
0050 set(KDEBUGSETTINGS_LIB_SOVERSION "5")
0051
0052 if(BUILD_TESTING)
0053     add_definitions(-DBUILD_TESTING)
0054 endif(BUILD_TESTING)
0055
0056 option(USE_UNITY_CMAKE_SUPPORT "Use UNITY cmake support (speedup compile time)" OFF)
0057
0058 set(COMPILE_WITH_UNITY_CMAKE_SUPPORT OFF)
0059 if (USE_UNITY_CMAKE_SUPPORT)
0060     set(COMPILE_WITH_UNITY_CMAKE_SUPPORT ON)
0061 endif()
0062
0063 add_subdirectory( src )
0064 if (BUILD_TESTING)
0065     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Test)
0066     add_subdirectory( autotests )
0067 endif()
0068 ecm_qt_install_logging_categories(EXPORT KDEBUGSETTINGS FILE kdebugsettings.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0069 add_subdirectory(data/groups)
0070
0071 install( FILES data/kde.renamecategories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR} )
0072 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0073 ki18n_install(po)
0074 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)