system/libdebconf-kde/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002 cmake_policy(SET CMP0048 NEW)
0003
0004 if (POLICY CMP0043)
0005   cmake_policy(SET CMP0043 NEW)
0006 endif()
0007 if (POLICY CMP0063)
0008   cmake_policy(SET CMP0063 NEW)
0009 endif()
0010
0011 project(libdebconf-kde VERSION 1.1.1)
0012
0013 find_package(ECM 0.0.14 REQUIRED NO_MODULE)
0014 set(CMAKE_MODULE_PATH
0015     ${ECM_MODULE_PATH}
0016     ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules)
0017
0018 include(ECMPackageConfigHelpers)
0019 include(ECMSetupVersion)
0020 include(FeatureSummary)
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings)
0024
0025 set(REQUIRED_QT_VERSION 5.2.0) # Used in CMakeConfig to check deps
0026 find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED
0027     COMPONENTS
0028         Widgets
0029         Network
0030 )
0031
0032 find_package(KF5 5.0.0 REQUIRED
0033     COMPONENTS
0034         CoreAddons
0035         I18n
0036         IconThemes
0037         TextWidgets
0038         WidgetsAddons
0039 )
0040
0041 if(ECM_VERSION VERSION_GREATER 1.5.0)
0042     # >1.5 has an optional compatibility option for the package version file.
0043     # TODO: bump dep and remove this check once 1.7 is out.
0044     set(VERSION_COMPAT_OPTION COMPATIBILITY SameMajorVersion)
0045 endif()
0046 ecm_setup_version(${PROJECT_VERSION}
0047     VARIABLE_PREFIX DEBCONF
0048     SOVERSION ${PROJECT_VERSION_MAJOR}
0049     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/DebconfVersion.h"
0050     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/DebconfKDEConfigVersion.cmake"
0051         ${VERSION_COMPAT_OPTION}
0052 )
0053
0054 add_definitions(-DPROJECT_VERSION=\"${PROJECT_VERSION}\")
0055 add_definitions(
0056     -DQT_NO_KEYWORDS
0057     -DQT_NO_CAST_TO_ASCII
0058     -DQT_NO_CAST_FROM_ASCII
0059     -DQT_STRICT_ITERATORS
0060     -DQT_NO_URL_CAST_FROM_STRING
0061     -DQT_NO_CAST_FROM_BYTEARRAY
0062     -DQT_USE_QSTRINGBUILDER
0063     -DQT_DISABLE_DEPRECATED_BEFORE=0x050900
0064 )
0065
0066 include_directories(
0067     ${CMAKE_CURRENT_SOURCE_DIR}/src
0068     ${CMAKE_CURRENT_SOURCE_DIR}
0069     ${CMAKE_CURRENT_BINARY_DIR}
0070 )
0071
0072 # create a Config.cmake and a ConfigVersion.cmake file and install them
0073 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/DebconfKDE")
0074
0075 ecm_configure_package_config_file(
0076     "${CMAKE_CURRENT_SOURCE_DIR}/DebconfKDEConfig.cmake.in"
0077     "${CMAKE_CURRENT_BINARY_DIR}/DebconfKDEConfig.cmake"
0078     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR})
0079
0080 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/DebconfKDEConfig.cmake"
0081               "${CMAKE_CURRENT_BINARY_DIR}/DebconfKDEConfigVersion.cmake"
0082     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0083     COMPONENT Devel)
0084 install(EXPORT DebconfKDETargets
0085         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0086         FILE DebconfKDETargets.cmake
0087         NAMESPACE DebconfKDE::)
0088
0089 add_subdirectory(src)
0090 add_subdirectory(tools)
0091
0092 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)