apps/kate/CMakeLists.txt

0001 # Kate application
0002
0003 find_package(KF6DBusAddons ${KF5_DEP_VERSION} REQUIRED)
0004
0005 if (UNIX AND NOT APPLE)
0006     set(HAVE_X11 TRUE)
0007 endif()
0008
0009 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-kate.h.in ${CMAKE_CURRENT_BINARY_DIR}/config-kate.h @ONLY)
0010
0011 add_executable(kate-bin
0012     main.cpp
0013     data/kate.qrc
0014
0015     katewaiter.cpp
0016
0017     # single application handing for the non-dbus case
0018     SingleApplication/singleapplication.cpp
0019     SingleApplication/singleapplication_p.cpp)
0020 target_link_libraries(kate-bin PRIVATE kateprivate PUBLIC KF6::DBusAddons)
0021
0022 if (HAVE_X11)
0023     target_link_libraries(kate-bin PRIVATE Qt::GuiPrivate)
0024 endif()
0025
0026 # ensure right translations domain, we use one kate.po(t) for lib + apps
0027 target_compile_definitions(kate-bin PRIVATE TRANSLATION_DOMAIN="kate")
0028
0029 # ensure consistent SingleApplication usage
0030 target_compile_definitions(kate-bin PRIVATE -DQAPPLICATION_CLASS=QApplication)
0031
0032 # we have different windows icons, less margins
0033 set(ICONS_FOLDER ${CMAKE_CURRENT_SOURCE_DIR}/icons/unix)
0034 if(WIN32)
0035     set(ICONS_FOLDER ${CMAKE_CURRENT_SOURCE_DIR}/icons/windows)
0036 endif()
0037
0038 # application icon, in all sizes needed to have e.g. nice Windows icons, too
0039 set(ICON_FILES
0040   ${ICONS_FOLDER}/sc-apps-kate.svg
0041   ${ICONS_FOLDER}/16-apps-kate.png
0042   ${ICONS_FOLDER}/22-apps-kate.png
0043   ${ICONS_FOLDER}/32-apps-kate.png
0044   ${ICONS_FOLDER}/44-apps-kate.png
0045   ${ICONS_FOLDER}/48-apps-kate.png
0046   ${ICONS_FOLDER}/64-apps-kate.png
0047   ${ICONS_FOLDER}/128-apps-kate.png
0048   ${ICONS_FOLDER}/150-apps-kate.png
0049   ${ICONS_FOLDER}/256-apps-kate.png
0050   ${ICONS_FOLDER}/310-apps-kate.png
0051   ${ICONS_FOLDER}/512-apps-kate.png
0052 )
0053
0054 # Add icon files to the application's source files to have CMake bundle them in the executable.
0055 ecm_add_app_icon(ICONS_SOURCES ICONS ${ICON_FILES})
0056 target_sources(kate-bin PRIVATE ${ICONS_SOURCES})
0057
0058 set_property(
0059   TARGET kate-bin
0060   PROPERTY OUTPUT_NAME kate
0061 )
0062
0063 # See https://cmake.org/cmake/help/v3.15/prop_tgt/MACOSX_BUNDLE_INFO_PLIST.html
0064 if(APPLE)
0065   set_property(
0066     TARGET kate-bin
0067     PROPERTY MACOSX_BUNDLE_INFO_PLIST ${CMAKE_CURRENT_SOURCE_DIR}/data/MacOSXBundleInfo.plist.in
0068   )
0069
0070   # These are substituted by CMake into plist.in.
0071   set(MACOSX_BUNDLE_DISPLAY_NAME "Kate")
0072   set(MACOSX_BUNDLE_GUI_IDENTIFIER "org.kde.Kate")
0073   set(MACOSX_BUNDLE_BUNDLE_NAME "Kate")
0074   set(MACOSX_BUNDLE_DISPLAY_NAME "Kate")
0075   set(MACOSX_BUNDLE_INFO_STRING "Kate - Advanced Text Editor")
0076   set(MACOSX_BUNDLE_LONG_VERSION_STRING "Kate ${RELEASE_SERVICE_VERSION}")
0077   set(MACOSX_BUNDLE_SHORT_VERSION_STRING "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}")
0078   set(MACOSX_BUNDLE_BUNDLE_VERSION "${RELEASE_SERVICE_VERSION}")
0079   set(MACOSX_BUNDLE_COPYRIGHT "2000-2022 The Kate Authors")
0080 endif()
0081
0082 install(TARGETS kate-bin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0083
0084 ecm_install_icons(
0085   ICONS ${ICON_FILES}
0086   DESTINATION ${KDE_INSTALL_ICONDIR}
0087   THEME hicolor
0088 )
0089
0090 install(
0091   PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/data/org.kde.kate.desktop
0092   DESTINATION ${KDE_INSTALL_APPDIR}
0093 )
0094
0095 install(
0096   FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/org.kde.kate.appdata.xml
0097   DESTINATION ${KDE_INSTALL_METAINFODIR}
0098 )