sdk/libkomparediff2/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(LibKompareDiff2 VERSION "5.4.0")
0004
0005 set(QT_MIN_VERSION "5.15.2")
0006 set(KF_MIN_VERSION "5.91.0")
0007
0008 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0009 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0010
0011 include(KDEInstallDirs)
0012 include(KDECMakeSettings)
0013 include(KDECompilerSettings NO_POLICY_SCOPE)
0014 include(ECMQtDeclareLoggingCategory)
0015 include(ECMSetupVersion)
0016 include(ECMGenerateExportHeader)
0017 include(ECMGenerateHeaders)
0018 include(ECMDeprecationSettings)
0019
0020 include(CMakePackageConfigHelpers)
0021 include(FeatureSummary)
0022
0023 # reset to 0 once all deprecated API has been removed on full switch to Qt6
0024 if (QT_MAJOR_VERSION STREQUAL "6")
0025 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 5.4.0 CACHE STRING "Control the range of deprecated API excluded from the build [default=7.5.0].")
0026 else()
0027 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
0028 endif()
0029
0030 if (QT_MAJOR_VERSION STREQUAL "6")
0031     set(QT_MIN_VERSION "6.5.0")
0032     set(KF_MIN_VERSION "5.240.0")
0033     set(KF_MAJOR_VERSION "6")
0034 else()
0035     set(KF_MAJOR_VERSION "5")
0036 endif()
0037
0038 set(ADDITIONAL_REQUIRED_QT_COMPONENTS)
0039 if(BUILD_TESTING)
0040     list(APPEND ADDITIONAL_REQUIRED_QT_COMPONENTS Test)
0041 endif()
0042 if (QT_MAJOR_VERSION STREQUAL "6")
0043     list(APPEND ADDITIONAL_REQUIRED_QT_COMPONENTS Core5Compat) # QTextCodec
0044 endif()
0045
0046 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED
0047     COMPONENTS
0048         Core
0049         Widgets
0050         ${ADDITIONAL_REQUIRED_QT_COMPONENTS}
0051 )
0052
0053 find_package(KF${KF_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED
0054     COMPONENTS
0055         CoreAddons
0056         Config
0057         XmlGui
0058         I18n
0059         KIO
0060 )
0061
0062 if (QT_MAJOR_VERSION STREQUAL "6")
0063     ecm_set_disabled_deprecation_versions(
0064         QT 6.5
0065         KF 5.239
0066     )
0067 else()
0068     ecm_set_disabled_deprecation_versions(
0069         QT 5.15.2
0070         KF 5.91
0071     )
0072 endif()
0073
0074 add_subdirectory(src)
0075
0076 if (BUILD_TESTING)
0077     add_subdirectory(tests)
0078 endif()
0079
0080 ki18n_install(po)
0081
0082 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)