Warning, /system/dolphin/src/CMakeLists.txt is written in an unsupported language. File is not indexed.
0001 include(ECMAddAppIcon)
0002
0003 configure_file(config-dolphin.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-dolphin.h)
0004
0005 add_definitions(
0006 -DTRANSLATION_DOMAIN=\"dolphin\"
0007 )
0008 remove_definitions(
0009 -DQT_NO_CAST_FROM_BYTEARRAY
0010 -DQT_NO_CAST_FROM_ASCII
0011 -DQT_NO_CAST_TO_ASCII
0012 )
0013
0014 ##########################################
0015
0016 add_library(dolphinvcs SHARED)
0017
0018 target_sources(dolphinvcs PRIVATE
0019 views/versioncontrol/kversioncontrolplugin.cpp
0020 )
0021
0022 generate_export_header(dolphinvcs BASE_NAME dolphinvcs)
0023
0024 target_link_libraries(
0025 dolphinvcs PUBLIC
0026 Qt6::Widgets
0027 )
0028
0029 set_target_properties(dolphinvcs PROPERTIES
0030 VERSION ${DOLPHINVCS_VERSION}
0031 SOVERSION ${DOLPHINVCS_SOVERSION}
0032 EXPORT_NAME DolphinVcs
0033 )
0034
0035 ecm_generate_headers(dolphinvcs_LIB_HEADERS
0036 HEADER_NAMES
0037 KVersionControlPlugin
0038
0039 RELATIVE "views/versioncontrol"
0040 REQUIRED_HEADERS dolphinvcs_LIB_HEADERS
0041 )
0042 target_include_directories(dolphinvcs INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>")
0043
0044 install(TARGETS dolphinvcs EXPORT DolphinVcsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0045
0046 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphinvcs_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
0047 install(FILES ${dolphinvcs_LIB_HEADERS} DESTINATION "${KDE_INSTALL_INCLUDEDIR}/Dolphin" COMPONENT Devel)
0048
0049 ########### next target ###############
0050
0051 add_library(dolphinprivate SHARED)
0052
0053 target_sources(dolphinprivate PRIVATE
0054 kitemviews/kfileitemlistview.cpp
0055 kitemviews/kfileitemlistwidget.cpp
0056 kitemviews/kfileitemlisttostring.cpp
0057 kitemviews/kfileitemmodel.cpp
0058 kitemviews/kfileitemmodelrolesupdater.cpp
0059 kitemviews/kitemlistcontainer.cpp
0060 kitemviews/kitemlistcontroller.cpp
0061 kitemviews/kitemlistgroupheader.cpp
0062 kitemviews/kitemlistheader.cpp
0063 kitemviews/kitemlistselectionmanager.cpp
0064 kitemviews/kitemliststyleoption.cpp
0065 kitemviews/kitemlistview.cpp
0066 kitemviews/kitemlistviewaccessible.cpp
0067 kitemviews/kitemlistwidget.cpp
0068 kitemviews/kitemmodelbase.cpp
0069 kitemviews/kitemset.cpp
0070 kitemviews/kstandarditemlistgroupheader.cpp
0071 kitemviews/kstandarditemlistwidget.cpp
0072 kitemviews/kstandarditemlistview.cpp
0073 kitemviews/private/kdirectorycontentscounter.cpp
0074 kitemviews/private/kdirectorycontentscounterworker.cpp
0075 kitemviews/private/kfileitemclipboard.cpp
0076 kitemviews/private/kfileitemmodelfilter.cpp
0077 kitemviews/private/kitemlistheaderwidget.cpp
0078 kitemviews/private/kitemlistkeyboardsearchmanager.cpp
0079 kitemviews/private/kitemlistroleeditor.cpp
0080 kitemviews/private/kitemlistrubberband.cpp
0081 kitemviews/private/kitemlistselectiontoggle.cpp
0082 kitemviews/private/kitemlistsizehintresolver.cpp
0083 kitemviews/private/kitemlistsmoothscroller.cpp
0084 kitemviews/private/kitemlistviewanimation.cpp
0085 kitemviews/private/kitemlistviewlayouter.cpp
0086 kitemviews/private/kitemviewsutils.cpp
0087 kitemviews/private/kpixmapmodifier.cpp
0088 settings/applyviewpropsjob.cpp
0089 settings/viewmodes/viewmodesettings.cpp
0090 settings/viewpropertiesdialog.cpp
0091 settings/viewpropsprogressinfo.cpp
0092 selectionmode/actiontexthelper.cpp
0093 views/dolphinfileitemlistwidget.cpp
0094 views/dolphinitemlistview.cpp
0095 views/dolphinnewfilemenuobserver.cpp
0096 views/dolphinremoteencoding.cpp
0097 views/dolphinview.cpp
0098 views/dolphinviewactionhandler.cpp
0099 views/draganddrophelper.cpp
0100 views/versioncontrol/updateitemstatesthread.cpp
0101 views/versioncontrol/versioncontrolobserver.cpp
0102 views/viewmodecontroller.cpp
0103 views/viewproperties.cpp
0104 views/zoomlevelinfo.cpp
0105 dolphinremoveaction.cpp
0106 middleclickactioneventfilter.cpp
0107 dolphinnewfilemenu.cpp
0108
0109 kitemviews/kfileitemlistview.h
0110 kitemviews/kfileitemlistwidget.h
0111 kitemviews/kfileitemlisttostring.h
0112 kitemviews/kfileitemmodel.h
0113 kitemviews/kfileitemmodelrolesupdater.h
0114 kitemviews/kitemlistcontainer.h
0115 kitemviews/kitemlistcontroller.h
0116 kitemviews/kitemlistgroupheader.h
0117 kitemviews/kitemlistheader.h
0118 kitemviews/kitemlistselectionmanager.h
0119 kitemviews/kitemliststyleoption.h
0120 kitemviews/kitemlistview.h
0121 kitemviews/kitemlistviewaccessible.h
0122 kitemviews/kitemlistwidget.h
0123 kitemviews/kitemmodelbase.h
0124 kitemviews/kitemset.h
0125 kitemviews/kstandarditemlistgroupheader.h
0126 kitemviews/kstandarditemlistwidget.h
0127 kitemviews/kstandarditemlistview.h
0128 kitemviews/private/kdirectorycontentscounter.h
0129 kitemviews/private/kdirectorycontentscounterworker.h
0130 kitemviews/private/kfileitemclipboard.h
0131 kitemviews/private/kfileitemmodelfilter.h
0132 kitemviews/private/kitemlistheaderwidget.h
0133 kitemviews/private/kitemlistkeyboardsearchmanager.h
0134 kitemviews/private/kitemlistroleeditor.h
0135 kitemviews/private/kitemlistrubberband.h
0136 kitemviews/private/kitemlistselectiontoggle.h
0137 kitemviews/private/kitemlistsizehintresolver.h
0138 kitemviews/private/kitemlistsmoothscroller.h
0139 kitemviews/private/kitemlistviewanimation.h
0140 kitemviews/private/kitemlistviewlayouter.h
0141 kitemviews/private/kpixmapmodifier.h
0142 settings/applyviewpropsjob.h
0143 settings/viewmodes/viewmodesettings.h
0144 settings/viewpropertiesdialog.h
0145 settings/viewpropsprogressinfo.h
0146 selectionmode/actiontexthelper.h
0147 views/dolphinfileitemlistwidget.h
0148 views/dolphinitemlistview.h
0149 views/dolphinnewfilemenuobserver.h
0150 views/dolphinremoteencoding.h
0151 views/dolphinview.h
0152 views/dolphinviewactionhandler.h
0153 views/draganddrophelper.h
0154 views/versioncontrol/updateitemstatesthread.h
0155 views/versioncontrol/versioncontrolobserver.h
0156 views/viewmodecontroller.h
0157 views/viewproperties.h
0158 views/zoomlevelinfo.h
0159 dolphinremoveaction.h
0160 middleclickactioneventfilter.h
0161 dolphinnewfilemenu.h
0162 )
0163
0164 ecm_qt_declare_logging_category(dolphinprivate
0165 HEADER dolphindebug.h
0166 IDENTIFIER DolphinDebug
0167 CATEGORY_NAME org.kde.dolphin
0168 DESCRIPTION "dolphin"
0169 EXPORT DOLPHIN
0170 )
0171
0172 if(HAVE_BALOO)
0173 target_sources(dolphinprivate PRIVATE
0174 views/tooltips/dolphinfilemetadatawidget.cpp
0175 views/tooltips/tooltipmanager.cpp
0176 kitemviews/private/kbaloorolesprovider.cpp
0177 views/tooltips/dolphinfilemetadatawidget.h
0178 views/tooltips/tooltipmanager.h
0179 kitemviews/private/kbaloorolesprovider.h
0180 )
0181 endif()
0182
0183 kconfig_add_kcfg_files(dolphinprivate
0184 settings/dolphin_compactmodesettings.kcfgc
0185 settings/dolphin_directoryviewpropertysettings.kcfgc
0186 settings/dolphin_detailsmodesettings.kcfgc
0187 settings/dolphin_iconsmodesettings.kcfgc
0188 settings/dolphin_contentdisplaysettings.kcfgc
0189 settings/dolphin_generalsettings.kcfgc
0190 settings/dolphin_contextmenusettings.kcfgc
0191 settings/dolphin_versioncontrolsettings.kcfgc
0192 )
0193
0194 generate_export_header(dolphinprivate BASE_NAME dolphin)
0195
0196 target_link_libraries(
0197 dolphinprivate PUBLIC
0198 dolphinvcs
0199 Qt6::Concurrent
0200 Qt6::Gui
0201 KF6::I18n
0202 KF6::IconThemes
0203 KF6::KIOCore
0204 KF6::KIOWidgets
0205 KF6::KIOFileWidgets
0206 KF6::Completion
0207 KF6::TextWidgets
0208 KF6::ConfigCore
0209 KF6::NewStuffWidgets # KNSWidgets::Button
0210 KF6::Parts
0211 KF6::WindowSystem
0212 KF6::WidgetsAddons
0213 KF6::Codecs
0214 KF6::KCMUtils
0215
0216 ${FTS_LIB}
0217 )
0218
0219 if(HAVE_BALOO)
0220 target_link_libraries(
0221 dolphinprivate PUBLIC
0222 KF6::FileMetaData
0223 KF6::Baloo
0224 KF6::BalooWidgets
0225 )
0226 endif()
0227
0228 set_target_properties(dolphinprivate PROPERTIES
0229 VERSION ${DOLPHINPRIVATE_VERSION}
0230 SOVERSION ${DOLPHINPRIVATE_SOVERSION}
0231 )
0232
0233 install(TARGETS dolphinprivate ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0234 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/dolphin_export.h DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
0235
0236 ##########################################
0237 configure_file(dolphinpart.json.in ${CMAKE_CURRENT_BINARY_DIR}/dolphinpart.json @ONLY)
0238
0239 add_library(dolphinpart MODULE)
0240
0241 target_sources(dolphinpart PRIVATE
0242 dolphinpart.cpp
0243 dolphinpart_ext.cpp
0244 dolphindebug.cpp
0245 dolphinpart.h
0246 dolphinpart_ext.h
0247 dolphindebug.h
0248
0249 dolphinpart.qrc
0250 )
0251
0252 target_link_libraries(dolphinpart
0253 dolphinprivate
0254 )
0255
0256 install(TARGETS dolphinpart DESTINATION ${KDE_INSTALL_PLUGINDIR}/kf6/parts)
0257 install(FILES dolphinpartactions.desktop DESTINATION "${KDE_INSTALL_DATADIR}/dolphin/")
0258
0259 ##########################################
0260
0261 add_library(dolphinstatic STATIC)
0262
0263 target_sources(dolphinstatic PRIVATE
0264 dolphinbookmarkhandler.cpp
0265 dolphindockwidget.cpp
0266 dolphinmainwindow.cpp
0267 dolphinviewcontainer.cpp
0268 dolphincontextmenu.cpp
0269 dolphinnavigatorswidgetaction.cpp
0270 dolphintabbar.cpp
0271 dolphinplacesmodelsingleton.cpp
0272 dolphinrecenttabsmenu.cpp
0273 dolphintabpage.cpp
0274 dolphintabwidget.cpp
0275 dolphinurlnavigator.cpp
0276 dolphinurlnavigatorscontroller.cpp
0277 trash/dolphintrash.cpp
0278 filterbar/filterbar.cpp
0279 kitemviews/kfileitemlisttostring.cpp
0280 panels/places/placespanel.cpp
0281 panels/panel.cpp
0282 panels/folders/foldersitemlistwidget.cpp
0283 panels/folders/treeviewcontextmenu.cpp
0284 panels/folders/folderspanel.cpp
0285 panels/terminal/terminalpanel.cpp
0286 search/dolphinfacetswidget.cpp
0287 search/dolphinquery.cpp
0288 search/dolphinsearchbox.cpp
0289 selectionmode/actiontexthelper.cpp
0290 selectionmode/actionwithwidget.cpp
0291 selectionmode/backgroundcolorhelper.cpp
0292 selectionmode/bottombar.cpp
0293 selectionmode/bottombarcontentscontainer.cpp
0294 selectionmode/topbar.cpp
0295 settings/interface/folderstabssettingspage.cpp
0296 settings/interface/statusandlocationbarssettingspage.cpp
0297 settings/interface/confirmationssettingspage.cpp
0298 settings/interface/interfacesettingspage.cpp
0299 settings/interface/previewssettingspage.cpp
0300 settings/dolphinsettingsdialog.cpp
0301 settings/contextmenu/contextmenusettingspage.cpp
0302 settings/settingspagebase.cpp
0303 settings/servicemodel.cpp
0304 settings/trash/trashsettingspage.cpp
0305 settings/viewmodes/dolphinfontrequester.cpp
0306 settings/viewmodes/viewsettingspage.cpp
0307 settings/viewmodes/viewmodesettings.cpp
0308 settings/viewmodes/viewsettingstab.cpp
0309 settings/viewmodes/contentdisplaytab.cpp
0310 settings/viewmodes/generalviewsettingspage.cpp
0311 statusbar/dolphinstatusbar.cpp
0312 statusbar/mountpointobserver.cpp
0313 statusbar/mountpointobservercache.cpp
0314 statusbar/spaceinfoobserver.cpp
0315 statusbar/statusbarspaceinfo.cpp
0316 views/zoomlevelinfo.cpp
0317 dolphindebug.cpp
0318 global.cpp
0319 dolphin.qrc
0320
0321 dolphinbookmarkhandler.h
0322 dolphindockwidget.h
0323 dolphinmainwindow.h
0324 dolphinviewcontainer.h
0325 dolphincontextmenu.h
0326 dolphinnavigatorswidgetaction.h
0327 dolphintabbar.h
0328 dolphinplacesmodelsingleton.h
0329 dolphinrecenttabsmenu.h
0330 dolphintabpage.h
0331 dolphintabwidget.h
0332 dolphinurlnavigator.h
0333 dolphinurlnavigatorscontroller.h
0334 trash/dolphintrash.h
0335 filterbar/filterbar.h
0336 kitemviews/kfileitemlisttostring.h
0337 panels/places/placespanel.h
0338 panels/panel.h
0339 panels/folders/foldersitemlistwidget.h
0340 panels/folders/treeviewcontextmenu.h
0341 panels/folders/folderspanel.h
0342 panels/terminal/terminalpanel.h
0343 search/dolphinfacetswidget.h
0344 search/dolphinquery.h
0345 search/dolphinsearchbox.h
0346 selectionmode/actiontexthelper.h
0347 selectionmode/actionwithwidget.h
0348 selectionmode/backgroundcolorhelper.h
0349 selectionmode/bottombar.h
0350 selectionmode/bottombarcontentscontainer.h
0351 selectionmode/topbar.h
0352 settings/interface/folderstabssettingspage.h
0353 settings/interface/statusandlocationbarssettingspage.h
0354 settings/interface/confirmationssettingspage.h
0355 settings/interface/interfacesettingspage.h
0356 settings/interface/previewssettingspage.h
0357 settings/dolphinsettingsdialog.h
0358 settings/contextmenu/contextmenusettingspage.h
0359 settings/settingspagebase.h
0360 settings/servicemodel.h
0361 settings/trash/trashsettingspage.h
0362 settings/viewmodes/dolphinfontrequester.h
0363 settings/viewmodes/viewsettingspage.h
0364 settings/viewmodes/viewmodesettings.h
0365 settings/viewmodes/viewsettingstab.h
0366 settings/viewmodes/contentdisplaytab.h
0367 settings/viewmodes/generalviewsettingspage.h
0368 statusbar/dolphinstatusbar.h
0369 statusbar/mountpointobserver.h
0370 statusbar/mountpointobservercache.h
0371 statusbar/spaceinfoobserver.h
0372 statusbar/statusbarspaceinfo.h
0373 views/zoomlevelinfo.h
0374 dolphindebug.h
0375 global.h
0376 )
0377
0378 if(HAVE_BALOO)
0379 target_sources(dolphinstatic PRIVATE
0380 panels/information/informationpanel.cpp
0381 panels/information/informationpanelcontent.cpp
0382 panels/information/pixmapviewer.cpp
0383 panels/information/phononwidget.cpp
0384 panels/information/informationpanel.h
0385 panels/information/informationpanelcontent.h
0386 panels/information/pixmapviewer.h
0387 panels/information/phononwidget.h
0388 )
0389 endif()
0390
0391 if(HAVE_KUSERFEEDBACK)
0392 target_sources(dolphinstatic PRIVATE
0393 userfeedback/dolphinfeedbackprovider.cpp
0394 userfeedback/settingsdatasource.cpp
0395 userfeedback/placesdatasource.cpp
0396 settings/userfeedback/userfeedbacksettingspage.cpp
0397 userfeedback/dolphinfeedbackprovider.h
0398 userfeedback/settingsdatasource.h
0399 userfeedback/placesdatasource.h
0400 settings/userfeedback/userfeedbacksettingspage.h
0401 )
0402 endif()
0403
0404 kconfig_add_kcfg_files(dolphinstatic
0405 panels/folders/dolphin_folderspanelsettings.kcfgc
0406 panels/information/dolphin_informationpanelsettings.kcfgc
0407 panels/places/dolphin_placespanelsettings.kcfgc
0408 settings/dolphin_compactmodesettings.kcfgc
0409 settings/dolphin_detailsmodesettings.kcfgc
0410 settings/dolphin_contextmenusettings.kcfgc
0411 settings/dolphin_iconsmodesettings.kcfgc
0412 settings/dolphin_contentdisplaysettings.kcfgc
0413 search/dolphin_searchsettings.kcfgc
0414 settings/dolphin_versioncontrolsettings.kcfgc
0415 )
0416 kconfig_add_kcfg_files(dolphinstatic GENERATE_MOC
0417 settings/dolphin_generalsettings.kcfgc
0418 )
0419
0420 qt_generate_dbus_interface(${CMAKE_CURRENT_SOURCE_DIR}/dolphinmainwindow.h org.kde.DolphinMainWindow.xml)
0421 qt_add_dbus_adaptor(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindow.h DolphinMainWindow)
0422 qt_add_dbus_interface(dolphin_dbus_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.DolphinMainWindow.xml dolphinmainwindowinterface)
0423 qt_add_dbus_interface(dolphin_dbus_SRCS panels/terminal/org.kde.KIOFuse.VFS.xml kiofuse_interface)
0424
0425 target_sources(dolphinstatic PRIVATE
0426 ${dolphin_dbus_SRCS}
0427 )
0428
0429 target_include_directories(dolphinstatic SYSTEM PRIVATE ${PHONON_INCLUDES})
0430 target_link_libraries(dolphinstatic
0431 dolphinprivate
0432 KF6::CoreAddons
0433 KF6::KCMUtils
0434 KF6::DBusAddons
0435 KF6::Notifications
0436 KF6::BookmarksWidgets
0437 Phonon::phonon4qt6
0438 )
0439
0440 if (HAVE_PLASMA_ACTIVITIES)
0441 target_link_libraries(
0442 dolphinstatic
0443 Plasma::Activities
0444 )
0445 endif()
0446
0447 if (HAVE_KUSERFEEDBACK)
0448 target_link_libraries(
0449 dolphinstatic
0450 KF6::UserFeedbackCore
0451 KF6::UserFeedbackWidgets
0452 )
0453 endif()
0454
0455 add_executable(dolphin)
0456
0457 target_sources(dolphin PRIVATE
0458 dbusinterface.cpp
0459 dbusinterface.h
0460 main.cpp
0461 )
0462
0463 if(FLATPAK)
0464 target_compile_definitions(dolphin PRIVATE FLATPAK)
0465 endif()
0466
0467 # Install the icons on macOS and Windows
0468 ecm_add_app_icon(dolphin
0469 ICONS
0470 icons/128-apps-org.kde.dolphin.png
0471 icons/16-apps-org.kde.dolphin.png
0472 icons/22-apps-org.kde.dolphin.png
0473 icons/32-apps-org.kde.dolphin.png
0474 icons/48-apps-org.kde.dolphin.png
0475 icons/64-apps-org.kde.dolphin.png
0476 DESTINATION
0477 ${KDE_INSTALL_ICONDIR}
0478 THEME
0479 hicolor
0480 )
0481
0482 install(FILES icons/org.kde.dolphin.svg DESTINATION ${KDE_INSTALL_ICONDIR}/hicolor/scalable/apps)
0483
0484 target_link_libraries(dolphin
0485 PRIVATE
0486 dolphinprivate
0487 dolphinstatic
0488 KF6::Crash
0489 )
0490
0491 if (HAVE_X11)
0492 target_link_libraries(dolphin PRIVATE Qt::GuiPrivate)
0493 endif()
0494
0495 include(DbusInterfaceMacros)
0496
0497 generate_and_install_dbus_interface(
0498 dolphin
0499 dbusinterface.h
0500 org.freedesktop.FileManager1.xml
0501 OPTIONS -a
0502 )
0503
0504 install(TARGETS dolphin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0505
0506 ##########################################
0507
0508 if(NOT WIN32)
0509 # The settings are still accessible from the hamburger menu
0510 add_library(kcm_dolphinviewmodes MODULE)
0511 add_library(kcm_dolphingeneral MODULE)
0512
0513 target_sources(kcm_dolphinviewmodes PRIVATE
0514 settings/kcm/kcmdolphinviewmodes.cpp
0515 settings/viewmodes/dolphinfontrequester.cpp
0516 settings/viewmodes/viewmodesettings.cpp
0517 settings/viewmodes/viewsettingstab.cpp
0518 settings/settingspagebase.cpp
0519 views/zoomlevelinfo.cpp
0520 settings/kcm/kcmdolphinviewmodes.h
0521 settings/viewmodes/dolphinfontrequester.h
0522 settings/viewmodes/viewmodesettings.h
0523 settings/viewmodes/viewsettingstab.h
0524 views/zoomlevelinfo.h)
0525
0526 target_sources(kcm_dolphingeneral PRIVATE
0527 settings/kcm/kcmdolphingeneral.cpp
0528 settings/interface/folderstabssettingspage.cpp
0529 settings/interface/statusandlocationbarssettingspage.cpp
0530 settings/interface/previewssettingspage.cpp
0531 settings/interface/confirmationssettingspage.cpp
0532 settings/settingspagebase.cpp
0533 settings/servicemodel.cpp
0534 dolphin_generalsettings.cpp
0535 dolphindebug.cpp
0536 dolphinmainwindowinterface.cpp
0537 views/viewproperties.cpp
0538 dolphin_directoryviewpropertysettings.cpp
0539 global.cpp
0540 settings/kcm/kcmdolphingeneral.h
0541 settings/interface/folderstabssettingspage.h
0542 settings/interface/statusandlocationbarssettingspage.h
0543 settings/interface/previewssettingspage.h
0544 settings/interface/confirmationssettingspage.h
0545 settings/settingspagebase.h
0546 settings/servicemodel.h
0547 dolphin_generalsettings.h
0548 dolphindebug.h
0549 dolphinmainwindowinterface.h
0550 views/viewproperties.h
0551 dolphin_directoryviewpropertysettings.h
0552 global.h
0553 )
0554
0555 kconfig_add_kcfg_files(kcm_dolphinviewmodes
0556 settings/dolphin_compactmodesettings.kcfgc
0557 settings/dolphin_directoryviewpropertysettings.kcfgc
0558 settings/dolphin_detailsmodesettings.kcfgc
0559 settings/dolphin_iconsmodesettings.kcfgc
0560 settings/dolphin_contentdisplaysettings.kcfgc
0561 settings/dolphin_generalsettings.kcfgc
0562 settings/dolphin_versioncontrolsettings.kcfgc
0563 )
0564
0565 kconfig_add_kcfg_files(kcm_dolphingeneral
0566 settings/dolphin_generalsettings.kcfgc)
0567
0568 target_link_libraries(kcm_dolphinviewmodes dolphinprivate)
0569 target_link_libraries(kcm_dolphingeneral dolphinprivate)
0570
0571 install( FILES org.kde.dolphin.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR} )
0572
0573 install(TARGETS kcm_dolphinviewmodes DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
0574 install(TARGETS kcm_dolphingeneral DESTINATION ${KDE_INSTALL_PLUGINDIR}/dolphin/kcms )
0575 endif()
0576
0577 if(NOT WIN32)
0578 add_subdirectory(settings/contextmenu/servicemenuinstaller)
0579 install( FILES settings/contextmenu/servicemenu.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR} )
0580 endif()
0581
0582 ########### install files ###############
0583
0584 install( PROGRAMS org.kde.dolphin.desktop DESTINATION ${KDE_INSTALL_APPDIR} )
0585
0586 install( DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel" )
0587
0588 install(
0589 CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/org.kde.dolphin.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/org.kde.dolphin.desktop\")"
0590 )
0591
0592 install( FILES settings/dolphin_directoryviewpropertysettings.kcfg
0593 settings/dolphin_generalsettings.kcfg
0594 settings/dolphin_contextmenusettings.kcfg
0595 settings/dolphin_compactmodesettings.kcfg
0596 settings/dolphin_iconsmodesettings.kcfg
0597 settings/dolphin_detailsmodesettings.kcfg
0598 settings/dolphin_contentdisplaysettings.kcfg
0599 settings/dolphin_versioncontrolsettings.kcfg
0600 DESTINATION ${KDE_INSTALL_KCFGDIR} )
0601
0602 install( FILES settings/dolphin_detailsmodesettings.upd
0603 DESTINATION ${KDE_INSTALL_KCONFUPDATEDIR} )
0604
0605 if(BUILD_TESTING)
0606 add_subdirectory(tests)
0607 endif()