kobjecttracking/src/CMakeLists.txt

0001 add_subdirectory(declarative)
0002
0003 add_library(KF5ObjectTracking objecttracking.cpp objecttimetracker.cpp objectwatcher.cpp objectdebug.cpp)
0004 add_library(KF5::ObjectTracking ALIAS KF5ObjectTracking)
0005
0006 target_link_libraries(KF5ObjectTracking PUBLIC Qt5::Core)
0007
0008 set_target_properties(KF5ObjectTracking PROPERTIES
0009    VERSION ${KOBJECTTRACKING_VERSION_STRING}
0010    SOVERSION ${KOBJECTTRACKING_SOVERSION}
0011    EXPORT_NAME ObjectTracking
0012 )
0013
0014 generate_export_header(KF5ObjectTracking BASE_NAME KObjectTracking EXPORT_FILE_NAME kobjecttracking_export.h)
0015
0016 ecm_generate_headers(KObjectTracking_CamelCase_HEADERS
0017   HEADER_NAMES
0018     ObjectTracking
0019 #     ObjectDebug
0020
0021   REQUIRED_HEADERS KObjectTracking_HEADERS
0022   PREFIX KObjectTracking
0023 )
0024
0025 target_include_directories(KF5ObjectTracking PUBLIC "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}>")
0026
0027 install(TARGETS KF5ObjectTracking EXPORT KF5ObjectTrackingTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
0028 install(FILES ${KObjectTracking_CamelCase_HEADERS} DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KObjectTracking COMPONENT Devel)
0029 install(FILES
0030     ${KObjectTracking_HEADERS}
0031     ${CMAKE_CURRENT_BINARY_DIR}/kobjecttracking_export.h
0032     DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/kobjecttracking COMPONENT Devel)
0033
0034 if(BUILD_QCH)
0035     ecm_add_qch(
0036         KF5ObjectTracking_QCH
0037         NAME KObjectTracking
0038         BASE_NAME KF5ObjectTracking
0039         VERSION ${KF5_VERSION}
0040         ORG_DOMAIN org.kde
0041         SOURCES ${KObjectTracking_HEADERS}
0042         BLANK_MACROS
0043             KOBJECTTRACKING_EXPORT
0044             KOBJECTTRACKING_DEPRECATED
0045             KOBJECTTRACKING_DEPRECATED_EXPORT
0046         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0047         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0048         COMPONENT Devel
0049     )
0050 endif()
0051
0052 include(ECMGeneratePriFile)
0053 ecm_generate_pri_file(BASE_NAME KObjectTracking LIB_NAME KF5ObjectTracking FILENAME_VAR COREPRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KObjectTracking)
0054 install(FILES ${COREPRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0055