qt4/style/CMakeLists.txt

0001 set(qtcurve_SRCS
0002   qtcurve.cpp
0003   qtcurve_plugin.cpp
0004   windowmanager.cpp
0005   blurhelper.cpp
0006   prepolish.cpp
0007   utils.cpp
0008   shortcuthandler.cpp
0009   argbhelper.cpp
0010   macmenu.cpp
0011   shadowhelper.cpp)
0012 set(qtcurve_MOC_HDRS
0013   qtcurve.h
0014   qtcurve_p.h
0015   qtcurve_plugin.h
0016   windowmanager.h
0017   blurhelper.h
0018   shortcuthandler.h
0019   argbhelper.h
0020   macmenu.h
0021   macmenu-dbus.h
0022   shadowhelper.h)
0023
0024 translate_add_sources(${qtcurve_SRCS} ${qtcurve_MOC_HDRS})
0025
0026 if(NOT ENABLE_QT4)
0027   return()
0028 endif()
0029
0030 set(qtcurve_style_common_SRCS
0031   ../common/common.cpp
0032   ../common/config_file.cpp)
0033
0034 foreach(pngname check_on check_x_on dialog_error dialog_information
0035     dialog_warning)
0036   add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/${pngname}-png.h"
0037     COMMAND "${PROJECT_BINARY_DIR}/tools/qt-dump-png"
0038     "${PROJECT_SOURCE_DIR}/data/${pngname}.png" "qtc_${pngname}"
0039     "${CMAKE_CURRENT_BINARY_DIR}/${pngname}-png.h"
0040     DEPENDS qt-dump-png "${PROJECT_SOURCE_DIR}/data/${pngname}.png")
0041   add_custom_target(qtc_qt4_${pngname}_hdr
0042     DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/${pngname}-png.h")
0043 endforeach()
0044
0045 set(qtcurve_SRCS
0046   ${qtcurve_SRCS}
0047   ${qtcurve_style_common_SRCS})
0048
0049 add_definitions(-DQT_PLUGIN)
0050 include_directories("${CMAKE_CURRENT_BINARY_DIR}")
0051 include_directories(SYSTEM
0052   "${QT_QTGUI_INCLUDE_DIR}"
0053   "${QT_QTCORE_INCLUDE_DIR}"
0054   "${QT_QTDBUS_INCLUDE_DIR}"
0055   "${QT_QTSVG_INCLUDE_DIR}")
0056 qt4_wrap_cpp(qtcurve_MOC_SRCS ${qtcurve_MOC_HDRS})
0057 add_library(qtcurve-qt4 MODULE ${qtcurve_SRCS} ${qtcurve_MOC_SRCS})
0058 add_dependencies(qtcurve-qt4 qtc_qt4_check_on_hdr qtc_qt4_check_x_on_hdr)
0059 set_target_properties(qtcurve-qt4 PROPERTIES
0060   LIBRARY_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}"
0061   OUTPUT_NAME "qtcurve"
0062   PREFIX "")
0063
0064 if(QTC_QT4_ENABLE_KDE)
0065   install(FILES qtcurve.themerc DESTINATION ${DATA_INSTALL_DIR}/kstyle/themes)
0066   set(QTC_KDE_LIBS ${KDE4_KDEUI_LIBS})
0067   if(NOT QTC_DISABLE_KDEFILEDIALOG_CALLS)
0068     set(QTC_KFILEDIALOG_LIBS ${KDE4_KIO_LIBS} ${KDE4_KDECORE_LIBS})
0069   endif()
0070 else()
0071   add_dependencies(qtcurve-qt4 qtc_qt4_dialog_error_hdr
0072     qtc_qt4_dialog_information_hdr
0073     qtc_qt4_dialog_warning_hdr)
0074 endif()
0075
0076 target_link_libraries(qtcurve-qt4
0077   ${QTC_KDE_LIBS}
0078   ${QTC_KFILEDIALOG_LIBS}
0079   ${QT_QTGUI_LIBRARY}
0080   ${QT_QTCORE_LIBRARY}
0081   ${QT_QTSVG_LIBRARY}
0082   ${QT_QTDBUS_LIBRARY}
0083   qtcurve-utils)
0084
0085 if(QTC_QT4_ENABLE_KDE)
0086   install(TARGETS qtcurve-qt4 DESTINATION ${QTCURVE_STYLE_DIR})
0087 else()
0088   install(TARGETS qtcurve-qt4 LIBRARY DESTINATION ${QTCURVE_STYLE_DIR})
0089 endif()