libkomparediff2/src/CMakeLists.txt

0001 set(KOMPAREDIFF2_INSTALL_INCLUDEDIR "${KDE_INSTALL_INCLUDEDIR}/KompareDiff2")
0002 set(KOMPAREDIFF2_CMAKECONFIG_NAME "KompareDiff2")
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"libkomparediff2\")
0005
0006 ecm_setup_version(PROJECT
0007     VARIABLE_PREFIX      KOMPAREDIFF2
0008     VERSION_HEADER       "komparediff2_version.h"
0009     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/${KOMPAREDIFF2_CMAKECONFIG_NAME}ConfigVersion.cmake"
0010     COMPATIBILITY        SameMajorVersion
0011     SOVERSION            6
0012 )
0013
0014 add_library(komparediff2 SHARED)
0015
0016 set_target_properties(komparediff2 PROPERTIES
0017     VERSION     ${KOMPAREDIFF2_VERSION}
0018     SOVERSION   ${KOMPAREDIFF2_SOVERSION}
0019     EXPORT_NAME "KompareDiff2"
0020 )
0021
0022 target_sources(komparediff2 PRIVATE
0023     kompareprocess.cpp
0024     modellist.cpp
0025     modellist_p.cpp
0026     diffmodellist.cpp
0027     diffmodel.cpp
0028     diffmodel_p.cpp
0029     difference.cpp
0030     differencestring.cpp
0031     diffhunk.cpp
0032     diffsettings.cpp
0033     info.cpp
0034     parser.cpp
0035     parserbase.cpp
0036     cvsdiffparser.cpp
0037     diffparser.cpp
0038     perforceparser.cpp
0039     stringlistpair.cpp
0040 )
0041
0042 ecm_qt_declare_logging_category(komparediff2
0043     HEADER komparediff2_logging.h
0044     IDENTIFIER KOMPAREDIFF2_LOG
0045     CATEGORY_NAME "libkomparediff"
0046     DESCRIPTION "libkomparediff"
0047     EXPORT komparediff2
0048 )
0049
0050 ecm_generate_export_header(komparediff2
0051     VERSION ${KOMPAREDIFF2_VERSION}
0052     DEPRECATED_BASE_VERSION 0
0053     DEPRECATION_VERSIONS
0054     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0055     USE_VERSION_HEADER
0056 )
0057
0058 target_link_libraries(komparediff2
0059     PUBLIC
0060         KF6::XmlGui
0061         KF6::ConfigCore
0062         Qt6::Widgets
0063         Qt6::Core
0064     PRIVATE
0065         KF6::KIOCore
0066         KF6::I18n
0067         KF6::CoreAddons
0068         Qt6::Core5Compat
0069 )
0070
0071 target_include_directories(komparediff2 INTERFACE "$<INSTALL_INTERFACE:${KOMPAREDIFF2_INSTALL_INCLUDEDIR}>")
0072
0073 install(TARGETS komparediff2 EXPORT LibKompareDiff2Targets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0074
0075 ecm_generate_headers(komparediff2_CamelCase_HEADERS
0076     HEADER_NAMES
0077         Difference
0078         DifferenceString
0079         DiffHunk
0080         DiffModel
0081         DiffModelList
0082         DiffSettings
0083         Info
0084         Global
0085         Marker
0086         ModelList
0087     PREFIX KompareDiff2
0088     REQUIRED_HEADERS komparediff2_HEADERS
0089 )
0090
0091 install(
0092     FILES
0093         ${CMAKE_CURRENT_BINARY_DIR}/komparediff2_export.h
0094         ${komparediff2_HEADERS}
0095     DESTINATION
0096         ${KOMPAREDIFF2_INSTALL_INCLUDEDIR}/komparediff2
0097     COMPONENT
0098         Devel
0099 )
0100 install(
0101     FILES
0102         ${komparediff2_CamelCase_HEADERS}
0103     DESTINATION
0104         ${KOMPAREDIFF2_INSTALL_INCLUDEDIR}/KompareDiff2
0105     COMPONENT
0106         Devel
0107 )
0108 install(
0109     FILES
0110         ${CMAKE_CURRENT_BINARY_DIR}/komparediff2_version.h
0111     DESTINATION
0112         ${KOMPAREDIFF2_INSTALL_INCLUDEDIR}
0113     COMPONENT
0114         Devel
0115 )
0116
0117 ecm_qt_install_logging_categories(
0118     EXPORT komparediff2
0119     FILE libkomparediff2.categories
0120     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0121 )
0122
0123
0124 # CMake config files
0125 set(_LibKompareDiff2_CONFIG_DEST "${KDE_INSTALL_CMAKEPACKAGEDIR}/${KOMPAREDIFF2_CMAKECONFIG_NAME}")
0126
0127 configure_package_config_file(
0128     "${CMAKE_CURRENT_SOURCE_DIR}/KompareDiff2Config.cmake.in"
0129     "${CMAKE_CURRENT_BINARY_DIR}/${KOMPAREDIFF2_CMAKECONFIG_NAME}Config.cmake"
0130     INSTALL_DESTINATION  "${_LibKompareDiff2_CONFIG_DEST}"
0131 )
0132
0133 install( FILES
0134         "${CMAKE_CURRENT_BINARY_DIR}/${KOMPAREDIFF2_CMAKECONFIG_NAME}ConfigVersion.cmake"
0135         "${CMAKE_CURRENT_BINARY_DIR}/${KOMPAREDIFF2_CMAKECONFIG_NAME}Config.cmake"
0136         DESTINATION "${_LibKompareDiff2_CONFIG_DEST}" )
0137 install( EXPORT LibKompareDiff2Targets
0138          DESTINATION "${_LibKompareDiff2_CONFIG_DEST}"
0139          FILE ${KOMPAREDIFF2_CMAKECONFIG_NAME}Targets.cmake )