rust-qt-binding-generator/cmake/FindCargo.cmake

0001 # Find the cargo executable
0002 #
0003 # Defines the following variables
0004 #  Cargo_FOUND      - True if the cargo executable was found
0005 #  Cargo_EXECUTABLE - path of the cargo executable
0006 #  Cargo_VERSION    - version number of cargo
0007
0008 #=============================================================================
0009 # Copyright 2017 Friedrich W. H. Kossebau <kossebau@kde.org>
0010 #
0011 # Distributed under the OSI-approved BSD License (the "License");
0012 # see accompanying file Copyright.txt for details.
0013 #
0014 # This software is distributed WITHOUT ANY WARRANTY; without even the
0015 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
0016 # See the License for more information.
0017 #=============================================================================
0018
0019 find_program(Cargo_EXECUTABLE NAMES cargo)
0020
0021 if (Cargo_EXECUTABLE)
0022     execute_process(COMMAND "${Cargo_EXECUTABLE}" --version
0023         OUTPUT_VARIABLE Cargo_VERSION_OUTPUT
0024         ERROR_VARIABLE Cargo_VERSION_ERROR
0025         RESULT_VARIABLE Cargo_VERSION_RESULT
0026     )
0027     if(NOT ${Cargo_VERSION_RESULT} EQUAL 0)
0028         message(SEND_ERROR "Command \"${Cargo_EXECUTABLE} --version\" failed with output:\n${Cargo_VERSION_ERROR}")
0029     else()
0030         # TODO: support also nightly
0031         string(REGEX MATCH "[0-9]+\\.[0-9]+\\.[0-9]+"
0032             Cargo_VERSION "${Cargo_VERSION_OUTPUT}"
0033         )
0034     endif()
0035 endif()
0036
0037 include(FindPackageHandleStandardArgs)
0038 find_package_handle_standard_args(Cargo
0039     REQUIRED_VARS Cargo_EXECUTABLE
0040     VERSION_VAR Cargo_VERSION
0041 )
0042
0043 mark_as_advanced(Cargo_EXECUTABLE Cargo_VERSION)
0044
0045 set_package_properties(Cargo PROPERTIES
0046     DESCRIPTION "The Rust package manager"
0047     URL "https://github.com/rust-lang/cargo/"
0048 )