utilities/kclock/CMakeLists.txt

0001 #
0002 # Copyright 2020 Han Young <hanyoung@protonmail.com>
0003 # Copyright 2020-2021 Devin Lin <devin@kde.org>
0004 #
0005 # SPDX-License-Identifier: GPL-2.0-or-later
0006 #
0007
0008 cmake_minimum_required(VERSION 3.16)
0009 set(CMAKE_CXX_STANDARD 17)
0010
0011 # KDE Applications version, managed by release script.
0012 set(RELEASE_SERVICE_VERSION_MAJOR "23")
0013 set(RELEASE_SERVICE_VERSION_MINOR "08")
0014 set(RELEASE_SERVICE_VERSION_MICRO "5")
0015 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0016
0017 project(kclock VERSION ${RELEASE_SERVICE_VERSION})
0018
0019 set(KF_MIN_VERSION "5.101.0")
0020 set(QT_MIN_VERSION "5.15.2")
0021
0022 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0023
0024 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0025
0026 # only enable QML debugging on debug builds
0027 set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -DQT_QML_DEBUG ")
0028
0029 include(FeatureSummary)
0030 include(ECMSetupVersion)
0031 include(ECMFindQmlModule)
0032 include(ECMConfiguredInstall)
0033 include(KDEInstallDirs)
0034 include(KDECMakeSettings)
0035 include(KDECompilerSettings NO_POLICY_SCOPE)
0036 include(KDEClangFormat)
0037 include(KDEGitCommitHooks)
0038
0039 ecm_setup_version(${PROJECT_VERSION}
0040     VARIABLE_PREFIX KCLOCK
0041     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/version.h
0042 )
0043
0044 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS
0045     Core
0046     Gui
0047     Quick
0048     Test
0049     Svg
0050     QuickControls2
0051     Multimedia
0052     DBus
0053 )
0054
0055 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0056     Config
0057     I18n
0058     CoreAddons
0059     Plasma
0060     Kirigami2
0061     Notifications
0062     DBusAddons
0063 )
0064 find_package(KF${QT_MAJOR_VERSION}KirigamiAddons 0.6 REQUIRED)
0065
0066 find_package(Qt${QT_MAJOR_VERSION}QuickCompiler)
0067
0068 ki18n_install(po)
0069
0070 add_subdirectory(src)
0071
0072 install(PROGRAMS org.kde.kclock.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0073 install(FILES org.kde.kclockd-autostart.desktop DESTINATION ${KDE_INSTALL_AUTOSTARTDIR})
0074 install(FILES org.kde.kclock.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0075 install(FILES org.kde.kclock.svg DESTINATION ${KDE_INSTALL_FULL_ICONDIR}/hicolor/scalable/apps/)
0076 install(FILES kclockd.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR})
0077
0078 ecm_install_configured_files(INPUT org.kde.kclockd.service.in DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR} @ONLY)
0079
0080 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0081
0082 # add clang-format target for all our real source files
0083 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.hpp)
0084 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0085 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)