Warning, /system/liquidshell/FindQt5ThemeSupport.cmake is written in an unsupported language. File is not indexed.
0001 #.rst:
0002 # FindQt5ThemeSupport
0003 # -------
0004 #
0005 # Try to find Qt5ThemeSupport on a Unix system.
0006 #
0007 # This will define the following variables:
0008 #
0009 # ``Qt5ThemeSupport_FOUND``
0010 # True if (the requested version of) Qt5ThemeSupport is available
0011 # ``Qt5ThemeSupport_VERSION``
0012 # The version of Qt5ThemeSupport
0013 # ``Qt5ThemeSupport_LIBRARIES``
0014 # This can be passed to target_link_libraries() instead of the ``Qt5ThemeSupport::Qt5ThemeSupport``
0015 # target
0016 # ``Qt5ThemeSupport_INCLUDE_DIRS``
0017 # This should be passed to target_include_directories() if the target is not
0018 # used for linking
0019 # ``Qt5ThemeSupport_DEFINITIONS``
0020 # This should be passed to target_compile_options() if the target is not
0021 # used for linking
0022 #
0023 # If ``Qt5ThemeSupport_FOUND`` is TRUE, it will also define the following imported target:
0024 #
0025 # ``Qt5ThemeSupport::Qt5ThemeSupport``
0026 # The Qt5ThemeSupport library
0027 #
0028 # In general we recommend using the imported target, as it is easier to use.
0029 # Bear in mind, however, that if the target is in the link interface of an
0030 # exported library, it must be made available by the package config file.
0031
0032 #=============================================================================
0033 # SPDX-FileCopyrightText: 2014 Alex Merry <alex.merry@kde.org>
0034 # SPDX-FileCopyrightText: 2014 Martin Gräßlin <mgraesslin@kde.org>
0035 # SPDX-FileCopyrightText: 2016 Takahiro Hashimoto <kenya888@gmail.com>
0036 #
0037 # SPDX-License-Identifier: BSD-3-Clause
0038 #=============================================================================
0039
0040 if(CMAKE_VERSION VERSION_LESS 2.8.12)
0041 message(FATAL_ERROR "CMake 2.8.12 is required by FindQt5ThemeSupport.cmake")
0042 endif()
0043 if(CMAKE_MINIMUM_REQUIRED_VERSION VERSION_LESS 2.8.12)
0044 message(AUTHOR_WARNING "Your project should require at least CMake 2.8.12 to use FindQt5ThemeSupport.cmake")
0045 endif()
0046
0047 # Use pkg-config to get the directories and then use these values
0048 # in the FIND_PATH() and FIND_LIBRARY() calls
0049 find_package(PkgConfig)
0050 pkg_check_modules(PKG_Qt5ThemeSupport QUIET Qt5Gui)
0051
0052 set(Qt5ThemeSupport_DEFINITIONS ${PKG_Qt5ThemeSupport_CFLAGS_OTHER})
0053 set(Qt5ThemeSupport_VERSION ${PKG_Qt5ThemeSupport_VERSION})
0054
0055 find_path(Qt5ThemeSupport_INCLUDE_DIR
0056 NAMES
0057 QtThemeSupport/private/qgenericunixthemes_p.h
0058 HINTS
0059 ${PKG_Qt5ThemeSupport_INCLUDEDIR}/QtThemeSupport/${PKG_Qt5ThemeSupport_VERSION}/
0060 )
0061 find_library(Qt5ThemeSupport_LIBRARY
0062 NAMES
0063 Qt5ThemeSupport
0064 HINTS
0065 ${PKG_Qt5ThemeSupport_LIBRARY_DIRS}
0066 )
0067
0068 include(FindPackageHandleStandardArgs)
0069 find_package_handle_standard_args(Qt5ThemeSupport
0070 FOUND_VAR
0071 Qt5ThemeSupport_FOUND
0072 REQUIRED_VARS
0073 Qt5ThemeSupport_LIBRARY
0074 Qt5ThemeSupport_INCLUDE_DIR
0075 VERSION_VAR
0076 Qt5ThemeSupport_VERSION
0077 )
0078
0079 if(Qt5ThemeSupport_FOUND AND NOT TARGET Qt5ThemeSupport::Qt5ThemeSupport)
0080 add_library(Qt5ThemeSupport::Qt5ThemeSupport UNKNOWN IMPORTED)
0081 set_target_properties(Qt5ThemeSupport::Qt5ThemeSupport PROPERTIES
0082 IMPORTED_LOCATION "${Qt5ThemeSupport_LIBRARY}"
0083 INTERFACE_COMPILE_OPTIONS "${Qt5ThemeSupport_DEFINITIONS}"
0084 INTERFACE_INCLUDE_DIRECTORIES "${Qt5ThemeSupport_INCLUDE_DIR}"
0085 )
0086 endif()
0087
0088 mark_as_advanced(Qt5ThemeSupport_LIBRARY Qt5ThemeSupport_INCLUDE_DIR)
0089
0090 # compatibility variables
0091 set(Qt5ThemeSupport_LIBRARIES ${Qt5ThemeSupport_LIBRARY})
0092 set(Qt5ThemeSupport_INCLUDE_DIRS ${Qt5ThemeSupport_INCLUDE_DIR})
0093 set(Qt5ThemeSupport_VERSION_STRING ${Qt5ThemeSupport_VERSION})
0094
0095
0096 include(FeatureSummary)
0097 set_package_properties(Qt5ThemeSupport PROPERTIES
0098 URL "https://www.qt.io"
0099 DESCRIPTION "Qt ThemeSupport module."
0100 )