xwaylandvideobridge/src/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2023 David Edmundson <kde@davidedmundson.co.uk>
0003 # SPDX-FileCopyrightText: 2023 Aleix Pol <aleixpol@kde.org>
0004
0005 add_executable(xwaylandvideobridge)
0006
0007 qt_add_dbus_interface(
0008    XDP_SRCS
0009    org.freedesktop.portal.ScreenCast.xml
0010    xdp_dbus_screencast_interface
0011 )
0012
0013 ecm_qt_install_logging_categories(EXPORT XWAYLANDVIDEOBRIDGE FILE xwaylandvideobridge.categories DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
0014 ecm_qt_declare_logging_category(XDP_SRCS HEADER xwaylandvideobridge_debug.h IDENTIFIER XWAYLANDBRIDGE CATEGORY_NAME org.kde.xwaylandvideobridge DESCRIPTION "Xwayland Video Bridge" EXPORT XWAYLANDVIDEOBRIDGE)
0015
0016 target_sources(xwaylandvideobridge PRIVATE
0017     main.cpp
0018     xwaylandvideobridge.cpp
0019     contentswindow.cpp
0020     x11recordingnotifier.cpp
0021     ${XDP_SRCS}
0022 )
0023
0024 configure_file(version.h.in version.h)
0025
0026 target_link_libraries(xwaylandvideobridge
0027     KF${QT_MAJOR_VERSION}::I18n
0028     KF${QT_MAJOR_VERSION}::CoreAddons
0029     KF${QT_MAJOR_VERSION}::WindowSystem
0030     KF${QT_MAJOR_VERSION}::Notifications
0031     Qt${QT_MAJOR_VERSION}::Quick
0032     Qt${QT_MAJOR_VERSION}::DBus
0033     Qt${QT_MAJOR_VERSION}::Widgets
0034     K::KPipeWireRecord
0035     XCB::XCB
0036     XCB::COMPOSITE
0037     XCB::RECORD
0038 )
0039
0040 if (QT_MAJOR_VERSION STREQUAL "6")
0041     target_link_libraries(xwaylandvideobridge Qt6::GuiPrivate KF6::StatusNotifierItem)
0042 elseif (QT_MAJOR_VERSION STREQUAL "5")
0043     target_link_libraries(xwaylandvideobridge Qt5::X11Extras)
0044 endif()
0045
0046 install(TARGETS xwaylandvideobridge ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0047 install(PROGRAMS org.kde.xwaylandvideobridge.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0048 install(FILES org.kde.xwaylandvideobridge.desktop DESTINATION ${KDE_INSTALL_AUTOSTARTDIR})
0049 install(FILES org.kde.xwaylandvideobridge.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})