system/kcm-grub2/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16 FATAL_ERROR)
0002 project(kcm-grub2)
0003
0004 set(PROJECT_VERSION "0.6.4")
0005 set(QT_MIN_VERSION "5.15.2")
0006 set(KF5_MIN_VERSION "5.105")
0007 find_package(ECM ${KF5_MIN_VERSION}  REQUIRED NO_MODULE)
0008 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
0009
0010 include(KDEInstallDirs)
0011 include(KDECMakeSettings)
0012 include(KDECompilerSettings NO_POLICY_SCOPE)
0013
0014 include(ECMInstallIcons)
0015 include(FeatureSummary)
0016
0017 set(KCM_GRUB2_VERSION ${PROJECT_VERSION})
0018
0019 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules ${CMAKE_MODULE_PATH})
0020
0021 include(GRUBPaths)
0022
0023 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS Core Gui Widgets)
0024
0025 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0026     Auth
0027     I18n
0028     KCMUtils
0029     KIO
0030     Solid
0031 )
0032
0033 # Qt
0034 add_definitions(-DQT_NO_KEYWORDS -DQT_NO_FOREACH -DQT_NO_CAST_FROM_ASCII -DQT_NO_CAST_TO_ASCII -DQT_NO_CAST_FROM_BYTEARRAY -DQT_NO_KEYWORDS -DQT_STRICT_ITERATORS -DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
0035 # ImageMagick
0036 add_definitions(-DMAGICKCORE_HDRI_ENABLE=0 -DMAGICKCORE_QUANTUM_DEPTH=16)
0037
0038 find_package(ImageMagick COMPONENTS Magick++ MagickCore)
0039 set_package_properties(ImageMagick PROPERTIES
0040                        DESCRIPTION "Create splash images compatible with GRUB2"
0041                        URL "http://www.imagemagick.org/"
0042                        TYPE OPTIONAL)
0043 if(ImageMagick_FOUND)
0044     set(HAVE_IMAGEMAGICK 1)
0045 else()
0046     set(HAVE_IMAGEMAGICK 0)
0047 endif()
0048
0049 find_package(HD)
0050 set_package_properties(hwinfo PROPERTIES
0051                        DESCRIPTION "Retrieve list of resolutions valid in GRUB2"
0052                        URL "http://www.opensuse.org/"
0053                        TYPE OPTIONAL)
0054 if(HD_FOUND)
0055     set(HAVE_HD 1)
0056 else()
0057     set(HAVE_HD 0)
0058 endif()
0059
0060 find_package(QApt 3.0.0)
0061 set_package_properties(QApt PROPERTIES
0062                        DESCRIPTION "Remove unneeded old entries (qapt backend)"
0063                        URL "https://commits.kde.org/libqapt"
0064                        TYPE OPTIONAL)
0065 if(QApt_FOUND)
0066     set(HAVE_QAPT 1)
0067 else()
0068     set(HAVE_QAPT 0)
0069 endif()
0070
0071 find_package(PackageKitQt${QT_MAJOR_VERSION})
0072 set_package_properties(PackageKitQt${QT_MAJOR_VERSION} PROPERTIES
0073                        DESCRIPTION "Remove unneeded old entries (qpackagekit backend)"
0074                        URL "http://www.packagekit.org/"
0075                        TYPE OPTIONAL)
0076 if(PackageKitQt5_FOUND)
0077     set(HAVE_QPACKAGEKIT 1)
0078 else()
0079     set(HAVE_QPACKAGEKIT 0)
0080 endif()
0081
0082 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/src/config.h)
0083
0084 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0085
0086 add_subdirectory(src)
0087
0088 find_package(KF5I18n CONFIG REQUIRED)
0089 ki18n_install(po)