system/wacomtablet/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.0)
0002 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
0003
0004 cmake_policy(SET CMP0048 NEW)
0005 project(wacomtablet VERSION "3.3.0")
0006
0007 set(QT_MIN_VERSION "5.7.0")
0008 find_package(ECM 1.6.0 REQUIRED CONFIG)
0009 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR} ${CMAKE_SOURCE_DIR}/cmake/modules)
0010 include(KDEInstallDirs)
0011 include(KDECMakeSettings)
0012 include(KDECompilerSettings NO_POLICY_SCOPE)
0013 include(FeatureSummary)
0014 include(ECMOptionalAddSubdirectory)
0015 include(ECMInstallIcons)
0016 include(ECMSetupVersion)
0017 include(ECMQtDeclareLoggingCategory)
0018
0019 ecm_setup_version(${PROJECT_VERSION}
0020     VARIABLE_PREFIX WACOMTABLET
0021     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/wacomtablet-version.h"
0022 )
0023
0024 find_package(Qt5 REQUIRED COMPONENTS Core Gui Widgets DBus X11Extras Qml)
0025 find_package(KF5 REQUIRED COMPONENTS CoreAddons I18n GlobalAccel Config XmlGui WidgetsAddons WindowSystem Notifications DBusAddons Plasma DocTools)
0026 find_package(XCB REQUIRED COMPONENTS XINPUT)
0027 find_package(X11 REQUIRED)
0028
0029 find_package(PkgConfig REQUIRED)
0030 pkg_check_modules(LIBWACOM libwacom REQUIRED IMPORTED_TARGET)
0031 pkg_check_modules(XORGWACOM xorg-wacom REQUIRED IMPORTED_TARGET)
0032
0033 if(${LIBWACOM_VERSION} VERSION_LESS "0.29")
0034     message(STATUS "Button detection with libwacom requires version at least 0.29. Detected version is: " ${LIBWACOM_VERSION})
0035     add_definitions(-DLIBWACOM_EVDEV_MISSING)
0036 endif()
0037
0038 add_definitions( -DQT_STRICT_ITERATORS )
0039 add_definitions( -DQT_NO_CAST_FROM_ASCII )
0040 add_definitions( -DQT_NO_CAST_TO_ASCII )
0041 add_definitions( -DQT_USE_QSTRINGBUILDER )
0042
0043 add_subdirectory( src )
0044 add_subdirectory( data )
0045 add_subdirectory( images )
0046 add_subdirectory( doc )
0047
0048 ### Tests
0049 if(BUILD_TESTING)
0050   find_package(Qt5Test ${QT_MIN_VERSION} CONFIG REQUIRED)
0051   add_subdirectory( autotests )
0052 endif()
0053
0054 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)