Warning, /sdk/cutehmi/extensions/CuteHMI/Examples/Modbus/Requests.3/WriteFileRecordControl.qml is written in an unsupported language. File is not indexed.

 import QtQuick 2.0
 import QtQuick.Controls 2.0
 import QtQuick.Layouts 1.0
 
 import CuteHMI.Modbus 4.0
 
 RowLayout {
         property AbstractDevice device
 
         Button {
                 Layout.alignment: Qt.AlignTop
 
                 text: "Write file record"
                 onClicked:  {
                         var subrequests = []
                         for (var i = 0; i < repeater.count; i++) {
                                 var item = repeater.itemAt(i)
                                 var values = []
                                 for (var j = 0; j < item.valuesRepeater.count; j++)
                                         values.push(item.valuesRepeater.itemAt(j).value)
                                 subrequests.push(device.writeFileRecordSubrequest(item.file, item.address, values))
                         }
                         device.requestWriteFileRecord(subrequests)
                 }
         }
 
         RowLayout {
                 Layout.alignment: Qt.AlignTop
 
                 Label {
                         text: qsTr("Subrequests:")
                 }
 
                 SpinBox {
                         id: subrequestsBox
 
                         editable: true
                         from: 1
                         to: 10
                 }
         }
 
         ColumnLayout {
                 Repeater {
                         id: repeater
 
                         model: subrequestsBox.value
 
                         RowLayout {
                                 property int file: fileBox.value
                                 property int address: addressBox.value
                                 property int amount: amountBox.value
                                 property var valuesRepeater: valuesRepeater
 
                                 Label {
                                         text: qsTr("File:")
                                 }
 
                                 SpinBox {
                                         id: fileBox
 
                                         editable: true
                                         from: 1
                                         to: 65535
                                 }
 
                                 Label {
                                         text: qsTr("Address:")
                                 }
 
                                 SpinBox {
                                         id: addressBox
 
                                         editable: true
                                         from: 0
                                         to: 0x270F
                                 }
 
                                 Label {
                                         text: qsTr("Amount:")
                                 }
 
                                 SpinBox {
                                         id: amountBox
 
                                         editable: true
                                         from: 1
                                         to: 65535
                                 }
 
                                 Label {
                                         text: qsTr("Values:")
                                 }
 
                                 Repeater {
                                         id: valuesRepeater
 
                                         model: amountBox.value
 
                                         SpinBox {
                                                 editable: true
                                                 from: 0
                                                 to: 65535
                                         }
                                 }
                         }
                 }
         }
 
 }
 
 //(c)C: Copyright © 2022, Michał Policht <michal@policht.pl>. All rights reserved.
 //(c)C: SPDX-License-Identifier: LGPL-3.0-or-later OR MIT
 //(c)C: This file is a part of CuteHMI.
 //(c)C: CuteHMI is free software: you can redistribute it and/or modify it under the terms of the GNU Lesser General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version.
 //(c)C: CuteHMI is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public License for more details.
 //(c)C: You should have received a copy of the GNU Lesser General Public License along with CuteHMI.  If not, see <https://www.gnu.org/licenses/>.
 //(c)C: Additionally, this file is licensed under terms of MIT license as expressed below.
 //(c)C: Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
 //(c)C: The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
 //(c)C: THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.