src/analyze/CMakeLists.txt

0001 if (ECM_FOUND)
0002     include(ECMEnableSanitizers)
0003 endif()
0004
0005 find_package(Boost 1.41.0 REQUIRED COMPONENTS headers iostreams program_options system filesystem)
0006
0007 configure_file(analyze_config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/analyze_config.h)
0008
0009 include_directories(
0010     ${Boost_INCLUDE_DIRS}
0011     ${ZLIB_INCLUDE_DIRS}
0012     ${PROJECT_SOURCE_DIR}/3rdparty/
0013     ${CMAKE_CURRENT_BINARY_DIR}
0014 )
0015
0016 add_library(sharedprint STATIC
0017     accumulatedtracedata.cpp
0018     suppressions.cpp
0019 )
0020
0021 target_link_libraries(sharedprint
0022     PUBLIC
0023         ${Boost_LIBRARIES}
0024         ${ZLIB_LIBRARIES}
0025         tsl::robin_map
0026 )
0027
0028 if (ZSTD_FOUND AND NOT BOOST_IOSTREAMS_HAS_ZSTD)
0029     target_link_libraries(sharedprint LINK_PUBLIC
0030         boost-zstd
0031     )
0032 endif()
0033
0034 add_subdirectory(print)
0035
0036 if(HEAPTRACK_BUILD_GUI)
0037     if(QT_VERSION_MAJOR EQUAL 6)
0038         set(KChartName KChart6)
0039     else()
0040         set(KChartName KChart)
0041     endif()
0042
0043     find_package(Qt${QT_VERSION_MAJOR} ${QT_MIN_VERSION} ${REQUIRED_IN_APPIMAGE} NO_MODULE OPTIONAL_COMPONENTS Widgets)
0044     set_package_properties(Qt${QT_VERSION_MAJOR} PROPERTIES TYPE RECOMMENDED PURPOSE "Required for the heaptrack_gui executable.")
0045     find_package(ECM 1.0.0 ${REQUIRED_IN_APPIMAGE} NO_MODULE)
0046     set_package_properties(ECM PROPERTIES TYPE RECOMMENDED PURPOSE "KDE's extra-cmake-modules, required for the heaptrack_gui executable.")
0047     if(Qt${QT_VERSION_MAJOR}_FOUND AND ECM_FOUND)
0048         set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0049             find_package(KF${QT_VERSION_MAJOR} ${REQUIRED_IN_APPIMAGE} COMPONENTS CoreAddons I18n ItemModels ThreadWeaver ConfigWidgets KIO IconThemes)
0050             find_package(${KChartName} ${REQUIRED_IN_APPIMAGE} "2.6.0")
0051             set_package_properties(${KChartName} PROPERTIES TYPE RECOMMENDED PURPOSE "Required for the heaptrack_gui executable. Get it from the kdiagram module.")
0052         if(KF${QT_VERSION_MAJOR}I18n_FOUND)
0053             ki18n_install(../../po)
0054         endif()
0055     else()
0056         message(WARNING "Required Qt/KF dependencies for building heaptrack GUI not found")
0057     endif()
0058 endif()
0059
0060 if(KChart6_FOUND)
0061     set(KChart_FOUND TRUE)
0062 endif()
0063
0064 if (KF${QT_VERSION_MAJOR}_FOUND)
0065     add_subdirectory(gui)
0066 endif()