Symbols/HVAC.1/MotorActuator.qml

0001 import QtQuick 2.0
0002
0003 import CuteHMI.GUI 1.0
0004
0005 /**
0006   Motor actuator.
0007   */
0008 Element {
0009         id: root
0010
0011         implicitWidth: units.quadrat * 0.5
0012         implicitHeight: units.quadrat * 0.5
0013
0014         property real start: 0.0
0015         property real value: 0.0
0016         property string symbol: "M"
0017         property alias font: symbolText.font
0018
0019         SymbolCanvas {
0020                 id: canvas
0021
0022                 anchors.fill: parent
0023
0024                 element: root
0025
0026                 onPaint: {
0027                         var ctx = getContext("2d")
0028                         ctx.save()
0029                         ctx.reset()
0030
0031                         ctx.lineWidth = units.strokeWidth
0032                         ctx.fillStyle = color.background
0033                         ctx.strokeStyle = color.stroke
0034
0035                         var r = (width - units.strokeWidth) * 0.5
0036                         var xCenter = width * 0.5
0037                         var yCenter = height * 0.5
0038
0039                         // Draw circle.
0040                         ctx.beginPath()
0041                         ctx.arc(xCenter, yCenter, r, 0, 2 * Math.PI)
0042                         ctx.fill()
0043                         ctx.stroke()
0044
0045                         // Draw progress
0046                         ctx.beginPath()
0047                         ctx.strokeStyle = color.background
0048                         ctx.arc(xCenter, yCenter, r - units.strokeWidth, 0, 2 * Math.PI)
0049                         ctx.stroke()
0050
0051                         ctx.beginPath()
0052                         ctx.strokeStyle = color.foreground
0053                         ctx.arc(xCenter, yCenter, r - units.strokeWidth, start * 2 * Math.PI - 0.5 * Math.PI, value * 2 * Math.PI - 0.5 * Math.PI)
0054                         ctx.stroke()
0055
0056                         ctx.restore()
0057                 }
0058
0059                 Connections {
0060                         target: root
0061
0062                         function onStartChanged() {
0063                                 canvas.requestPaint()
0064                         }
0065
0066                         function onValueChanged() {
0067                                 canvas.requestPaint()
0068                         }
0069                 }
0070         }
0071
0072         Text {
0073                 id: symbolText
0074
0075                 anchors.centerIn: parent
0076                 color: root.color.foreground
0077                 font.family: Theme.fonts.monospace.family
0078                 font.pixelSize: units.quadrat * 0.2
0079                 text: parent.symbol
0080         }
0081 }
0082
0083 //(c)C: Copyright © 2020-2021, Michał Policht <michal@policht.pl>. All rights reserved.
0084 //(c)C: SPDX-License-Identifier: LGPL-3.0-or-later OR MIT
0085 //(c)C: This file is a part of CuteHMI.
0086 //(c)C: CuteHMI is free software: you can redistribute it and/or modify it under the terms of the GNU Lesser General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version.
0087 //(c)C: CuteHMI is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public License for more details.
0088 //(c)C: You should have received a copy of the GNU Lesser General Public License along with CuteHMI.  If not, see <https://www.gnu.org/licenses/>.
0089 //(c)C: Additionally, this file is licensed under terms of MIT license as expressed below.
0090 //(c)C: Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
0091 //(c)C: The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
0092 //(c)C: THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.