apps/lib/CMakeLists.txt

0001 # Kate shared library, used by Kate/KWrite and the addons
0002 ecm_set_disabled_deprecation_versions(
0003     QT 5.15
0004     KF 5.90
0005 )
0006
0007 add_library(kateprivate SHARED "")
0008 set_target_properties(kateprivate PROPERTIES VERSION ${RELEASE_SERVICE_VERSION})
0009 install(TARGETS kateprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0010
0011 # ensure right translations domain, we use one kate.po(t) for lib + apps
0012 target_compile_definitions(kateprivate PRIVATE TRANSLATION_DOMAIN="kate")
0013
0014 # export version to be used by Kate/KWrite/...
0015 target_compile_definitions(kateprivate PUBLIC KATE_VERSION="${RELEASE_SERVICE_VERSION}")
0016
0017 include(GenerateExportHeader)
0018 generate_export_header(
0019   kateprivate
0020   EXPORT_FILE_NAME kateprivate_export.h
0021   EXPORT_MACRO_NAME KATE_PRIVATE_EXPORT
0022 )
0023
0024 target_include_directories(
0025   kateprivate
0026   PUBLIC
0027     ${CMAKE_CURRENT_SOURCE_DIR}
0028     ${CMAKE_CURRENT_SOURCE_DIR}/session
0029     ${CMAKE_CURRENT_SOURCE_DIR}/quickopen
0030     ${CMAKE_CURRENT_SOURCE_DIR}/diff
0031     ${CMAKE_CURRENT_BINARY_DIR} # kateprivate_export.h
0032 )
0033
0034 find_package(
0035   KF6 ${KF5_DEP_VERSION}
0036   QUIET
0037   REQUIRED
0038   COMPONENTS
0039     Crash
0040     IconThemes
0041     TextEditor
0042     TextWidgets
0043     WindowSystem
0044     WidgetsAddons
0045 )
0046
0047 target_link_libraries(
0048   kateprivate
0049   PUBLIC
0050     KF6::CoreAddons
0051     KF6::Crash
0052     KF6::I18n
0053     KF6::IconThemes
0054     KF6::TextEditor
0055     KF6::TextWidgets
0056     KF6::WindowSystem
0057     KF6::KIOGui
0058     KF6::KIOWidgets
0059     KF6::WidgetsAddons
0060 )
0061
0062 if (NOT WIN32 AND NOT HAIKU)
0063     target_compile_definitions(kateprivate PRIVATE -DKDE_INSTALL_FULL_LOCALEDIR=\"${KDE_INSTALL_FULL_LOCALEDIR}\")
0064     target_include_directories(kateprivate PRIVATE ${Intl_INCLUDE_DIRS})
0065     target_link_libraries(kateprivate PRIVATE ${Intl_LIBRARIES})
0066 endif()
0067
0068 # optional KUserFeedback integration
0069 find_package(KF6UserFeedback ${KF5_DEP_VERSION} CONFIG)
0070
0071 if (TARGET KF6::UserFeedbackWidgets)
0072     target_link_libraries(kateprivate PUBLIC KF6::UserFeedbackWidgets)
0073     target_compile_definitions(kateprivate PUBLIC -DWITH_KUSERFEEDBACK)
0074 endif()
0075
0076 # terminal detection
0077 include(CheckFunctionExists)
0078 check_function_exists(ctermid HAVE_CTERMID)
0079 if(HAVE_CTERMID)
0080   target_compile_definitions(kateprivate PRIVATE HAVE_CTERMID)
0081 endif()
0082
0083 # detaching from terminal
0084 check_function_exists(daemon HAVE_DAEMON)
0085 if(HAVE_DAEMON)
0086   target_compile_definitions(kateprivate PRIVATE HAVE_DAEMON)
0087 endif()
0088
0089 ki18n_wrap_ui(kateprivate ui/sessionconfigwidget.ui welcomeview/welcomeview.ui session/katesessionmanagedialog.ui)
0090
0091 target_sources(
0092   kateprivate
0093   PRIVATE
0094     session/katesession.cpp
0095     session/katesessionmanagedialog.cpp
0096     session/katesessionmanager.cpp
0097     session/katesessionsaction.cpp
0098
0099     quickopen/katequickopen.cpp
0100     quickopen/katequickopenmodel.cpp
0101     quickopen/katequickopenlineedit.cpp
0102
0103     kateapp.cpp
0104     kateappadaptor.cpp
0105     kateconfigdialog.cpp
0106     kateconfigplugindialogpage.cpp
0107     katedocmanager.cpp
0108     katefileactions.cpp
0109     katemainwindow.cpp
0110     katemdi.cpp
0111     katemwmodonhddialog.cpp
0112     katepluginmanager.cpp
0113
0114     katerunninginstanceinfo.cpp
0115     katesavemodifieddialog.cpp
0116     katetabbar.cpp
0117     katesplitter.cpp
0118     kateviewmanager.cpp
0119     kateviewspace.cpp
0120     tabmimedata.cpp
0121
0122     kateoutputview.cpp
0123     katestashmanager.cpp
0124     diagnostics/diagnosticview.cpp
0125     diagnostics/diagnosticview.qrc
0126     texthint/KateTextHintManager.cpp
0127     texthint/tooltip.cpp
0128
0129     kateurlbar.cpp
0130
0131     gitprocess.cpp
0132     quickdialog.cpp
0133     ktexteditor_utils.cpp
0134
0135     data/kateprivate.qrc
0136     hostprocess.cpp
0137
0138     diff/diffwidget.cpp
0139     diff/diffeditor.cpp
0140     diff/difflinenumarea.cpp
0141     diff/gitdiff.cpp
0142
0143     filehistorywidget.cpp
0144     commitfilesview.cpp
0145
0146     welcomeview/welcomeview.cpp
0147     welcomeview/recentitemsmodel.cpp
0148     welcomeview/savedsessionsmodel.cpp
0149 )
0150
0151 if (BUILD_PCH)
0152     target_precompile_headers(kateprivate REUSE_FROM katepch)
0153 endif()
0154
0155 if(BUILD_TESTING)
0156   add_subdirectory(autotests)
0157 endif()