apps/kwrite/CMakeLists.txt

0001 # KWrite application
0002
0003 find_package(KF6DBusAddons ${KF5_DEP_VERSION} REQUIRED)
0004
0005 add_executable(kwrite main.cpp  data/kwrite.qrc)
0006 target_link_libraries(kwrite PRIVATE kateprivate PUBLIC KF6::DBusAddons)
0007
0008 # ensure right translations domain, we use one kate.po(t) for lib + apps
0009 target_compile_definitions(kwrite PRIVATE TRANSLATION_DOMAIN="kate")
0010
0011 # application icon, in all sizes needed to have e.g. nice Windows icons, too
0012 set(ICONS_FOLDER ${CMAKE_CURRENT_SOURCE_DIR}/icons)
0013 set(ICON_FILES
0014     ${ICONS_FOLDER}/sc-apps-kwrite.svg
0015     ${ICONS_FOLDER}/16-apps-kwrite.png
0016     ${ICONS_FOLDER}/22-apps-kwrite.png
0017     ${ICONS_FOLDER}/32-apps-kwrite.png
0018     ${ICONS_FOLDER}/44-apps-kwrite.png
0019     ${ICONS_FOLDER}/48-apps-kwrite.png
0020     ${ICONS_FOLDER}/64-apps-kwrite.png
0021     ${ICONS_FOLDER}/128-apps-kwrite.png
0022     ${ICONS_FOLDER}/150-apps-kwrite.png
0023     ${ICONS_FOLDER}/256-apps-kwrite.png
0024     ${ICONS_FOLDER}/310-apps-kwrite.png
0025     ${ICONS_FOLDER}/512-apps-kwrite.png
0026 )
0027
0028 # Add icon files to the application's source files to have CMake bundle them in the executable.
0029 ecm_add_app_icon(ICONS_SOURCES ICONS ${ICON_FILES})
0030 target_sources(kwrite PRIVATE ${ICONS_SOURCES})
0031
0032 # See https://cmake.org/cmake/help/v3.15/prop_tgt/MACOSX_BUNDLE_INFO_PLIST.html
0033 if(APPLE)
0034   set_property(
0035     TARGET kwrite
0036     PROPERTY MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/data/MacOSXBundleInfo.plist.in
0037   )
0038
0039   # These are substituted by CMake into plist.in.
0040   set(MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.KWrite")
0041   set(MACOSX_BUNDLE_BUNDLE_NAME "KWrite")
0042   set(MACOSX_BUNDLE_DISPLAY_NAME "KWrite")
0043   set(MACOSX_BUNDLE_INFO_STRING "KWrite - Text Editor")
0044   set(MACOSX_BUNDLE_LONG_VERSION_STRING "KWrite ${RELEASE_SERVICE_VERSION}")
0045   set(MACOSX_BUNDLE_SHORT_VERSION_STRING "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}")
0046   set(MACOSX_BUNDLE_BUNDLE_VERSION "${RELEASE_SERVICE_VERSION}")
0047   set(MACOSX_BUNDLE_COPYRIGHT "2000-2022 The KWrite Authors")
0048 endif()
0049
0050 install(TARGETS kwrite ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0051
0052 ecm_install_icons(
0053     ICONS ${ICON_FILES}
0054     DESTINATION ${KDE_INSTALL_ICONDIR}
0055     THEME hicolor
0056 )
0057
0058 install(
0059   FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/org.kde.kwrite.desktop
0060   DESTINATION ${KDE_INSTALL_APPDIR}
0061 )
0062
0063 install(
0064   FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/org.kde.kwrite.appdata.xml
0065   DESTINATION ${KDE_INSTALL_METAINFODIR}
0066 )