system/drkonqi-pk-debug-installer/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2017-2020 Harald Sitter <sitter@kde.org>
0003
0004 cmake_minimum_required(VERSION 3.16.3)
0005
0006 set(QT_MIN_VERSION "5.15.0")
0007 set(KF5_MIN_VERSION "5.75")
0008
0009 project(drkonqi-pk-debug-installer)
0010 set(PROJECT_VERSION "1.0")
0011 if(NOT VERSION_STRING_FULL) # May be set by packaging; realistically we have no version
0012     set(VERSION_STRING_FULL ${PROJECT_VERSION})
0013 endif()
0014
0015 set(DEBUG_REPO_APPSTREAM_IDS ""
0016     CACHE STRING
0017         "Semicolon separated list of appstream 'repository' component IDs describing debug repos that need adding")
0018
0019 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0020 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0021
0022 set(CMAKE_AUTOUIC ON)
0023 set(CMAKE_AUTOMOC ON)
0024 set(CMAKE_AUTORCC ON)
0025
0026 set(CMAKE_CXX_STANDARD 17)
0027 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0028
0029 include(FeatureSummary)
0030 include(KDEInstallDirs)
0031 include(KDECMakeSettings)
0032 include(KDECompilerSettings)
0033 include(ECMQtDeclareLoggingCategory)
0034
0035 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED Widgets DBus Test Quick)
0036 find_package(KF5CoreAddons ${KF5_MIN_VERSION} REQUIRED)
0037 find_package(KF5I18n ${KF5_MIN_VERSION} REQUIRED)
0038 find_package(KF5Declarative ${KF5_MIN_VERSION} REQUIRED)
0039 find_package(PackageKitQt5 REQUIRED)
0040 find_package(AppStreamQt 0.16 REQUIRED)
0041
0042 # Disable legacy stuff to get rid of some deprecation warnings.
0043 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050e00)
0044
0045 # Standardish sanity definitions we tend to use in KDE software.
0046 add_definitions(
0047     -DQT_NO_CAST_TO_ASCII
0048     -DQT_NO_CAST_FROM_ASCII
0049     -DQT_NO_URL_CAST_FROM_STRING
0050     -DQT_NO_CAST_FROM_BYTEARRAY
0051     -DQT_NO_NARROWING_CONVERSIONS_IN_CONNECT
0052 )
0053
0054 if(BUILD_TESTING)
0055 # None here right now. A bit tricky to test anything here without an abstraction interface towards PK.
0056 #  add_subdirectory(autotests)
0057 endif()
0058
0059 ki18n_install(po)
0060
0061 add_subdirectory(src)
0062
0063 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)