sdk/dolphin-plugins/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 # Release service version, managed by release script
0004 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0005 set(RELEASE_SERVICE_VERSION_MINOR "04")
0006 set(RELEASE_SERVICE_VERSION_MICRO "70")
0007
0008 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0009
0010 project(dolphin-plugins VERSION ${RELEASE_SERVICE_VERSION})
0011
0012 set(QT_MIN_VERSION "6.5.0")
0013 set(KF_MIN_VERSION "5.240.0")
0014
0015 # ECM setup
0016 find_package(ECM ${KF_MIN_VERSION} CONFIG REQUIRED)
0017 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake)
0018
0019 include(QtVersionOption)
0020 include(ECMSetupVersion)
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024
0025 include(ECMDeprecationSettings)
0026 include(ECMOptionalAddSubdirectory)
0027 include(FeatureSummary)
0028
0029 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED COMPONENTS
0030     Core
0031     Core5Compat
0032     Widgets
0033     Network
0034     DBus
0035 )
0036
0037 find_package(KF6 ${KF_MIN_VERSION} REQUIRED COMPONENTS
0038     XmlGui
0039     I18n
0040     KIO
0041     TextWidgets
0042     CoreAddons
0043     Solid
0044 )
0045
0046 find_package(DolphinVcs REQUIRED)
0047 set_package_properties(DolphinVcs PROPERTIES
0048     DESCRIPTION "the Dolphin version control plugin library"
0049     URL "https://commits.kde.org/dolphin"
0050     TYPE REQUIRED
0051     PURPOSE "Provides the version control plugin interface."
0052 )
0053
0054 ecm_set_disabled_deprecation_versions(
0055     QT 6.5
0056     KF 5.240
0057 )
0058
0059 ecm_optional_add_subdirectory(svn)
0060 ecm_optional_add_subdirectory(git)
0061 ecm_optional_add_subdirectory(bazaar)
0062 ecm_optional_add_subdirectory(dropbox)
0063 ecm_optional_add_subdirectory(hg)
0064 if(UNIX)
0065     ecm_optional_add_subdirectory(makefileactions)
0066 endif()
0067 if(UNIX AND NOT APPLE)
0068     ecm_optional_add_subdirectory(mountiso)
0069 endif()
0070
0071 install(FILES org.kde.dolphin-plugins.metainfo.xml
0072         DESTINATION ${KDE_INSTALL_METAINFODIR})
0073
0074 ki18n_install(po)
0075
0076 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)